[newb1e]

hi. how can i add here a function that will show another player rank if you are spectating him?

PHP Code:

public Info() {
    for(new id = 1; id <= MaxPlayers; id++)
    {
        if(is_user_alive(id) && is_user_connected(id))
        {
            if(PlayerLevel[id] <= 18)
            {
                needXP[id] = LEVELS[PlayerLevel[id]] - PlayerXP[id];
                set_hudmessage(100, 100, 100, 0.01, 0.15, 0, 1.0, 1.0, _, _, -1)
                static buffer[192], len;
                len = format(buffer, charsmax(buffer), "%L",LANG_PLAYER,"RANK");
                len += format(buffer[len], charsmax(buffer) - len, " %L",LANG_PLAYER,RANKS[PlayerLevel[id]]);
                len += format(buffer[len], charsmax(buffer) - len, "^n%L %d",LANG_PLAYER,"PL_XP",PlayerXP[id]);
                len += format(buffer[len], charsmax(buffer) - len, "^n%L",LANG_PLAYER,"NEXT_LVL");
                len += format(buffer[len], charsmax(buffer) - len, " %d ",needXP[id]);
                len += format(buffer[len], charsmax(buffer) - len, "%L",LANG_PLAYER,"FRAGS");
                ShowSyncHudMsg(id, g_MsgHud, "%s", buffer);
            } else {
                set_hudmessage(100, 100, 100, 0.01, 0.13, 0, 1.0, 1.0, _, _, -1)
                static buffer[192], len;
                len = format(buffer, charsmax(buffer), "%L",LANG_PLAYER,"RANK");
                len += format(buffer[len], charsmax(buffer) - len, " %L",LANG_PLAYER,RANKS[PlayerLevel[id]]);
                len += format(buffer[len], charsmax(buffer) - len, "^n%L",LANG_PLAYER,"PL_MAX");
                ShowSyncHudMsg(id, g_MsgHud, "%s", buffer);
            }
        }
        // if i'm dead, hide my rank
        return PLUGIN_HANDLED
    }
    return PLUGIN_CONTINUE
} 


[Kakarot47]

Show full code

[Croxeye]

Try this, not tested.

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <csstats>
#include <fakemeta>

#define PLUGIN "Spec Rank"
#define VERSION "1.0"
#define AUTHOR "Croxeye"

new g_SpecInfo

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)

    set_task(1.0, "SpecInfo", _, _, _, "b")

    g_SpecInfo = CreateHudSyncObj()
}

public SpecInfo()
{
    new players[32], num 
    get_players(players, num, "ch")
    
    new id, target, szTargetName[32]
    
    target = pev(id, pev_iuser2)
    
    set_hudmessage(0, 85, 255, -1.0, 0.75, 0, 6.0, 1.0)
    
    for(new i; i < num; i++)
    {
        id = players[i]
        
        if(!is_user_alive(id))
        {
            
            if(!target)
                continue
                
            if(is_user_alive(target))
            {
                return PLUGIN_HANDLED;
            }
            
            get_user_name(target, szTargetName, charsmax(szTargetName))
            new stats[8], body[8]
            new rank_pos = get_user_stats(target, stats, body)
            new rank_max = get_statsnum()
            
            ShowSyncHudMsg(id, g_SpecInfo, "Spectating: %s ® Rank: %d of %d", szTargetName, rank_pos, rank_max)
        }
    }
    return PLUGIN_HANDLED;
} 


Or just change this:

PHP Code:

len = format(buffer, charsmax(buffer), "%L",LANG_PLAYER,"RANK"); 


to this:

PHP Code:

len = format(buffer, charsmax(buffer), "%L %d",LANG_PLAYER,"RANK", rank_pos); 


and you need to define rank_pos

PHP Code:

new stats[8], body[8]
new rank_pos = get_user_stats(id, stats, body) 


[newb1e]

