[Qes]

Hello,
I can not removed Healthshot, because after last update this item has new slot.
Someone know which is the slot?

[root88]

Removing it by slot currently doesn't work. Check this out. You can easily adjust code part near RemovePlayerItem to remove healthshot.

[Qes]

Thanks, it works
// Dziękuję bardzo

[Bacardi]

Originally Posted by root88 Removing it by slot currently doesn't work. Check this out. You can easily adjust code part near RemovePlayerItem to remove healthshot.

Is there reason why need use "offsets" to look "m_hMyWeapons" ?

Isn't this more simple ?

PHP Code:

public void OnPluginStart()
{
    RegConsoleCmd("sm_test", test);

}

public Action test(int client, int args)
{

    char classname[35];
    int m_hMyWeapons_size = GetEntPropArraySize(client, Prop_Send, "m_hMyWeapons"); // array size
    int item;

    for(int index = 0; index < m_hMyWeapons_size; index++)
    {
        item = GetEntPropEnt(client, Prop_Send, "m_hMyWeapons", index);

        if(item != -1)
        {
            GetEntityClassname(item, classname, sizeof(classname));
            PrintToServer("%N has (%i)%s", client, item, classname);
        }
    }

    return Plugin_Handled;
} 


[Franc1sco]

So now this remove all the weapons except Healthshot:

PHP Code:

stock void StripAllWeapons(int client)
{
    int wepIdx;
    for (int i; i < 5; i++)
    {
        while ((wepIdx = GetPlayerWeaponSlot(client, i)) != -1)
        {
            RemovePlayerItem(client, wepIdx);
            AcceptEntityInput(wepIdx, "Kill");
        }
    }
} 


And now to remove all the weapons should be like this:

PHP Code:

stock void StripAllWeapons(int client)
{
    int m_hMyWeapons_size = GetEntPropArraySize(client, Prop_Send, "m_hMyWeapons"); // array size 
    int item; 

    for(int index = 0; index < m_hMyWeapons_size; index++) 
    { 
        item = GetEntPropEnt(client, Prop_Send, "m_hMyWeapons", index); 

        if(item != -1) 
        { 
            RemovePlayerItem(client, item);
            AcceptEntityInput(item, "Kill");
        } 
    } 
} 


Correct? time to update some plugins

[Bacardi]

...I changed variable name later before posting, shuold be now item, not weapon
sry

*edit
I wanted to know, why we go back "offsets" like... 5 years ago or somewhere that

[Franc1sco]

Originally Posted by Bacardi ...I changed variable name later before posting, shuold be now item, not weapon sry

Ohh, I had not realized. I edited my post too.