[5c0r-|3i0]

How can I do that....?? fm_set_user_nobuy ??
If there's any better way..please tell me

[One]

Huh u want to restrict all weapons or restrict any weapons?or u mean anything elsE?

[5c0r-|3i0]

Make Terrorists can't buy weapon.....that's all

[One]

get player team & restrict.

[zwfgdlc]

try this.not tested.

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>
#include <fakemeta>

#define PLUGIN_NAME "no buy"
#define PLUGIN_VERSION  "1.0"
#define PLUGIN_AUTHOR   "zwfgdlc"

#define OFFSET_MAP_BUYZONE    235
#define CS_MAPZONE_BUY    (1<<0)

public plugin_init()
{
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR);
    RegisterHam(Ham_Touch,"func_buyzone","fw_TouchBuyZone");
}
public fw_TouchBuyZone(iEnt,id)
{
    fm_block_buy(id);
    return HAM_SUPERCEDE;
}
stock fm_block_buy(id)
{
    set_pdata_int(id,OFFSET_MAP_BUYZONE,get_pdata_int(id,OFFSET_MAP_BUYZONE)&~CS_MAPZONE_BUY);
}

[xPaw]

PHP Code:

#include <amxmodx>
#include <fakemeta>

public plugin_init( ) {
    register_plugin( "No Terr Buying", "1.0", "xPaw" );
    
    register_message( get_user_msgid( "StatusIcon" ), "Msg_StatusIcon" );
}

public Msg_StatusIcon( msgid, msgdest, id ) {
    if( get_user_team( id ) != 1 )
        return PLUGIN_CONTINUE;
    
    static szMsg[ 8 ];
    get_msg_arg_string( 2, szMsg, 7 );
    
    if( equal( szMsg, "buyzone" ) && get_msg_arg_int( 1 ) ) {
        set_pdata_int( id, 235, get_pdata_int( id, 235 ) & ~( 1 << 0 ) );
        return PLUGIN_HANDLED;
    }
    
    return PLUGIN_CONTINUE;
} 


[Arkshine]

@zwfgdlc: It will not work with map without this entity. "Later releases of CS don't require a func_buyzone, as the player spawn area defines the buy area."

So xPaw's way is fine :

    #include <amxmodx>
    #include <fakemeta>
    #include <cstrike>

    const OFFSET_MAP_BUYZONE = 235;
    const CS_MAPZONE_BUY     = ( 1 << 0 );

    public plugin_init ()
    {
        register_plugin( "No Terr Buying", "1.0", "xPaw" );
        register_message( get_user_msgid( "StatusIcon" ), "Msg_StatusIcon" ); 
    }
    
    public Msg_StatusIcon( const MsgId, const MsgDest, const Player ) 
    { 
        if( cs_get_user_team( Player ) == CS_TEAM_T && get_msg_arg_int( 1 ) )
        {
            static Message[ 8 ]; 
            get_msg_arg_string( 2, Message, charsmax( Message ) ); 
            
            if( equal( Message, "buyzone" ) )
            {
                set_pdata_int( Player, OFFSET_MAP_BUYZONE, get_pdata_int( Player, OFFSET_MAP_BUYZONE ) & ~CS_MAPZONE_BUY ); 
                return PLUGIN_HANDLED;
            }
        }
        
        return PLUGIN_CONTINUE; 
    }

Another version which keep the icon but let a (existing) message text when T is trying to buy :

    #include <amxmodx>
    #include <fakemeta>
    #include <engine>
    
    new gFwdKeyValue;
    
    public plugin_precache() 
    { 
        new Entity = create_entity( "info_map_parameters" );
        DispatchKeyValue( Entity, "buying", "1" );
        DispatchSpawn( Entity );
        
        gFwdKeyValue = register_forward( FM_KeyValue, "Forward_KeyValue" );
    } 

    public Forward_KeyValue( const Entity, const KvdHandle ) 
    { 
        if ( pev_valid( Entity ) ) 
        { 
            new ClassName[ 20 ];
            get_kvd( KvdHandle, KV_ClassName, ClassName, charsmax( ClassName ) );
            
            if( equal( ClassName, "info_map_parameters" ) )
            { 
                remove_entity( Entity );
                return FMRES_SUPERCEDE;
            }
        } 
        
        return FMRES_IGNORED;
    } 
    
    public plugin_init() 
    { 
        register_plugin( "Disable T's Buy", "1.0.0", "Arkshine" );
        unregister_forward( FM_KeyValue, gFwdKeyValue );
    }

[5c0r-|3i0]

Thanks a lot ...SOLVED

[--kml--]

What is an offset?