[ghost95v]

i use this zombie class tight for double jump , but it not having any double jump ,, i use ZPA 1.6.1 anyone can fix something pls ? thank you

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <engine>
#include <fakemeta>
#include <zombieplague>

new jumpznum[33] = 0
new bool:dozjump[33] = false
new cvar_jumps
new g_zclass_tight

// Tight Atributes
new const zclass_name[] = { "tight" } // name
new const zclass_info[] = { "Double Jump" } // description
new const zclass_model[] = { "zombie_source" } // model
new const zclass_clawmodel[] = { "v_knife_zombie.mdl" } // claw model
const zclass_health = 4500 // health
const zclass_speed = 269 // speed
const Float:zclass_gravity = 0.7 // gravity
const Float:zclass_knockback = 1.3 // knockback

public plugin_init()
{
    register_plugin("Class tight", "1.0c", "MultiJump by twistedeuphoria, Plagued by Dabbi, Classed by B!gBud")
    cvar_jumps = register_cvar("zp_tight_jump","2")    
}

public plugin_precache()
{
    g_zclass_tight = zp_register_zombie_class(zclass_name, zclass_info, zclass_model, zclass_clawmodel, zclass_health, zclass_speed, zclass_gravity, zclass_knockback)
}

public client_putinserver(id)
{
    jumpznum[id] = 0
    dozjump[id] = false
}

public client_disconnect(id)
{
    jumpznum[id] = 0
    dozjump[id] = false
}

public client_PreThink(id)
{
    if(!is_user_alive(id) || !zp_get_user_zombie(id)) return PLUGIN_CONTINUE
    if(zp_get_user_zombie_class(id) != g_zclass_tight) return PLUGIN_CONTINUE
    
    new nzbut = get_user_button(id)
    new ozbut = get_user_oldbutton(id)
    if((nzbut & IN_JUMP) && !(get_entity_flags(id) & FL_ONGROUND) && !(ozbut & IN_JUMP))
    {
        if (jumpznum[id] < get_pcvar_num(cvar_jumps))
        {
            dozjump[id] = true
            jumpznum[id]++
            return PLUGIN_CONTINUE
        }
    }
    if((nzbut & IN_JUMP) && (get_entity_flags(id) & FL_ONGROUND))
    {
        jumpznum[id] = 0
        return PLUGIN_CONTINUE
    }    
    return PLUGIN_CONTINUE
}

public client_PostThink(id)
{
    if(!is_user_alive(id) || !zp_get_user_zombie(id)) return PLUGIN_CONTINUE
    if(zp_get_user_zombie_class(id) != g_zclass_tight) return PLUGIN_CONTINUE
    
    if(dozjump[id] == true)
    {
        new Float:vezlocityz[3]    
        entity_get_vector(id,EV_VEC_velocity,vezlocityz)
        vezlocityz[2] = random_float(265.0,285.0)
        entity_set_vector(id,EV_VEC_velocity,vezlocityz)
        dozjump[id] = false
        return PLUGIN_CONTINUE
    }    
    return PLUGIN_CONTINUE
} 


[Krtola]

Plugin works fine I tested and I use it.
I do not know if it is intended for ZPA 1.6.1.

[ghost95v]

Originally Posted by Krtola Plugin works fine I tested and I use it. I do not know if it is intended for ZPA 1.6.1.

i dont know why

[zmd94]

Just use this version. I have tested it in ZPA and it is working well. ;)

Jumper Zombie v2 (This Jumper Zombie do not use PreThink code. So, it don't cause lag to your server)

[ghost95v]

Originally Posted by zmd94 Just use this version. I have tested it in ZPA and it is working well. ;) Jumper Zombie v2 (This Jumper Zombie do not use PreThink code. So, it don't cause lag to your server)

Thank you man, but when i choose this Class , and when new round starts im still having multijump also when i am human . and it's giving triplejump not double ... anyway thank you

[Krtola]

I corrected it. Try now:

PHP Code:

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>
#include <zombieplague>

new _gJumpCount[33]
new cvar_multi_jump_amount
new g_zclass_jumper

new const zclass_name[] = {"Jumper"} 
new const zclass_info[] = {"Double Jump"} 
new const zclass_model[] = {"zombie_source"} 
new const zclass_clawmodel[] = {"v_knife_zombie.mdl"}
const zclass_health = 2500 
const zclass_speed = 269 
const Float:zclass_gravity = 0.7 
const Float:zclass_knockback = 1.3 

public plugin_init() 
{
    register_plugin("[ZP] Zombie Class: Jumper", "1.0", "zmd94")
    RegisterHam(Ham_Player_Jump, "player", "fw_PlayerJump", 0)
    
    cvar_multi_jump_amount = register_cvar("zp_multi_jump_amount", "2")
}

public plugin_precache()
{
    g_zclass_jumper = zp_register_zombie_class(zclass_name, zclass_info, zclass_model, zclass_clawmodel, zclass_health, zclass_speed, zclass_gravity, zclass_knockback)
}

public fw_PlayerJump(id) 
{
        if(!is_user_alive(id) || !zp_get_user_zombie(id))
    {
        return HAM_SUPERCEDE
    }

    if(is_user_alive(id) && zp_get_user_zombie_class(id) == g_zclass_jumper) 
    {
        new Flags = pev(id, pev_flags)
        
        if( Flags & FL_WATERJUMP || pev(id, pev_waterlevel) >= 2 || !(get_pdata_int(id, 246) & IN_JUMP) )
        {
            return HAM_IGNORED
        }
        if(Flags & FL_ONGROUND) 
        {
            _gJumpCount[id] = 0
            
            return HAM_IGNORED
        }
        if(get_pcvar_num(cvar_multi_jump_amount)) 
        {
            if( get_pdata_float(id, 251) < 500 && ++_gJumpCount[id] <= get_pcvar_num(cvar_multi_jump_amount)) 
            {
                new Float:fVelocity[3]
                pev(id, pev_velocity, fVelocity)
                fVelocity[2] = 268.328157
                set_pev(id, pev_velocity, fVelocity)
                
                return HAM_HANDLED
            }
        }
    }
    return HAM_IGNORED
} 


I just added a check if the player is dead and that's not a zombie in "public fw_PlayerJump(id)"

PHP Code:

if(!is_user_alive(id) || !zp_get_user_zombie(id))
{
    return HAM_SUPERCEDE
} 


Use this cvar for jump amount

PHP Code:

zp_multi_jump_amount 


If you set 2 zombi will jump 3x in the mid air. If you set 1 zombi jump 2x....

[zmd94]

I have update the code. ;)

Thank you to Krtola.

[ghost95v]

Thank you guys
i updated again , cuz complier was not finding this symbol: is_user_zombie
Now its fixed , not more multijump remains in new round , but,,, still its giving me triplejump , and i addet to "1" cvar_multi_jump_amount.

PHP Code:

if(!is_user_alive(id) || !zp_get_user_zombie(id))
     {
        return HAM_SUPERCEDE
     } 


[Krtola]

Sorry for "is_user_zombie" that is for my biohazard mod
wryte in amxx.cfg
zp_multi_jump_amount 1

[ghost95v]

Originally Posted by Krtola Sorry for "is_user_zombie" that is for my biohazard mod wryte in amxx.cfg zp_multi_jump_amount 1

Works Perfect now .. Thank you so much