[CowGod]

so right now I made it so when a player types test in chat it does a mini explosion and kills them, but what if I wanted it to be the c4 explosion xD any help would be appreciated thanks

[Farbror Godis]

Are you using "env_explosion"? If so, you could set it's magnitude to a very large number:

PHP Code:

float position[3];
GetClientAbsOrigin(client, position);

int explosion;
if((explosion = CreateEntityByName("env_explosion")) != -1) {
    DispatchKeyValue(explosion, "classname", "env_explosion");
    DispatchKeyValue(explosion, "iMagnitude", "16000");

    DispatchKeyValueVector(explosion, "Origin", position);

    if(DispatchSpawn(explosion)) {
        ActivateEntity(explosion);

        AcceptEntityInput(explosion, "Explode");
        AcceptEntityInput(explosion, "Kill");
    }
} 


This would have the (un)fortunate effect of killing everyone around the player as well, perhaps you should go with what xines proposed.

[xines]

Don't think Cod supports this

Joke aside, as this is the scripting section, and no script was posted i consider this to be wrong section.

For your problem, you properly want to use the c4 explosion particle effect and make it spawn at client position when typing your command and slay them.

[CowGod]

Originally Posted by xines Don't think Cod supports this Joke aside, as this is the scripting section, and no script was posted i consider this to be wrong section. For your problem, you properly want to use the c4 explosion particle effect and make it spawn at client position when typing your command and slay them.

Sorry if this is wrong section, how would I go about using the c4 explosion particle effect? I would be grateful to learn

[xines]

Originally Posted by CowGod Sorry if this is wrong section, how would I go about using the c4 explosion particle effect? I would be grateful to learn

First i would like to know what game is this for ?

[CowGod]

Originally Posted by xines First i would like to know what game is this for ?

CSGO

[xines]

Originally Posted by CowGod CSGO

Contact me on steam, and i'll give it a go.

Script will be posted for others to use, because sharing is caring.

[Neuro Toxin]

My lame COD joke is infecting the community...

[xines]

Here is the finish product:

Working CS:GO:

Just change the text "cringe" in the source code to whatever needed.

PHP Code:

#include <sourcemod>
#include <sdktools>

int g_MyBomb[MAXPLAYERS+1];

public Plugin myinfo = 
{
    name = "Xines",
    author = "Bomb Explosion Death Particle",
    description = "Performs a bomb explosion by typing a ingame specific word",
    version = "1.0",
    url = ""
};

public void OnClientSayCommand_Post(int client, const char[] command, const char[] sArgs)
{
    if (strcmp(sArgs, "cringe", false) == 0)
    {
        if (client > 0 && IsClientInGame(client) && IsPlayerAlive(client))
        {
            float clientPos[3];
            GetClientAbsOrigin(client, clientPos);
            DropExplosion(client, clientPos);
            EmitAmbientSound("weapons/c4/c4_explode1.wav", NULL_VECTOR, client);
            ForcePlayerSuicide(client);
        }
    }
}

public void DropExplosion(int client, float pos[3])
{
    g_MyBomb[client] = CreateEntityByName("info_particle_system");
    DispatchKeyValue(g_MyBomb[client], "start_active", "0");
    DispatchKeyValue(g_MyBomb[client], "effect_name", "explosion_c4_500");
    DispatchSpawn(g_MyBomb[client]);
    TeleportEntity(g_MyBomb[client], pos, NULL_VECTOR, NULL_VECTOR);
    ActivateEntity(g_MyBomb[client]);
    SetVariantString("!activator");
    AcceptEntityInput(g_MyBomb[client], "SetParent", g_MyBomb[client], g_MyBomb[client], 0);
    CreateTimer(0.25, Timer_Run, g_MyBomb[client]);
}

public Action Timer_Run(Handle timer, any ent)
{
    if(ent > 0 && IsValidEntity(ent))
    {
        AcceptEntityInput(ent, "Start"); //Start Particle
        CreateTimer(7.0, Timer_Die, ent); //Timer to end particle
    }
}

public Action Timer_Die(Handle timer, any ent)
{
    if(ent > 0 && IsValidEntity(ent))
    {
        if(IsValidEdict(ent))
        {
            AcceptEntityInput(ent, "Kill");
        }
    }
}