[MaxK]

Hello,

I'm just beginning sourcemod scripting. I have written my first plugin, but i have a problem.

The aim of this plugin is to limit the number of heavy weapon a team can have.

It almost works but when i pass over a heavy weapon, the weapon disappear

In fact, it's only the visibility of the weapon. If i change the con_var and the if a go where the weapon was, i actually pick it up

Can you help me ?

PHP Code:

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>
 
public Plugin:myinfo =
{
    name = "Heavy Weapon Drop",
    author = "MAX-k",
    description = "Limit the amount of heavy weapons a team can carry",
    version = "1.0.0.0",
    url = "http://www.sourcemod.net/"
};


new Handle:sm_hweapon_drop = INVALID_HANDLE
new Handle:sm_hweapon_max_t = INVALID_HANDLE
new Handle:sm_hweapon_max_ct = INVALID_HANDLE
 
public OnPluginStart()
{
    sm_hweapon_drop = CreateConVar("sm_hweapon_drop", "0", "(Des)activate Heavy Weapon Drop Plugin", FCVAR_PLUGIN|FCVAR_SPONLY|FCVAR_REPLICATED|FCVAR_NOTIFY, true, 0.0, true, 1.0)
    sm_hweapon_max_t = CreateConVar("sm_hweapon_max_t", "-1", "Amount of HW taht Ts can carry (-1 = unlimited)", FCVAR_PLUGIN|FCVAR_SPONLY|FCVAR_REPLICATED|FCVAR_NOTIFY, true, -1.0)
    sm_hweapon_max_ct = CreateConVar("sm_hweapon_max_ct", "-1", "Amount of HW taht CTs can carry (-1 = unlimited)", FCVAR_PLUGIN|FCVAR_SPONLY|FCVAR_REPLICATED|FCVAR_NOTIFY, true, -1.0)
    AutoExecConfig(true, "plugin_heavy_weapon_drop")
    
    LoadTranslations ("hweapon_drop.phrases");

}

public Bool:IsHeavyWeapon(String:w_name[64])
{
    new String:hw_list[][32] = { "weapon_m3", "weapon_xm1014", "weapon_galil", "weapon_ak47", "weapon_scout", "weapon_sg552", "weapon_awp", "weapon_g3sg1", "weapon_famas", "weapon_m4a1", "weapon_aug", "weapon_sg550", "weapon_mac10", "weapon_tmp", "weapon_mp5navy", "weapon_ump45", "weapon_p90", "weapon_m249" }
    new Bool:retVal = false
    for (new i = 0; i < 18; i++)
    {
        if(!strcmp(hw_list[i], w_name))
        {
            retVal = true
            i = 18
        }
    }
    
    return retVal
}

public OnClientPutInServer(client) 
{ 
    SDKHook(client, SDKHook_WeaponEquip, OnWeaponEquip) 
} 
public OnClientDisconnect(client) 
{ 
    if ( IsClientInGame(client) ) 
    { 
        SDKUnhook(client, SDKHook_WeaponEquip, OnWeaponEquip) 
    } 
} 
public Action:OnWeaponEquip(Cli, weapon) 
{
    if(GetConVarBool(sm_hweapon_drop))
    {    
        
        new String:Item[64]
        GetEdictClassname(weapon, Item, sizeof(Item));
        
        if(IsHeavyWeapon(Item))
        {        
            new Max = 0
            new TeamCli = GetClientTeam(Cli)
            if(TeamCli == 2)
            {
                Max = GetConVarInt(sm_hweapon_max_t)
            }
            else if(TeamCli == 3)
            {
                Max = GetConVarInt(sm_hweapon_max_ct)
            }
            
            if (Max != -1)
            {
                new nb = 0
                
                for(new i = 1; i <= GetMaxClients() && nb < Max; i++)
                {
                    if(i != Cli && IsClientInGame(i) && GetClientTeam(i) == TeamCli && GetPlayerWeaponSlot(i, 0) != -1)
                    {
                        nb++
                    }
                }
                
                if(nb >= Max)
                {
                    return Plugin_Handled;
                }
            }
        }
    }
    return Plugin_Continue;
} 


[AtomicStryker]

Weapon_Equip happens after the game 'vanished' the weapon from the ground. I'd say instead of just return Plugin_Handled you need to save Angles and AbsOrigin, remove the old gun, and spawn a new one in the same position.

That WILL spam if someone is sitting on said gun though.

[Death [GER]]

Something i had lying around.. dunno if it works as i dont have css atm

[rhelgeby]

Have a look at the SDKHook_WeaponCanUse hook. That one is triggered before you pick up a weapon.

[spunkster21]

I had this problem as well. I got around it by using SDKHook_WeaponCanUse, which prevents the weapon from being used but doesn't remove it.

PHP Code:

SDKHook(client, SDKHook_WeaponCanUse, OnWeaponCanUse);

public Action:OnWeaponCanUse(client, weapon)
{
    /* Check if this client can use this weapon. */
    if (!CanUseWeapon(client))
    {
        return Plugin_Handled;
    }
    
    return Plugin_Continue;
} 


Edit: I had this in edit mode before rhelgeby posted his response and therefore didn't see it ;-)

[rhelgeby]

Off topic: The forum could have a update notifier when in edit mode (AJAX based or something).

[NoS]

Just wanted to mention, if you decide to release the plugin, I would suggest you call it Anti-Primary Pick up, I got confused thinking it was like awps, saws, possibly m4s and aks blocking.