[redivcram]

Does nvault_pset literally update a key without a timestamp or does it still set a timestamp but a permanent one? I want to know whether I can update a key with nvault_pset which has been created (previously set) with nvault_set, but without touching its timestamp.

[Bugsy]

All pset does is set the timestamp to 0, so there is no timestamp on permanent records.

[redivcram]

Really? Pity you couldn't do the opposite of nvault_touch; Updating the key's data without touching its timestamp...

[Bugsy]

The fact that the timestamp is 0 makes it a permanent record. There is no separate field in a vault record that would allow both a timestamp and permanent status. So you can make a set record permanent by touching it with 0.

[redivcram]

I don't believe I've made myself clear enough. I want to update the key's data without changing its current timestamp. I assumed nvault_pset would not touch the key's timestamp at all instead of actually setting it to 0 making it permanent.

[Bugsy]

So what you need to do is use nvault_lookup() which allows you to get the current timestamp. Then call set or pset, followed by a touch using the timestamp retrieved with lookup.

[redivcram]

Jeez, all this time no one really bothered turning all of that improvisation into one nvault_update ish method? Confusing at first glance, let alone never came to mind. As long as It's possible to achieve my goal, It's good. Thanks! Haven't tested it, yet.

[Bugsy]

If you're touching the data the timestamp should theoretically reflect that.

[redivcram]

PHP Code:

#include <amxmodx>
#include <nvault>

new gVault;

public plugin_init() {
    
    register_plugin("nVault Update Test", "1.0", "Cram");
    
    gVault = nvault_open("nvault_update-test");
    
    register_clcmd("nvault_set", "CmdSet");
    register_clcmd("nvault_get", "CmdGet");
    register_clcmd("nvault_update", "CmdUpdate");
}

public plugin_end() {
    
    nvault_close(gVault);
}

public CmdSet(id) {
    
    new szArgv[16];
    read_argv(1, szArgv, charsmax(szArgv));
    
    SetVaultData(id, szArgv);
    
    console_print(id, "^n[NVAULT SET]^nSaved data to nVault:^n%s^n", szArgv);
    
    return PLUGIN_HANDLED;
}

public CmdGet(id) {
    
    new szAuthID[32], szData[16], iTimeStamp;
    
    get_user_authid(id, szAuthID, charsmax(szAuthID));
    
    if(nvault_lookup(gVault, szAuthID, szData, charsmax(szData), iTimeStamp))
        console_print(id, "^n[NVAULT GET]^nData: %s^nTimestamp: %d^n", szData, iTimeStamp);
    else
        console_print(id, "^n[NVAULT GET] No data found.^n");
        
    return PLUGIN_HANDLED;
}

public CmdUpdate(id) {
    
    new szAuthID[32], szData[16], iTimeStamp, szArgv[16];
    
    get_user_authid(id, szAuthID, charsmax(szAuthID));
    read_argv(1, szArgv, charsmax(szArgv));
    
    if(nvault_lookup(gVault, szAuthID, szData, charsmax(szData), iTimeStamp)) {
        
        nvault_pset(gVault, szAuthID, szArgv);
        nvault_touch(gVault, szAuthID, iTimeStamp);
        
        console_print(id, "^n[NVAULT UPDATE]^nUpdated data in nVault:^nOld Value: %s^nNew Value: %s^n", szData, szArgv);
    }
    else {
        
        SetVaultData(id, szArgv);
        
        console_print(id, "^n[NVAULT UPDATE] No initial data found to update.^nSet new data instead.^n");
    }
    
    return PLUGIN_HANDLED;
}

SetVaultData(id, szData[]) {
    
    new szAuthID[32];
    
    get_user_authid(id, szAuthID, charsmax(szAuthID));
    
    nvault_set(gVault, szAuthID, szData);
    
    return PLUGIN_HANDLED;
} 


Worked fine for me. Timestamp remains the same when using Update instead of Set for the second time.