[meTaLiCroSS]

Here is a stock I usually use for my plugins. With this one you can create an explosion effect (dmg included only if enabled) without caching sprites, and these sh*ts.

PHP Code:

/**
 * Creates an explosion which the engine will do.
 * Note: Requieres Engine Module. Tested only on CS Steam.
 *
 * @param vecCenter                Position where the explosion should be created.
 * @param iMagnitude            Explosion size. This defines the explosion's max damage and sprite's size
 * @param iFlags                Explosion flags which you can find on hlsdk_const.inc
 * @param bDoDamage                Should do a radius damage?
 * @param bNoActivate        If this param is on true, the entity won't explode, and you must do it manually
 * @return                    Entity index on sucess, 0 on failure.
 */

stock ExplosionCreate(const Float:vecCenter[3], iMagnitude, iFlags = 0, bool:bDoDamage = true, bool:bNoActivate = false)
{
    // env_explosion entities are the ones
    // who creates explosions. So we are available
    // for using this one for creating explosions
    new iEnt = create_entity("env_explosion")
    
    if(!iEnt) // Invalid?
    return 0
    
    // The center of the explosion
    entity_set_origin(iEnt, vecCenter)
    
    // Key values must be only string, so we must
    // convert it from Int to String.
    new szMagnitude[8] // In explode.cpp the char size is 128 lol.
    formatex(szMagnitude, charsmax(szMagnitude), "%3d", iMagnitude) // Exactly as how the engine does it.
    DispatchKeyValue(iEnt, "iMagnitude", szMagnitude) // This will modify m_iMagnitude value.
    
    // In hlsdk_const.inc you can find env_explosion's spawn flags
    if(!bDoDamage) // If you don't want to create a damage sphere, so we must only add this flag.
        entity_set_int(iEnt, EV_INT_spawnflags, iFlags | SF_ENVEXPLOSION_NODAMAGE)
    else
        entity_set_int(iEnt, EV_INT_spawnflags, iFlags) // 3rd parameter flags.
    
    // Applying some pev values, and offset modifications
    DispatchSpawn(iEnt)
    
    if(!bNoActivate)
        force_use(iEnt, iEnt) // The engine doesn't care who used it. Btw, this actives the explosion.
    
    return iEnt
} 


Code from explode.cpp (HLSDK, line 257):

PHP Code:

// HACKHACK -- create one of these and fake a keyvalue to get the right explosion setup
void ExplosionCreate( const Vector &center, const Vector &angles, edict_t *pOwner, int magnitude, BOOL doDamage )
{
    KeyValueData    kvd;
    char            buf[128];

    CBaseEntity *pExplosion = CBaseEntity::Create( "env_explosion", center, angles, pOwner );
    sprintf( buf, "%3d", magnitude );
    kvd.szKeyName = "iMagnitude";
    kvd.szValue = buf;
    pExplosion->KeyValue( &kvd );
    if ( !doDamage )
        pExplosion->pev->spawnflags |= SF_ENVEXPLOSION_NODAMAGE;

    pExplosion->Spawn();
    pExplosion->Use( NULL, NULL, USE_TOGGLE, 0 );
} 


You can easily use it like in this example:

PHP Code:

// HamSandwich forward "Ham_Killed" on "player"
// Called when someone killed.
public fw_Player_Killed(iVictim) 
{
    new Float:vecOrigin[3]
    entity_get_vector(iVictim, EV_VEC_origin, vecOrigin)
    
    ExplosionCreate(vecOrigin, 100.0)
} 


If you want to modify engine default values, check this example of how to it:

PHP Code:

// HamSandwich forward "Ham_Killed" on "player"
// Called when someone killed.
public fw_Player_Killed(iVictim) 
{
    new Float:vecOrigin[3]
    entity_get_vector(iVictim, EV_VEC_origin, vecOrigin)
    
    // Registering Ham_TakeDamage fwd
    new HamHook:hTakeDamageFwd = RegisterHam(Ham_TakeDamage, "player", "fw_Player_TakeDamage")
    
    // Creating explosion entity
    new iEntId = ExplosionCreate(vecOrigin, 100.0, _ /* no flags */, true, true /* we must activate it manually */)
    
    // His owner would be the victim, here is where we should
    entity_set_edict(iEntId, EV_ENT_owner, iVictim)
    
    // Manually activation
    force_use(iEntId, iEntId) 
    
    // We don't need the Ham forward, so we must disable it
    DisableHamForward(hTakeDamageFwd)
}

