[ZASTRELIS]

Have a problem with last build with this steamworks.inc

Compiling get5.sp...
SourcePawn Compiler 1.10.0.6266
Copyright (c) 1997-2006 ITB CompuPhase
Copyright (c) 2004-2017 AlliedModders LLC

/home/kgb1st/CLASSIC/csgo/addons/sourcemod/scripting/include/SteamWorks.inc(248) : fatal error 196: deprecated syntax; see https://wiki.alliedmods.net/SourcePawn_Transitional_Syntax#Typedefs

Compilation aborted.Code size:            44952 bytes
Data size:             7128 bytes
Stack/heap size:      16384 bytes
Total requirements:   68464 bytes

Problem with https://github.com/KyleSanderson/Ste...SteamWorks.inc in

funcenum SteamWorksHTTPRequestCompleted
{
	public(Handle:hRequest, bool:bFailure, bool:bRequestSuccessful, EHTTPStatusCode:eStatusCode),
	public(Handle:hRequest, bool:bFailure, bool:bRequestSuccessful, EHTTPStatusCode:eStatusCode, any:data1),
	public(Handle:hRequest, bool:bFailure, bool:bRequestSuccessful, EHTTPStatusCode:eStatusCode, any:data1, any:data2)
};

funcenum SteamWorksHTTPHeadersReceived
{
	public(Handle:hRequest, bool:bFailure),
	public(Handle:hRequest, bool:bFailure, any:data1),
	public(Handle:hRequest, bool:bFailure, any:data1, any:data2)
};

funcenum SteamWorksHTTPDataReceived
{
	public(Handle:hRequest, bool:bFailure, offset, bytesreceived),
	public(Handle:hRequest, bool:bFailure, offset, bytesreceived, any:data1),
	public(Handle:hRequest, bool:bFailure, offset, bytesreceived, any:data1, any:data2)
};

How I can sove it? I've read wiki, but nothing can to do with these funcenum

[Dr!fter]

You definitely didn’t look at the wiki link or didn’t bother to read.

[ZASTRELIS]

Originally Posted by Dr!fter You definitely didn’t look at the wiki link or didn’t bother to read.

Typedefs

Function tags and function enums have been deprecated in favor of a more modern syntax. Currently, they can still only create tag names for functions. Future versions will support arbitrary types.

Upgrading both functags and funcenums is simple. Below are two examples:

functag public Action:SrvCmd(args);
 
funcenum Timer {
  Action:public(Handle:Timer, Handle:hndl),
  Action:public(Handle:timer),
};

Now, this becomes:

typedef SrvCmd = function Action (int args);
 
typeset Timer {
  function Action (Handle timer, Handle hndl);
  function Action (Handle timer);
};

I tried, but I can't do it..

I've 3 function in SteamWorks at the one if its native. So I can't understand how it must be work

funcenum SteamWorksHTTPRequestCompleted
{
    public(Handle:hRequest, bool:bFailure, bool:bRequestSuccessful, EHTTPStatusCode:eStatusCode),
    public(Handle:hRequest, bool:bFailure, bool:bRequestSuccessful, EHTTPStatusCode:eStatusCode, any:data1),
    public(Handle:hRequest, bool:bFailure, bool:bRequestSuccessful, EHTTPStatusCode:eStatusCode, any:data1, any:data2)
};

funcenum SteamWorksHTTPHeadersReceived
{
    public(Handle:hRequest, bool:bFailure),
    public(Handle:hRequest, bool:bFailure, any:data1),
    public(Handle:hRequest, bool:bFailure, any:data1, any:data2)
};

funcenum SteamWorksHTTPDataReceived
{
    public(Handle:hRequest, bool:bFailure, offset, bytesreceived),
    public(Handle:hRequest, bool:bFailure, offset, bytesreceived, any:data1),
    public(Handle:hRequest, bool:bFailure, offset, bytesreceived, any:data1, any:data2)
};

native bool:SteamWorks_SetHTTPCallbacks(
Handle:hHandle, 
    SteamWorksHTTPRequestCompleted:fCompleted = INVALID_FUNCTION, 
    SteamWorksHTTPHeadersReceived:fHeaders = INVALID_FUNCTION, 
    SteamWorksHTTPDataReceived:fData = INVALID_FUNCTION, 
Handle:hCalling = INVALID_HANDLE);

[Kailo]

PHP Code:

typeset SteamWorksHTTPRequestCompleted
{
    function void (Handle hRequest, bool bFailure, bool bRequestSuccessful, EHTTPStatusCode eStatusCode);
    function void (Handle hRequest, bool bFailure, bool bRequestSuccessful, EHTTPStatusCode eStatusCode, any data1);
    function void (Handle hRequest, bool bFailure, bool bRequestSuccessful, EHTTPStatusCode eStatusCode, any data1, any data2);
};

typeset SteamWorksHTTPHeadersReceived
{
    function void (Handle hRequest, bool bFailure);
    function void (Handle hRequest, bool bFailure, any data1);
    function void (Handle hRequest, bool bFailure, any data1, any data2);
};

typeset SteamWorksHTTPDataReceived
{
    function void (Handle hRequest, bool bFailure, int offset, int bytesreceived);
    function void (Handle hRequest, bool bFailure, int offset, int bytesreceived, any data1);
    function void (Handle hRequest, bool bFailure, int offset, int bytesreceived, any data1, any data2);
}; 


[ZASTRELIS]

Originally Posted by Kailo PHP Code: typeset SteamWorksHTTPRequestCompleted {     function void (Handle hRequest, bool bFailure, bool bRequestSuccessful, EHTTPStatusCode eStatusCode);     function void (Handle hRequest, bool bFailure, bool bRequestSuccessful, EHTTPStatusCode eStatusCode, any data1);     function void (Handle hRequest, bool bFailure, bool bRequestSuccessful, EHTTPStatusCode eStatusCode, any data1, any data2); };

void? Really, why?

/*funcenum SteamWorksHTTPBodyCallback
{
    public(const String:sData[]),
    public(const String:sData[], any:value),
    public(const data[], any:value, datalen)
};*/

Can you help me with advice? My problem with understanding in differences of const String:sData[] and const data[]
As I mean, const String:sData[] it's a simple dynamic string, and const data[] it's as dynamic massive?

[hmmmmm]

A String:[] is an array of chars. A regular array would be a string of regular cells. Different data types but both are arrays. If the concept of data types or arrays confuses you you should read the wiki or do a bit of research, there are a lot of good resources out there.

[ZASTRELIS]

Originally Posted by hmmmmm A String:[] is an array of chars. A regular array would be a string of regular cells. Different data types but both are arrays. If the concept of data types or arrays confuses you you should read the wiki or do a bit of research, there are a lot of good resources out there.

okay, thx. very usefull for me.