[Balloons]

It's been a while since I've worked on plugins, which is why I'm struggling with this simple edit.

Errors:

plugin.sp(287) : error 035: argument type mismatch (argument 3)
plugin.sp(291) : error 092: number of arguments does not match definition

Code:

PHP Code:

        if (IsValidEdict(i) && IsClientInGame(i) && GetClientTeam(i) == TEAM_SURVIVORS)
        {
            if (damagepct > 0 && damagepct < 75)
            {
                CheatCMD(i, "sm_setscore %d", damagepct); // Line 287
            }
            if (damagepct >= 75)
            {
                CheatCMD(i, "sm_setscore 75"); // Line 291
            }
        } 


Stock:

PHP Code:

void CheatCMD(int client, const char[] command, const char[] argument1)
{
    int userFlags = GetUserFlagBits(client);
    SetUserFlagBits(client, ADMFLAG_ROOT);
    int flags = GetCommandFlags(command);
    SetCommandFlags(command, flags & ~FCVAR_CHEAT);
    FakeClientCommand(client, "%s %s", command, argument1);
    SetCommandFlags(command, flags);
    SetUserFlagBits(client, userFlags);
} 


[ProjectSky]

1. CheatCMD not accept format param
2. CheatCMD have 3 param but you code only pass 2 param

[alasfourom]

I have no idea what ur script do, but this is only an example

PHP Code:

#include <sourcemod>
#include <sdkhooks>
#include <sdktools>

#pragma semicolon 1
#pragma newdecls required

public void OnPluginStart()
{
    RegConsoleCmd("sm_test", Command_Test, "Test Command");
}

Action Command_Test(int client, int args)
{
    int damagepct = 50;
    
    int CmdFlags = GetCommandFlags("sm_setscore");
    SetCommandFlags("sm_setscore", CmdFlags & ~FCVAR_CHEAT);
    FakeClientCommand(client, "sm_setscore %d", damagepct);
    SetCommandFlags("sm_setscore", CmdFlags);
    return Plugin_Handled;
} 


[Balloons]

Thank you for the suggestions. I managed to figure it out by changing some format functions. Probably not the ideal method, but it works for me.

PHP Code:

void CheatCMD(int client, char[] command, int score)
{
    int userFlags = GetUserFlagBits(client);
    SetUserFlagBits(client, ADMFLAG_ROOT);
    int flags = GetCommandFlags(command);
    SetCommandFlags(command, flags & ~FCVAR_CHEAT);
    FakeClientCommand(client, "%s %d", command, score);
    SetCommandFlags(command, flags);
    SetUserFlagBits(client, userFlags);
} 


PHP Code:

int damagepct = GetDamageAsPercent(TankDamage[i]);
        //if (IsValidEdict(i) && IsClientInGame(i) && !IsFakeClient(i))
        if (IsValidEdict(i) && IsClientInGame(i) && GetClientTeam(i) == TEAM_SURVIVORS)
        {
            if (damagepct > 0 && damagepct < 75)
            {
                CheatCMD(i, "sm_setscore", damagepct);
            }
            if (damagepct >= 75)
            {
                CheatCMD(i, "sm_setscore", 75);
            }
        } 


[BRU7US]

PHP Code:

if (IsValidEdict(i) && IsClientInGame(i) && GetClientTeam(i) == TEAM_SURVIVORS)
{
            char s_damagepct[3];
            IntToString(damagepct, s_damagepct, sizeof(s_damagepct))

            if (damagepct > 0 && damagepct < 75)
            {
                CheatCMD(i, "sm_setscore", s_damagepct); // Line 287
            }
            if (damagepct >= 75)
            {
                CheatCMD(i, "sm_setscore", "75"); // Line 291
            }
} 


you need to convert you integer "damagepct" to char-type variable, because your CheatCMD function uses char variable in third argument, but you trying to use integer variable. It causes "argument mismatch" error like in line #287

[alasfourom]

I'm not sure but I think this "sm_setscore" is a command from an external plugin not a cvar which doent require you to bypass cheats command.

if so, the only thing u need to do is like this:

PHP Code:

if (IsValidEdict(i) && IsClientInGame(i) && GetClientTeam(i) == TEAM_SURVIVORS)
{
    char s_damagepct[3];
    IntToString(damagepct, s_damagepct, sizeof(s_damagepct))
    
    if (damagepct > 0 && damagepct < 75) FakeClientCommand(i, "sm_setscore %s", s_damagepct);
    else if (damagepct >= 75) FakeClientCommand(i, "sm_setscore 75");
} 


[Earendil]

Try this:

PHP Code:

    if (IsValidEdict(i) && IsClientInGame(i) && GetClientTeam(i) == TEAM_SURVIVORS)
        {
            char sAmt[8];
            if (damagepct > 0 && damagepct < 75)
            {
                Format(sAmt, sizeof(sAmt), "%d", damagepct);
                CheatCMD(i, "sm_setscore", sAmt);
            }
            if (damagepct >= 75)
            {
                CheatCMD(i, "sm_setscore",  "75");
            }
        }