[silkker]

you have to upload the unzipped folder to your webspace. if you want to add overviews you just have to convert them into JPEG and put it with the associated overview txt-file in the overviews folder.

e.g.

the maps name is de_example.bsp

then it has to look like this

<webspace root>/onlinemap/overviews/de_example.jpg
<webspace root>/onlinemap/overviews/de_example.txt

I will write an how to for it as soon as I find the time to do so

[Daddy-K]

There are other settings that need to be made​​, that does not work.
I look only:

An error occured please try again in a few seconds. If you keep on having this problem the server could be offline.

[silkker]

I've made a little how-to in the first post be sure to follow the instructions. If you need more help you can send me a pm.

[hLiaS]

Can anyone create this _i386.so for windows .dll ??????
http://forums.alliedmods.net/showthread.php?t=60026

I find it sorry http://forums.alliedmods.net/showpos...8&postcount=15

[Daddy-K]

Since I put this plugin always gives me the console:

User 82.146.57.125:59748 Will Be Banned for rcon hacking Bad Rcon from 82.146.57.125:59748: rcon 1525305438 "Jack" stats L 03/06/2013 - 21:40:10: Bad Rcon: "rcon 1525305438" Jack "stats" from "82.146.57.125:59748" Bad rcon_password.

If you stop not show anything. How do you start and gives me these messages in the console.
Why?

[silkker]

This plugin has nothing to do with rcon. It looks like user Jack tries to "brutforce" your password. I just want to make clear two things. Is it your server? What does the server console say on server start up? Perhaps I can help you if you give me this informations.

[Arkshine]

When I was saying static ; you could have kept the var inside the function. static is like a global variable but in the scope of the function. Using static out of function would mean in the scope of the plugin, but I would guess it doesn't matter really new/static here.

There are things you can do : for example, map name is not going to change, that's something you should retrieve one time. You could also put the string in a static const variable too. And instead of hardcoding the size - 1, there is a define charsmax() which does that, so if you change buffer, you don't have to changes where it's used.
Btw, why don't you concatenate all strings, and sending one socket_send(), at the end ?

Edit: Can you explain the part with the regex, not sure to understand why on the received data, you retrieve something and you send it again, can you give an example also ?

[silkker]

Originally Posted by Arkshine Edit: Can you explain the part with the regex, not sure to understand why on the received data, you retrieve something and you send it again, can you give an example also ?

Yup. It's because of the jQuery. jQuery sends some GET informations and they have to be sent back. For example if the request looks like:

http://localhost:1107/?jsonp=jQuery191021287121100443662_1362654468020&_=1362654468081

The response has to look like:

jQuery191021287121100443662_1362654468020({
     "bombpos": [ "-1372", "2736", "27", "0" ],
     ...

If you wouldn't do that jquery would act like you try to get data that's not from your source.
It's all because of the same domain policie.

[Arkshine]

Ok. If it can help you, here more how I would do things, about I said above. I'm not telling you to use that (I don't even know if it works ), just you give some ideas without the redundant code and bit more efficient.

Spoiler

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <regex>
#include <sockets_hz>

#define PLUGIN "Online Map"
#define VERSION "1.1"
#define AUTHOR "Sebastian Groß"

new Regex:RegexHandle;
new Socket;
new MapName[ 32 ];
new BombPos[4];

public plugin_init()
{
    register_plugin( PLUGIN, VERSION, AUTHOR );

    new result, errorstr[ 2 ], errorno;
    RegexHandle = regex_compile( "jsonp=(.+)&_=", result, errorstr, charsmax( errorstr ), "i" );

    socket_unblock( Socket = socket_listen( "127.0.0.1", 1107, SOCKET_TCP, errorno ) );
    server_print( "[Online Map] Waiting for requests on port %d", 1107 );

    register_event( "BombDrop", "bombDrop", "a" );
    register_logevent( "roundEnd", 2, "1=Round_End" );

    get_mapname( MapName, charsmax( MapName ) );

    set_task( 0.1, "OnSocketReply", .flags = "b" );
}

public plugin_end()
{
    socket_close( Socket );
}

public bombDrop( const player )
{
    BombPos[ 0 ] = read_data( 1 );
    BombPos[ 1 ] = read_data( 2 );
    BombPos[ 2 ] = read_data( 3 );
    BombPos[ 3 ] = read_data( 4 );
}
public roundEnd(id)
{
    BombPos[ 3 ] = 0;
}

public OnSocketReply()
 {
    static const requestHeader      [] = "HTTP/1.1 200 OK^r^nServer: Online Map^r^nConnection: close^r^nContent-Type: text/plain^r^n^r^n";
    static const requestMapHeader   [] = "({^r^n^t^"bombpos^": [ ^"%d^", ^"%d^", ^"%d^", ^"%d^" ], ^r^n^t^"map^": ^"%s^",^r^n^t^"users^": [";
    static const requestPlayerHeader[] = "^r^n^t{^r^n^t^t^"name^": ^"%s^",^r^n^t^t^"status^": [ ^"%d^", ^"%d^", ^"%d^", ^"%d^" ],^r^n^t^t^"position^": [ ^"%d^", ^"%d^", ^"%d^" ],^r^n^t^t^"angle^": [ ^"%d^", ^"%d^", ^"%d^" ],^r^n^t^t^"stats^": [ ^"%d^", ^"%d^" ]^r^n^t},^r^n";
    static const requestEndHeader   [] = "]^r^n})";

    static request;

    if( ( request = socket_accept( Socket ) ) > 0 )
    {
        static requestData[ 2047 ];
        static requestRecv[ 256 ];
        static length;
        static result;

        socket_recv( request, requestRecv, charsmax( requestRecv ) );

        length = copy( requestData, charsmax( requestData ), requestHeader );

        if( regex_match_c( requestRecv, RegexHandle, result ) )
        {
            static match[ 64 ];

            regex_substr( RegexHandle, 1, match, charsmax( match ) );
            length += copy( requestData[ length ] , charsmax( requestData ) - length, match );
        }

        length += formatex( requestData[ length ], charsmax( requestData ) - length, requestMapHeader, BombPos[0], BombPos[1], BombPos[2], BombPos[3], MapName) ;

        static playersList[ 32 ], playersCount, player;
        static playerName[ 32 ];
        static angles[ 3 ];
        static origin[ 3 ];
        static i;

        get_players( playersList, playersCount );

        for( i = 0; i < playersCount; i++ )
        {
            player = playersList[i];

            get_user_name( player, playerName, charsmax( playerName ) );
            get_user_origin( player, origin, 0 );
            get_user_origin( player, angles, 3 );

            length += formatex( requestData[ length ], charsmax( requestData ) - length, requestPlayerHeader,
                playerName,
                is_user_alive( player ),
                cs_get_user_team( player ),
                get_user_weapon( player ),
                get_user_health( player ),
                origin[0], origin[1], origin[2],
                angles[0], angles[1], angles[2],
                get_user_frags( player ),
                get_user_deaths( player ) );
        }

        length += copy( requestData[ length ] , charsmax( requestData ) - length, requestEndHeader );

        socket_send( request, requestData, length );
        socket_close( request )
    }
}

[silkker]

WOW - just thank you. It seems like there are some errors but I think I can get that done Does the donate button in your signature lead to your pocket? ;)

[EDIT] sorry not some errors, one error i can open the stream via telnet but the browser can't handle it. But as I said I think I will get that done