[Solved] How does the JSON module work?

Ricaz · **Author**

Hi.

I want to send JSON events from a mod. I upgraded to v. 1.10 to get the JSON include that was added a while ago.
I can't really find any examples of its use, so I tried going off the documentation on amxmodx.org/api/json, but I can't really seem to make it work:

Code:

stock send_players()
{
    new Players[32]
    new playerCount, i
    new JSON:playersJson = json_init_object();
    new JSON:argsJson = json_init_array();
    json_object_set_string(playersJson, "command", "players");
    get_players(Players, playerCount, "c")
    for (i=0; i<playerCount; i++)
    {
        new JSON:playerObject = json_init_object();
        json_object_set_string(playerObject, "steamid", "1234");
        json_object_set_string(playerObject, "name", "plaf");
        json_array_append_value(argsJson, playerObject);
    }

    json_object_set_value(playersJson, "args", argsJson);

    new buf[3072]
    json_serial_to_string(playersJson, buf, strlen(buf));

    log_amx("PLAYERS: %s", buf);

    json_free(argsJson);
    json_free(playersJson);
}

After this, 'buf' is just an empty string. What am I doing wrong?

Thanks.

CrazY. · *Last edited by CrazY.; 08-02-2021 at 18:29.*

The problem is that you're using strlen instead of charsmax.

Code:

json_serial_to_string(playersJson, buf, strlen(buf))

Since you didn't assign any string to the buf variable, strlen will return 0. The third parameter of json_serial_to_string is:

Code:

maxlen - Maximum size of the buffer

You're literally doing this:

Code:

json_serial_to_string(playersJson, buf, 0);
// copy up to 0 characters

charsmax will return the size of the buffer - 1 for the null terminator, in your case 3072 - 1 (3071) and will copy up to 3070 characters.

By the way, you should probably call json_free() on the playerObject variable after each iteration.

Code:

new JSON:playerObject = json_init_object();
json_object_set_string(playerObject, "steamid", "1234");
json_object_set_string(playerObject, "name", "plaf");
json_array_append_value(argsJson, playerObject);
json_free(playerObject)

Ricaz · 08-09-2021 , 07:59 Re: How does the JSON module work?

Ah, my SourcePawn is a bit rusty. It works now. Thanks!

fysiks · 08-09-2021 , 22:13 Re: How does the JSON module work?

To be clear, this isn't SourcePawn. SourcePawn is only used with SourceMod.