[CsIosefin]

Hi,
I know there are plugin "Time Played" Mr Alka's, but I want something similar but much simpler (not that I be with other stuff, if not used ...)
What I was I calculate time spent on your server (all, after all saved each reconecare be named).
What I want, when you order in chat "/ h" appears like "your accumulated hours are: 1 hour 22 minute 33 seconds."
Do you guys that can do something simple and good? Waiting for a reply, thanks.

[CsIosefin]

Up!

[Arkshine]

Read the rules, you have to wait 15 days from your last posts. Be patient and learn the pawn. Also you have posted in the wrong forum, since you are not willing to learn, you should have posted in the request section.

[Dygear]

new Int:time = get_user_time(id);
new Int:h = (time / 3600) % 60;
new Int:m = ((time - (h * 3600)) / 60) % 60;
new Int:s = time - ((h * 3600) + (m * 60));

client_print(id, print_chat, "Has been playing for %d hours, %d minutes, %d seconds", h, m, s);

[Sylwester]

not tested:

PHP Code:

#include <amxmodx>
#include <nvault>

new g_auth[33][24]
new g_time_played[33]
new g_connect_time[33]
new g_db_name[] = "time_played"

public plugin_init(){
    register_plugin("Player Time Played", "1.0", "Sylwester")
    register_clcmd("say /h", "show_time")
}

public show_time(id){
    if(g_time_played[id] == -1){
        client_print(id, print_chat, "Server was unable to retrieve your time played.")
        return
    }
    new t = time()-g_connect_time[id]+g_time_played[id]
    new h = t/3600
    new m = t/60%60
    new s = t%60
    client_print(id, print_chat, "Your total time played is: %d hour%s %d minute%s %d second%s.",
    h, h==1?"":"s", m, m==1?"":"s", s, s==1?"":"s")
}

public client_connect(id)
    g_auth[id][0] = '^0'
    
public client_putinserver(id)
    g_connect_time[id] = time()

public client_authorized(id){
    get_user_authid(id, g_auth[id], 23)
    new nv_hnd = nvault_open(g_db_name)
    if(nv_hnd == INVALID_HANDLE){
        log_amx("Failed to open nVault %s.", g_db_name)
        g_time_played[id] = -1
        return
    }
    new data[10], ts
    if(!nvault_lookup(nv_hnd, g_auth[id], data, 9, ts))
        g_time_played[id] = 0
    else
        g_time_played[id] = str_to_num(data)
    nvault_close(nv_hnd)
}

public client_disconnect(id){
    if(g_auth[id][0] == '^0' || g_time_played[id] == -1)
        return
    new nv_hnd = nvault_open(g_db_name)
    new data[10]
    formatex(data, 9, "%d", time()-g_connect_time[id]+g_time_played[id])
    nvault_set(nv_hnd, g_auth[id], data)
    nvault_close(nv_hnd)
} 


[Dygear]

PHP Code:

    $h = $time / 3600;
    $m = $time / 60 % 60;
    $s = $time % 60; 


Beautiful code, Sylwester. Casting to int solves the rounding issue, and that's done by the %d modifier.

[Dygear]

My answer in 21 lines of code.

#include <amxmodx>

#define getSeconds(%1)  (%1 % 60)
#define getMinutes(%1)  (%1 / 60 % 60)
#define getHours(%1)    (%1 / 3600)
#define getPlural(%1)   ((%1 != 1) ? "s" : "")

public plugin_init() {
    register_plugin("Play Time", "1.0", "Dygear");
    register_clcmd("say /h", "getPlayTime");
}

public getPlayTime(id) {
    new time = get_user_time(id);
    new h = getHours(time), i = getMinutes(time), s = getSeconds(time);
    client_print(
        id, print_chat,
        "Your accumulated hours are: %d hour%s %d minute%s and %d second%s.",
        h, getPlural(h), i, getPlural(i), s, getPlural(s)
    );
}

Welcome to the AMX Mod X 1.8.1-300 Compiler.
Copyright (c) 1997-2006 ITB CompuPhase, AMX Mod X Team

Header size:            204 bytes
Code size:              596 bytes
Data size:              468 bytes
Stack/heap size:      16384 bytes; estimated max. usage=40 cells (160 bytes)
Total requirements:   17652 bytes
Done.

[g_often]

Originally Posted by Dygear My answer in 21 lines of code. Code: #include <amxmodx> #define getSeconds(%1)&nbsp;&nbsp;&nbsp;&nbsp;(%1 % 60) #define getMinutes(%1)&nbsp;&nbsp;&nbsp;&nbsp;(%1 / 60 % 60) #define getHours(%1)&nbsp;&nbsp;&nbsp;&nbsp;(%1 / 3600) #define getPlural(%1)&nbsp;&nbsp;&nbsp;&nbsp;((%1 != 1) ? "s" : "") public plugin_init() { &nbsp;&nbsp;&nbsp;&nbsp;register_plugin("Play Time", "1.0", "Dygear"); &nbsp;&nbsp;&nbsp;&nbsp;register_clcmd("say /h", "getPlayTime"); } public getPlayTime(id) { &nbsp;&nbsp;&nbsp;&nbsp;new time = get_user_time(id); &nbsp;&nbsp;&nbsp;&nbsp;new h = getHours(time), i = getMinutes(time), s = getSeconds(time); &nbsp;&nbsp;&nbsp;&nbsp;client_print( &nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nb sp;id, print_chat, &nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nb sp;"Your accumulated hours are: %d hour%s %d minute%s and %d second%s.", &nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nb sp;h, getPlural(h), i, getPlural(i), s, getPlural(s) &nbsp;&nbsp;&nbsp;&nbsp;); } Welcome to the AMX Mod X 1.8.1-300 Compiler. Copyright (c) 1997-2006 ITB CompuPhase, AMX Mod X Team Header size: 204 bytes Code size: 596 bytes Data size: 468 bytes Stack/heap size: 16384 bytes; estimated max. usage=40 cells (160 bytes) Total requirements: 17652 bytes Done.

nice code! this work perfectly.

[Seta00]

It may be perfect, but it doesn't do what the thread author has requested.
He wants to save the time in a way that when the client reconnects his time is recovered.
Sylwester code seems to work just fine.

[g_often]

PHP Code:

#include <amxmodx>

public plugin_init() register_clcmd("say /h","GetTime")

public GetTime(id){
    new time  = get_user_time(id)
    new h = time / 3600, m = time / 60 % 60, s = time % 60
    
    client_print(id, print_chat, "Time Playing: Hours %d, Minutes: %d, Seconds: %d",h,m,s)
} 


this work too, but... i don't understend very well for wath is the symbol "%", example

PHP Code:

s = time % 60