[ditmesteam]

May anyone make plugin anti-fast change name?
All players only can change their name interval 10 minute
For example they can change their name 3 times in 30 minutes of one map (10 minute for one change name)
Thank you in advanced.

[Exolent[jNr]]

#include < amxmodx >

// interval between name changes in seconds
#define NAME_CHANGE_WAIT 10

new Float:g_fLastNameChange[ 33 ];

public plugin_init( )
{
    register_plugin( "Name Change Wait", "0.0.1", "Exolent" );
    
    register_message( get_user_msgid( "SayText" ), "MessageSayText" );
}

public client_disconnect( iPlayer )
{
    g_fLastNameChange[ iPlayer ] = 0.0;
}

public client_infochanged( iPlayer )
{
    new szNewName[ 32 ], szOldName[ 32 ];
    get_user_info( iPlayer, "name", szNewName, 31 );
    get_user_name( iPlayer, szOldName, 31 );
    
    if( !equal( szNewName, szOldName ) )
    {
        new Float:fGametime = get_gametime( );
        new Float:fDiff = g_fLastNameChange[ iPlayer ] + NAME_CHANGE_WAIT - fGametime;
        
        if( fDiff > 0.0 )
        {
            set_user_info( iPlayer, "name", szOldName );
            client_print( iPlayer, print_center, "You must wait %.1f seconds before changing you name.", fDiff );
        }
        else
        {
            g_fLastNameChange[ iPlayer ] = fGametime;
        }
    }
}

public MessageSayText( iMsgID, iDest, iReceiver )
{
    static const Cstrike_Name_Change[ ] = "#Cstrike_Name_Change";
    
    new szMessage[ sizeof( Cstrike_Name_Change ) + 1 ];
    get_msg_arg_string( 2, szMessage, sizeof( szMessage ) - 1 );
    
    if( equal( szMessage, Cstrike_Name_Change ) )
    {
        new szName[ 32 ], iPlayer;
        for( new i = 3; i <= 4; i++ )
        {
            get_msg_arg_string( i, szName, 31 );
            iPlayer = get_user_index( szName );
            
            if( is_user_connected( iPlayer ) )
            {
                if( ( g_fLastNameChange[ iPlayer ] + NAME_CHANGE_WAIT ) > get_gametime( ) )
                {
                    return PLUGIN_HANDLED;
                }
                
                break;
            }
        }
    }
    
    return PLUGIN_CONTINUE;
}

[wrecked_]

Quick question Exolent - what does the

PHP Code:

break; 


do? Does it act as some kind of return value?

[Exolent[jNr]]

The break stops the loop.

[wrecked_]

Ah, thanks.

[Seta00]

Also, you can use

continue;

to go to the next iteration of the loop.

[wrecked_]

Originally Posted by Seta00 Also, you can use continue; to go to the next iteration of the loop.

Yeah, I'd used that wrongly back when I first began scripting. I tried using that to replace

PHP Code:

return PLUGIN_CONTINUE; 


[ditmesteam]

Thank Mr Exolent[jNr]
it work so fine, thank you so much!

[ditmesteam]

Sorry, but players are auto change name into other of player name .... I must stop using plugin

[TigerMan]

this plugin perfect working but there is a problem with kill_asist plugin...