Originally Posted by Croxeye Try this, not tested. PHP Code: #include <amxmodx> #include <amxmisc> #include <csstats> #include <fakemeta> #define PLUGIN "Spec Rank" #define VERSION "1.0" #define AUTHOR "Croxeye" new g_SpecInfo public plugin_init() {     register_plugin(PLUGIN, VERSION, AUTHOR)     set_task(1.0, "SpecInfo", _, _, _, "b")     g_SpecInfo = CreateHudSyncObj() } public SpecInfo() {     new players[32], num      get_players(players, num, "ch")          new id, target, szTargetName[32]          target = pev(id, pev_iuser2)          set_hudmessage(0, 85, 255, -1.0, 0.75, 0, 6.0, 1.0)          for(new i; i < num; i++)     {         id = players[i]                  if(!is_user_alive(id))         {                          if(!target)                 continue                              if(is_user_alive(target))             {                 return PLUGIN_HANDLED;             }                          get_user_name(target, szTargetName, charsmax(szTargetName))             new stats[8], body[8]             new rank_pos = get_user_stats(target, stats, body)             new rank_max = get_statsnum()                          ShowSyncHudMsg(id, g_SpecInfo, "Spectating: %s ® Rank: %d of %d", szTargetName, rank_pos, rank_max)         }     }     return PLUGIN_HANDLED; }  Or just change this: PHP Code: len = format(buffer, charsmax(buffer), "%L",LANG_PLAYER,"RANK");  to this: PHP Code: len = format(buffer, charsmax(buffer), "%L %d",LANG_PLAYER,"RANK", rank_pos);  and you need to define rank_pos PHP Code: new stats[8], body[8] new rank_pos = get_user_stats(id, stats, body)

not working mate

[1ka]

i need
show player (kills deaths) while spectating
(not in map k.d., need full stats kills and deaths

i know i want
get_user_stats(id, stats, body);
stats[0]
stats[1]
but i cant write script

[Bugsy]

I'm not sure how much this will affect server performance, you may see impacts if your csstats.dat file is large. I couldn't test this because I have only bots to work with and they are not ranked in my test configuration.

I used ConnorMcLeod's Spectator Hud Information as a base and made some modifications.

PHP Code:

//Used ConnorMcLeods plugin as base: https://forums.alliedmods.net/showthread.php?p=1469706

#include <amxmodx>
#include <engine>
#include <csx>

new const Version[] = "0.1";

const FirstPersonView = 4;
const Float:fRefreshInterval = 0.25;

new g_HUDSyncObj;

public plugin_init() 
{
    register_plugin( "Spec Rank Info" , Version , "bugsy" );
    
    new iEntity = create_entity( "info_target" );
    entity_set_string( iEntity , EV_SZ_classname , "SpecHUDEntity" );
    register_think( "SpecHUDEntity" , "SpecHUDThink" );
    entity_set_float( iEntity , EV_FL_nextthink , get_gametime() + fRefreshInterval );
    
    g_HUDSyncObj = CreateHudSyncObj();
}

public SpecHUDThink( iEntity )
{
    new iAlivePlayers[ 32 ] , iDeadPlayers[ 32 ] , iAliveNum , iDeadNum , iAlivePlayer , iDeadPlayer;
    new iRank , iStats[ 8 ] , iBodyHits[ 8 ] , szName[ 32 ] , bool:bRetrievedData;
    
    entity_set_float( iEntity , EV_FL_nextthink , get_gametime() + fRefreshInterval );
    
    get_players( iAlivePlayers , iAliveNum , "a" );
    
    if( !iAliveNum )
        return
    
    get_players( iDeadPlayers , iDeadNum , "bch" );
    
    if( !iDeadNum )
        return    
    
    for ( new iAlive = 0 ; iAlive < iAliveNum ; iAlive++ )
    {
        iAlivePlayer = iAlivePlayers[ iAlive ];
        
        bRetrievedData = false;
        
        for( new iDead = 0 ; iDead < iDeadNum ; iDead++ )
        {
            iDeadPlayer = iDeadPlayers[ iDead ];
            
            if ( entity_get_int( iDeadPlayer , EV_INT_iuser2 ) == iAlivePlayer && entity_get_int( iDeadPlayer , EV_INT_iuser1 ) == FirstPersonView )
            {
                if ( bRetrievedData == false )
                {
                    get_user_name( iAlivePlayer , szName , charsmax( szName ) );
                    iRank = get_user_stats( iAlivePlayer , iStats , iBodyHits );
                    bRetrievedData = true;
                }
                
                ClearSyncHud( iDeadPlayer , g_HUDSyncObj );
                set_hudmessage( 255 , 255 , 255 , -1.0 , 0.25 , .holdtime=0.5 , .channel=-1 );
                ShowSyncHudMsg( iDeadPlayer , g_HUDSyncObj , "%s^nRank: %d^nKills: %d^nDeaths: %d" , szName , iRank , iStats[ 0 ] , iStats[ 1 ] );
            }
        }
    }
}