[xxxperts]

hii all, i need some good suggestions & better way or new idea.... as i m wanted to give points as per specific weapon kills...

sooo is there any new idea to detect weapons....soo plugin can use low cpu usage...

if simple lang i dont want to use if that attacker has this or that weapon..

PHP Code:

public Event_Dead()
{
    new iKiller = read_data(1);
    new iVictim = read_data(2);
    new iHskill = read_data(3);
    new weapon, HitPoint = get_user_attacker(iVictim, weapon, HitPoint);
    
    if(weapon == CSW_KNIFE)
    {
        // my points
    }
    
    if(weapon == CSW_M4A1)
    {
        if(iHskill)
        {
            // my points
        }
        else
        {
            // my points
        }
    }
    
    if(weapon == CSW_AK47)
    {
        if(iHskill)
        {
            // my points
        }
        else
        {
            // my points
        }
    }
    
    if(weapon == CSW_AWP)
    {
        if(iHskill)
        {
            // my points
        }
        else
        {
            // my points
        }
    }
    
    if(weapon == CSW_SCOUT)
    {
        if(iHskill)
        {
            // my points
        }
        else
        {
            // my points
        }
    }
    
    if(weapon == CSW_DEAGLE)
    {
        if(iHskill)
        {
            // my points
        }
        else
        {
            // my points
        }
    }
} 


[DavidJr]

You can check the victim was killed by weapon of the attacker like this:

PHP Code:

new iWeapon[32]
read_data(4, iWeapon, sizeof iWeapon)

client_print(iKiller, print_chat, "%s", iWeapon) 


[xxxperts]

bro i wanted to give points on that weapon then how...???

[DavidJr]

What do you mean points for weapon?

[xxxperts]

i am creating xp / points system plugin ... i want to give points on specific weapons i had used that above give my code but i need better one..

[BlueGaming]

Show here code

[xxxperts]

code is show above ....

[hornet]

Store your preset points for kills in an array ( corresponding with the CSW constants ), then retrieve the used weapon's name with read_data( 4 ), formatting it and converting it back to it's CSW constant, and then get the points value from the array.

[xxxperts]

i didn't got this can show one example...plz

[ConnorMcLeod]

long way without csx

PHP Code:

new g_iMaxPlayers;

enum _:pointsPerKill
{
    m_iNormalKillPoints,
    m_iHsKillPoints
}

new const g_iPointsPerKill[][pointsPerKill] = 
{
//    {normal , hs}
    {-1, -1}, // 
    {1, 1}, // CSW_P228
    {-1, -1}, // 
    {1, 1}, // CSW_SCOUT
    {1, 1}, // CSW_HEGRENADE
    {1, 1}, // CSW_XM1014
    {-1, -1}, // CSW_C4
    {1, 1}, // CSW_MAC10
    {1, 1}, // CSW_AUG
    {-1, -1}, // CSW_SMOKEGRENADE
    {1, 1}, // CSW_ELITE
    {1, 1}, // CSW_FIVESEVEN
    {1, 1}, // CSW_UMP45
    {1, 1}, // CSW_SG550
    {1, 1}, // CSW_GALIL
    {1, 1}, // CSW_FAMAS
    {1, 1}, // CSW_USP
    {1, 1}, // CSW_GLOCK18
    {1, 1}, // CSW_AWP
    {1, 1}, // CSW_MP5NAVY
    {1, 1}, // CSW_M249
    {1, 1}, // CSW_M3
    {1, 1}, // CSW_M4A1
    {1, 1}, // CSW_TMP
    {1, 1}, // CSW_G3SG1
    {-1, -1}, // CSW_FLASHBANG
    {1, 1}, // CSW_DEAGLE
    {1, 1}, // CSW_SG552
    {1, 1}, // CSW_AK47
    {1, 1}, // CSW_KNIFE
    {1, 1} // CSW_P90
};

public plugin_init()
{
    register_plugin( PLUGIN, VERSION, "ConnorMcLeod" );

    g_iMaxPlayers = get_maxplayers();

    register_event("DeathMsg", "Event_DeathMsg", "a", "1>0");
}

