[Gashi]

hello,

i saw this Thread @ http://forums.alliedmods.net/showthread.php?t=227995

And i need exactly this plugin, but this doenst work fine:

PHP Code:

#include <sourcemod>
#include <sdktools>

new bool:g_Round;
new g_Count;

public Plugin:myinfo = 
{
    name = "l4d2_duration",
    author = "RU_6uK",
    description = "Duration of map played",
    version = "0.0",
    url = "http://forums.alliedmods.net"
}

public OnPluginStart()
{
    HookEvent(    "round_start",    Event_Round    );
    HookEvent(    "round_end",    Event_Round    );
}

public OnMapStart()
{
    g_Round = true;
}

public Action:Event_Round(Handle:event, const String:name[], bool:dontBroadcast)  
{
    if ( g_Round == true )
    {
        g_Count = 0;
        CreateTimer( 1.0, Timer_RoundCount, _, TIMER_REPEAT|TIMER_FLAG_NO_MAPCHANGE );
        g_Round = false;
    }
    else
    {
        g_Round = true;
    }
}

public Action:Timer_RoundCount( Handle:timer, any:client )
{
    g_Count ++;
    if ( g_Round == false )
    {
        return Plugin_Continue;
    }
    else
    {
        // Do the math here.. i lazy
        // Note that the timer ticking every 1.0 sec once. With +1 sec gape.
        new min = g_Count/60;
        new sec = g_Count - min;
        
        
        PrintToChatAll( "[ROUNDDURATION]: %d min | %d sec", min, sec );
    }
    return Plugin_Stop;
} 


But it shows me [ROUNDDURATION]: 6 min | 122 sec

Or if a say slay @all it shows: [ROUNDDURATION]: 0 min | 15 sec (= always)

Iam a noob, how can i fix this?

Thanks in advance

[Gugie]

new sec = g_Count - min*60;

[Gashi]

Originally Posted by Gugie new sec = g_Count - min*60;

Thank you! I will try it later ;)

[noxman]

Sometimes it works, sometimes it shows:

[ROUNDDURATION] 0 min | 15 sec

What is wrong with the code??

[RU_6uK]

W/o timer, not tested.

PHP Code:

new Float:g_fSeconds;

public OnPluginStart()
{
    HookEvent("round_start", Event_RoundStart, EventHookMode_PostNoCopy);
    HookEvent("round_end", Event_RoundEnd, EventHookMode_PostNoCopy);
}

public Action:Event_RoundStart(Handle:event, const String:name[], bool:dontBroadcast)
{
    g_fSeconds = GetEngineTime();
}

public Action:Event_RoundEnd(Handle:event, const String:name[], bool:dontBroadcast)
{
    new secDiff = RoundToFloor(GetEngineTime() - g_fSeconds);
    PrintToChatAll("[ROUNDDURATION]: %02i min | %02i sec", secDiff / 60, secDiff % 60);
} 


[noxman]

Originally Posted by RU_6uK W/o timer, not tested.

Thanks. It works, but one little bug:

If the round is end it shows: [ROUNDDURATION] 5 min | 10 sec ( = right)

but after 10 sec a new message comes up: [ROUNDDURATION] 5min | 20 sec

Bugg: On round_end the message come 2 times. hmmm

[RU_6uK]

It's game bug, when event fires several times.

PHP Code:

new Float:g_fSeconds;
new bool:g_bRoundEnd;

public OnPluginStart()
{
    HookEvent("round_start", Event_RoundStart, EventHookMode_PostNoCopy);
    HookEvent("round_end", Event_RoundEnd, EventHookMode_PostNoCopy);
}

public Action:Event_RoundStart(Handle:event, const String:name[], bool:dontBroadcast)
{
    g_fSeconds = GetEngineTime();
    g_bRoundEnd = false;
}

public Action:Event_RoundEnd(Handle:event, const String:name[], bool:dontBroadcast)
{
    if(!g_bRoundEnd) {
        new secDiff = RoundToFloor(GetEngineTime() - g_fSeconds);
        PrintToChatAll("[ROUNDDURATION]: %02i min | %02i sec", secDiff / 60, secDiff % 60);
        g_bRoundEnd = true;
    }
} 


[noxman]

Originally Posted by RU_6uK It's game bug, when event fires several times. PHP Code: new Float:g_fSeconds; new bool:g_bRoundEnd; public OnPluginStart() {     HookEvent("round_start", Event_RoundStart, EventHookMode_PostNoCopy);     HookEvent("round_end", Event_RoundEnd, EventHookMode_PostNoCopy); } public Action:Event_RoundStart(Handle:event, const String:name[], bool:dontBroadcast) {     g_fSeconds = GetEngineTime();     g_bRoundEnd = false; } public Action:Event_RoundEnd(Handle:event, const String:name[], bool:dontBroadcast) {     if(!g_bRoundEnd) {         new secDiff = RoundToFloor(GetEngineTime() - g_fSeconds);         PrintToChatAll("[ROUNDDURATION]: %02i min | %02i sec", secDiff / 60, secDiff % 60);         g_bRoundEnd = true;     } }

This one works perfect. Thank you

[alasfourom]

Updating it, and adding "sm_duration" command

PHP Code:

float g_fSeconds;
bool g_bRoundEnd;

public Plugin myinfo = 
{
    name = "Round Duration",
    author = "RU_6uK, alasfourom",
    description = "Print Current Round Duration",
    version = "1.0",
    url = "https://forums.alliedmods.net/"
};

public void OnPluginStart()
{
    HookEvent("round_start", Event_RoundStart);
    HookEvent("round_end", Event_RoundEnd);

    RegConsoleCmd("sm_duration", Duration, "Print Round Duration To Chat");
}

public Action Event_RoundStart(Event event, const char[] name, bool dontBroadcast)
{
    g_fSeconds = GetEngineTime();
    g_bRoundEnd = false;
    return Plugin_Handled;
}

public Action Duration(int client, int args)
{
    int secDiff = RoundToFloor(GetEngineTime() - g_fSeconds);
    ReplyToCommand(client, "\x04Round Duration: \x03%i min %i sec", secDiff / 60, secDiff % 60);
    return Plugin_Handled;
}

//Printing Round Duration At The End Of The Round
public Action Event_RoundEnd(Event event, const char[] name, bool dontBroadcast)
{
    if(!g_bRoundEnd) {
        int secDiff = RoundToFloor(GetEngineTime() - g_fSeconds);
        PrintToChatAll("\x04Round Duration: \x03%i min %i sec", secDiff / 60, secDiff % 60);
        g_bRoundEnd = true;
    }
    return Plugin_Handled;
}