// HamSandwich forward "Ham_TakeDamage" on "player"
// Called when "in this case" someone takes damage by an explosion entity.
public fw_Player_TakeDamage(iVictim, iInflictor, iAttacker, Float:flDamage, iDamageType)
{
    // iVictim -> Any player on the radius
    // iInflictor -> Explosion entity
    // iAttacker -> iInflictor
    // flDamage -> Damage done
    // iDamageType -> DMG_BLAST
    
    // The attacker will be the player who got killed
    // If mp_friendlyfire cvar is off, won't do team kill
    SetHamParamEntity(3, entity_get_edict(iInflictor, EV_ENT_owner))
    
    // Fix DMG_BLAST value which does not able to send DeathMsg HUD
    SetHamParamInteger(5, DMG_GENERIC) // DMG_GENERIC works fine without probles
    
    // Any code that you want to put, do it here.
    // Like restrictions for special players, etc.
    // ...
} 


For usage, you must Copy-Paste this code to your plugin, and including "engine".

If there is something wrong, please let me know.

[Arkshine]

You have others spawn flags for this entity, why don't you let to pass directly the flags. Also it's a bad idea to remove right away the entity, there is a chance the smoke/spark won't be showed. If you look the HLSDK, the entity is removed after the smoke creation, so it will be removed automatically. Another thing is I would return the entity index if you don't remove the entity right away.

[meTaLiCroSS]

Originally Posted by Arkshine You have others spawn flags for this entity, why don't you let to pass directly the flags. Also it's a bad idea to remove right away the entity, there is a chance the smoke/spark won't be showed. If you look the HLSDK, the entity is removed after the smoke creation. And it will be done automatically. Another thing is I would return the entity index so.

So what you recommend me?

Also, the both things works without problems on-game...

[Arkshine]

Sorry about the spawnflags, i've read too fastly your code, it's fine what you do.

What you should do :

- Remove remove_entity() : it will be done automatically after the smoke.
- Return the entity index : In case you need to get the index to be used later. (like with the Repeatable flag)

[meTaLiCroSS]

Originally Posted by Arkshine Sorry about the spawnflags, i've read too fastly your code, it's fine what you do. What you should do : - Remove remove_entity() : it will be done automatically after the smoke. - Return the entity index : In case you need to get the index to be used later. (like with the Repeatable flag)

I was thinking exactly on that, thanks Arkshine.

[fearAR]

Please correct it, If I kill to someone, All players explode!

[meTaLiCroSS]

Originally Posted by fearAR Please correct it, If I kill to someone, All players explode!

You're saying about the example?

That's only for the usage man.

[ConnorMcLeod]

Problem is that damage done is DMG_BLAST, i guess it makes player explode.
You can't alter it with a stock.

	// do damage
	if ( !( pev->spawnflags & SF_ENVEXPLOSION_NODAMAGE ) )
	{
		RadiusDamage ( pev, pev, m_iMagnitude, CLASS_NONE, DMG_BLAST );
	}

What you have to do is to hook TakeDamage or Killed in your plugin and change damagebit or bGib value, or hook RadiusDamage with orpheu.

Nice stock anyway.

Doesn't engine allow force_use(entity, 0) ? (doesn't matter, just wondered).

[dFF]

Possible to no kill teammate ?

@ConnorMcLeod: [ENGINE] Invalid player 0 (not in-game)

@meTaLiCroSS

stock ExplosionCreate(const Float:vecCenter[3], iMagnitude, iFlags = 0, bool:bDoDamage)

Should be:

stock ExplosionCreate( const Float:vecCenter[ 3 ], Float:iMagnitude, iFlags = 0, bool:bDoDamage )

[meTaLiCroSS]

Originally Posted by ConnorMcLeod Problem is that damage done is DMG_BLAST, i guess it makes player explode. You can't alter it with a stock. // do damage if ( !( pev->spawnflags & SF_ENVEXPLOSION_NODAMAGE ) ) { RadiusDamage ( pev, pev, m_iMagnitude, CLASS_NONE, DMG_BLAST ); } What you have to do is to hook TakeDamage or Killed in your plugin and change damagebit or bGib value, or hook RadiusDamage with orpheu. Nice stock anyway. Doesn't engine allow force_use(entity, 0) ? (doesn't matter, just wondered).

With DMG_BLAST does not appear the DeathMsg HUD. It's a little bit weirds, I tested some damage codes, and all of these if they are with "DMG_BLAST" included, no DeathMsg HUD appear...

About the force_use native, dFF answered you. Also, watching the "Use" call on explode.cpp, the engine does not care who activated it. I did "force_use(same, same)" because If in the 2nd parameter I put "0", will give me an error, and I don't want to use dllfunc(DLLFunc_Use, id, 0) bcoz will be the unique fm native :B

Originally Posted by dFF Possible to no kill teammate ? @ConnorMcLeod: [ENGINE] Invalid player 0 (not in-game) @meTaLiCroSS stock ExplosionCreate(const Float:vecCenter[3], iMagnitude, iFlags = 0, bool:bDoDamage) Should be:

About team kill:

PHP Code:

RadiusDamage ( pev, pev, m_iMagnitude, CLASS_NONE, DMG_BLAST ) 


The damage is done by the same explosion.

About the float param, I didn't understand "why" you want as float, bcoz the engine catch that keyvalue as an integer...

Right now I'm doing an example of how changing the default explosion values.