public Event_DeathMsg()
{
    new iKiller = read_data(1);
    if( iKiller > g_iMaxPlayers ) // if killed by entity, exit function
    {
        return;
    }

    new iVictim = read_data(2);

    // if selfkill, or teamkill, exit
    if( iVictim == iKiller || get_user_team(iVictim) == get_user_team(iKiller) )
    {
        return;
    }

    new iWeapon = GetDeathMsgWeaponIndex();

    new iPoints = g_iPointsPerKill[ iWeapon ][ read_data(3) ];
}

GetDeathMsgWeaponIndex(bool:bRegisterMessage = false)
{
    static Trie:tWeaponsIndexes = Invalid_Trie;
    if( tWeaponsIndexes == Invalid_Trie )
    {
        tWeaponsIndexes = TrieCreate();
        const NOT_DMG_WEAPONS_BITSUM = 1<<CSW_C4 | 1<<CSW_SMOKEGRENADE | 1<<CSW_FLASHBANG;
        new szWeaponName[32];
        for(new iId = CSW_P228; iId<=CSW_P90; iId++)
        {
            if( ~NOT_DMG_WEAPONS_BITSUM & 1<<iId )
            {
                if( iId == CSW_HEGRENADE )
                {
                    TrieSetCell(tWeaponsIndexes, "grenade", iId);
                }
                else if( get_weaponname(iId, szWeaponName, charsmax(szWeaponName)) )
                {
                    TrieSetCell(tWeaponsIndexes, szWeaponName[7], iId);
                }
            }
        }
    }

    new szShortWeaponName[32], iWeaponType;
    if( bRegisterMessage )
    {
        get_msg_arg_string(4, szShortWeaponName, charsmax(szShortWeaponName));
    }
    else
    {
        read_data(4, szShortWeaponName, charsmax(szShortWeaponName));
    }
    TrieGetCell(tWeaponsIndexes, szShortWeaponName, iWeaponType);

    return iWeaponType;
} 


easy way with csx module (RECOMMANDED)

PHP Code:

#include < amxmodx >
#include < csx >

#pragma semicolon 1

new g_iMaxPlayers;
#define IsPlayer(%0)    ( 1 <= (%0) <= g_iMaxPlayers )

enum _:pointsPerKill
{
    m_iNormalKillPoints,
    m_iHsKillPoints
}

new const g_iPointsPerKill[][pointsPerKill] = 
{
//    {normal , hs}
    {-1, -1}, // 
    {1, 1}, // CSW_P228
    {-1, -1}, // 
    {1, 1}, // CSW_SCOUT
    {1, 1}, // CSW_HEGRENADE
    {1, 1}, // CSW_XM1014
    {-1, -1}, // CSW_C4
    {1, 1}, // CSW_MAC10
    {1, 1}, // CSW_AUG
    {-1, -1}, // CSW_SMOKEGRENADE
    {1, 1}, // CSW_ELITE
    {1, 1}, // CSW_FIVESEVEN
    {1, 1}, // CSW_UMP45
    {1, 1}, // CSW_SG550
    {1, 1}, // CSW_GALIL
    {1, 1}, // CSW_FAMAS
    {1, 1}, // CSW_USP
    {1, 1}, // CSW_GLOCK18
    {1, 1}, // CSW_AWP
    {1, 1}, // CSW_MP5NAVY
    {1, 1}, // CSW_M249
    {1, 1}, // CSW_M3
    {1, 1}, // CSW_M4A1
    {1, 1}, // CSW_TMP
    {1, 1}, // CSW_G3SG1
    {-1, -1}, // CSW_FLASHBANG
    {1, 1}, // CSW_DEAGLE
    {1, 1}, // CSW_SG552
    {1, 1}, // CSW_AK47
    {1, 1}, // CSW_KNIFE
    {1, 1} // CSW_P90
};

public plugin_init()
{
    register_plugin( PLUGIN, VERSION, "ConnorMcLeod" );

    g_iMaxPlayers = get_maxplayers();
}

public client_death(iKiller, iVictim, iWeapon, iHitPlace, TK)
{
    if( !IsPlayer(iKiller) || iKiller == iVictim || TK )
    {
        return;
    }

    new iPoints = g_iPointsPerKill[ iWeapon ][ iHitPlace == HIT_HEAD ];
}