[Jelle]

G-Dog likes the semicolons.

Anyway, try G-Dogs method. I'm sure it works.

[The Art of War]

Now we are actually getting somewhere!

PHP Code:

#include <superheromod> 
// GLOBAL VARIABLES 
new gHeroID; 
new bool:gHasTest[SH_MAXSLOTS+1]; 
new pcvar_cool, pcvar_dmg; 
//---------------------------------------------------------------------------------------------- 
public plugin_init() 
{ 
    // Plugin Info 
    register_plugin("SUPERHERO Test", "0.1", "Random1") 
    // DO NOT EDIT THIS FILE TO CHANGE CVARS, USE THE SHCONFIG.CFG 
    new pcvarLevel = register_cvar("test_level", "0"); 
    pcvar_cool = register_cvar("test_cooldown", "30.0"); 
    pcvar_dmg = register_cvar("test_pctdmg", "0.1"); 
    // FIRE THE EVENT TO CREATE THIS SUPERHERO! 
    gHeroID = sh_create_hero("Test", pcvarLevel); 
    sh_set_hero_info(gHeroID, "Leech Seed", "Slowly absorb players health"); 
    sh_set_hero_bind(gHeroID);  
} 
//---------------------------------------------------------------------------------------------- 
public sh_hero_init(id, heroid, mode) 
    if ( heroid == gHeroID ) 
        gHasTest[id] = mode ? true : false; 
//---------------------------------------------------------------------------------------------- 
public sh_hero_key(id, heroID, key) 
{ 
    if ( gHeroID != heroID ) return; 
    if ( key )    //ya I know, instead of sticking with one method I went with yet another method of checking keydown just to f with yall 
    { 
        new tid, tbody; 
        get_user_aiming(id, tid, tbody); 
 
        if ( is_user_alive(tid) && gHasTest[id] && !gPlayerInCooldown[id] && (cs_get_user_team(id) != cs_get_user_team(tid) || sh_friendlyfire_on()) ) 
            leech_player(tid, id); 
    } 
}  
//---------------------------------------------------------------------------------------------- 
leech_player(victim, attacker) 
{ 
    if ( sh_is_active() && gHasTest[attacker] && is_user_alive(victim) ) 
    { 
        //first lets stun the player, we'll let them move a little cause stoping them all together can get cheap 
        sh_set_stun(victim, 3.0, 75.0); 
 
        new args[3]; args[0] = victim; args[1] = attacker;  
        args[2] = floatround(floatclamp(get_pcvar_float(pcvar_dmg) * get_user_health(victim) / 10.0, 1.0, float(sh_get_max_hp(victim)))); 
        set_task(0.3, "drain_health", attacker, args, 3, "a", 10);        //loops our task to occur 10 times over a 3 second interval 
 
        //set our cooldown now, assuming there is one 
        if (get_pcvar_float(pcvar_cool) > 0.0) sh_set_cooldown(attacker, get_pcvar_float(pcvar_cool)); 
    } 
} 
//---------------------------------------------------------------------------------------------- 
public drain_health(args[]) 
{ 
    static victim, attacker, damage; victim = args[0]; attacker = args[1]; damage = args[2]; 
    if ( !is_user_alive(victim) || !is_user_alive(attacker) ) 
    { 
        remove_task(attacker); 
        return; 
    } 
 
    sh_extra_damage(victim, attacker, damage, "leech life"); 
    sh_add_hp(attacker, damage, 0); 
 
    //and finally some kind of sprite effect, for now i'm gonna copy drac and just have the red flash    
    sh_screen_fade(attacker, 0.5, 0.25, 255, 10, 10, 40);  
} 
//---------------------------------------------------------------------------------------------- 
public client_connect(id) 
    gHasTest[id] = false; 
//---------------------------------------------------------------------------------------------- 


I would like to add the electro sprite to it;

PHP Code:

message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
 write_byte(TE_BEAMENTS)
 write_short(beamStartID)// start entity
 write_short(victim) // entity
 write_short(gSpriteLightning) // model
 write_byte(0)  // starting frame
 write_byte(15)  // frame rate
 write_byte(10)  // life
 write_byte(linewidth) // linewidth
 write_byte(10)  // noise amplitude
 write_byte(105)  // r, g, b
 write_byte(105)  // r, g, b
 write_byte(255)  // r, g, b 125
 write_byte(60)  // brightness 175
 write_byte(0)  // scroll speed
 message_end() 


and then play around with it to get a nice effect, though I need

PHP Code:

new Float:beamOrigin[3]
 pev(beamStartID, pev_origin, beamOrigin) 


right? And then I dont know what to change in the original code ^^

[The Art of War]

Aww, cmon now, check my last post

[vittu]

G-Dog, I think he wants a weapon to have increased damage for only a certain time period triggered by a power key.

[G-Dog]

do you want to play that effect each time hp is absorbed or just when the player gets leeched?

[The Art of War]

Originally Posted by vittu G-Dog, I think he wants a weapon to have increased damage for only a certain time period triggered by a power key.

Lal, not really..... G-Dog made it exactly the way I want it, though I just need to add a sprite and sound now. Im trying right now with some stuff from electro, though I fail pretty bigtime.
@G-Dog: Like the loop; The sprite is displayed all the time you leech someone; So the same amount of time you leech hp. I know it could look pretty fail, but I will probably set the cooldown to 30-60 secs and the leech % to 0.3 (30% of max hp), though I will test it some more if I get the sprite and sound on it.

This will probably just confuse you, and im sure that if G-Dog will help me, he will make it faster on his own... Still here it is, and im still not sure how to get the damn ;'s right

PHP Code:

#include <superheromod> 
#define LINE_WIDTH 100
// GLOBAL VARIABLES 
new gHeroID; 
new bool:gHasTest[SH_MAXSLOTS+1]; 
new pcvar_cool, pcvar_dmg; 
//---------------------------------------------------------------------------------------------- 
public plugin_init() 
{ 
    // Plugin Info 
    register_plugin("SUPERHERO Test", "0.1", "Random1") 
    // DO NOT EDIT THIS FILE TO CHANGE CVARS, USE THE SHCONFIG.CFG 
    new pcvarLevel = register_cvar("test_level", "0"); 
    pcvar_cool = register_cvar("test_cooldown", "30.0"); 
    pcvar_dmg = register_cvar("test_pctdmg", "0.1"); 
    // FIRE THE EVENT TO CREATE THIS SUPERHERO! 
    gHeroID = sh_create_hero("Test", pcvarLevel); 
    sh_set_hero_info(gHeroID, "Leech Seed", "Slowly absorb players health"); 
    sh_set_hero_bind(gHeroID);  
} 
//---------------------------------------------------------------------------------------------- 
public sh_hero_init(id, heroid, mode) 
    if ( heroid == gHeroID ) 
        gHasTest[id] = mode ? true : false; 
//---------------------------------------------------------------------------------------------- 
public sh_hero_key(id, heroID, key) 
{ 
    if ( gHeroID != heroID ) return; 
    if ( key )    //ya I know, instead of sticking with one method I went with yet another method of checking keydown just to f with yall 
    { 
        new tid, tbody; 
        get_user_aiming(id, tid, tbody); 
         
        if ( is_user_alive(tid) && gHasTest[id] && !gPlayerInCooldown[id] && (cs_get_user_team(id) != cs_get_user_team(tid) || sh_friendlyfire_on()) ) 
            leech_player(tid, id); 
    } 
}  
//---------------------------------------------------------------------------------------------- 
leech_player(victim, attacker) 
{ 
    if ( sh_is_active() && gHasTest[attacker] && is_user_alive(victim) ) 
    { 
        //first lets stun the player, we'll let them move a little cause stoping them all together can get cheap 
        sh_set_stun(victim, 3.0, 75.0); 
         
        new args[3]; args[0] = victim; args[1] = attacker;  
        args[2] = floatround(floatclamp(get_pcvar_float(pcvar_dmg) * get_user_health(victim) / 10.0, 1.0, float(sh_get_max_hp(victim)))); 
        set_task(0.3, "drain_health", attacker, args, 3, "a", 10);        //loops our task to occur 10 times over a 3 second interval 
         
        //set our cooldown now, assuming there is one 
        if (get_pcvar_float(pcvar_cool) > 0.0) sh_set_cooldown(attacker, get_pcvar_float(pcvar_cool)); 
    } 
} 
//---------------------------------------------------------------------------------------------- 
public drain_health(args[]) 
{ 
    static victim, attacker, damage; victim = args[0]; attacker = args[1]; damage = args[2]; 
    if ( !is_user_alive(victim) || !is_user_alive(attacker) ) 
    { 
        remove_task(attacker); 
        return; 
    } 
     
    sh_extra_damage(victim, attacker, damage, "leech life"); 
    sh_add_hp(attacker, damage, 0); 
     
    new Float:beamOrigin[3];
 pev(beamStartID, pev_origin, beamOrigin);

    //and finally some kind of sprite effect, for now i'm gonna copy drac and just have the red flash    
    message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
 write_byte(TE_BEAMENTS)
 write_short(beamStartID)// start entity
 write_short(victim) // entity
 write_short(gSpriteLightning) // model
 write_byte(0)  // starting frame
 write_byte(15)  // frame rate
 write_byte(10)  // life
 write_byte(linewidth) // linewidth
 write_byte(10)  // noise amplitude
 write_byte(150)  // r, g, b
 write_byte(0)  // r, g, b
 write_byte(170)  // r, g, b 125
 write_byte(60)  // brightness 175
 write_byte(0)  // scroll speed
 message_end();

     new vicOrigin[3];
 get_user_origin(victim, vicOrigin) ;
 // Create an elight on the target
 message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
 write_byte(TE_ELIGHT)
 write_short(victim) // entity
 write_coord(vicOrigin[0])  // initial position
 write_coord(vicOrigin[1])  // initial position
 write_coord(vicOrigin[2])  // initial position
 write_coord(10) // radius
 write_byte(0)  // r, g, b
 write_byte(0)  // r, g, b
 write_byte(255)  // r, g, b
 write_byte(10)  // life
 write_coord(0)  // decay rate
 message_end();
    
} 
//---------------------------------------------------------------------------------------------- 
public client_connect(id) 
    gHasTest[id] = false; 
//---------------------------------------------------------------------------------------------- 


Errors:

//// sh_necromonger.sma
// C:\Users\Cornerstone\Desktop\HLDS_Server\cstrike\addons\amxmodx\scripting\sh_
necromonger.sma(73) : warning 217: loose indentation
// C:\Users\Cornerstone\Desktop\HLDS_Server\cstrike\addons\amxmodx\scripting\sh_
necromonger.sma(73) : error 017: undefined symbol "beamStartID"
// C:\Users\Cornerstone\Desktop\HLDS_Server\cstrike\addons\amxmodx\scripting\sh_
necromonger.sma(73) : warning 215: expression has no effect
// C:\Users\Cornerstone\Desktop\HLDS_Server\cstrike\addons\amxmodx\scripting\sh_
necromonger.sma(73) : warning 215: expression has no effect
// C:\Users\Cornerstone\Desktop\HLDS_Server\cstrike\addons\amxmodx\scripting\sh_
necromonger.sma(73) : error 001: expected token: ";", but found ")"
// C:\Users\Cornerstone\Desktop\HLDS_Server\cstrike\addons\amxmodx\scripting\sh_
necromonger.sma(73) : error 029: invalid expression, assumed zero
// C:\Users\Cornerstone\Desktop\HLDS_Server\cstrike\addons\amxmodx\scripting\sh_
necromonger.sma(73) : fatal error 107: too many error messages on one line
//
// Compilation aborted.
// 4 Errors.
// Could not locate output file compiled\sh_necromonger.amx (compile failed).
//
// Compilation Time: 0,59 sec

[G-Dog]

assuming you want a constant beam and not one that phases in and out this should work(at least if I'm right about the life parameter). For one that phases in and out move the effect into the loop function and change the life rate to 1

PHP Code:

#include <superheromod>

// GLOBAL VARIABLES
new gHeroID;
new bool:gHasTest[SH_MAXSLOTS+1];
new pcvar_cool, pcvar_dmg;
new gSpriteLightning;
//----------------------------------------------------------------------------------------------
public plugin_init()
{
    // Plugin Info
    register_plugin("SUPERHERO Test", "0.2", "Random1");

    // DO NOT EDIT THIS FILE TO CHANGE CVARS, USE THE SHCONFIG.CFG
    new pcvarLevel = register_cvar("test_level", "0");
    pcvar_cool = register_cvar("test_cooldown", "30.0");
    pcvar_dmg = register_cvar("test_pctdmg", "0.1");

    // FIRE THE EVENT TO CREATE THIS SUPERHERO!
    gHeroID = sh_create_hero("Test", pcvarLevel);
    sh_set_hero_info(gHeroID, "Leech Seed", "Slowly absorb players health");
    sh_set_hero_bind(gHeroID);
}
//----------------------------------------------------------------------------------------------
public plugin_precache()
    gSpriteLightning = precache_model("sprites/lgtning.spr");
//----------------------------------------------------------------------------------------------
public sh_hero_init(id, heroid, mode)
    if ( heroid == gHeroID )
        gHasTest[id] = mode ? true : false;
//----------------------------------------------------------------------------------------------
public sh_hero_key(id, heroID, key)
{
    if ( gHeroID != heroID ) return;

    if ( key )    //ya I know, instead of sticking with one method I went with yet another method of checking keydown just to f with yall
    {
        new tid, tbody;
        get_user_aiming(id, tid, tbody);
        
        if ( is_user_alive(tid) && gHasTest[id] && !gPlayerInCooldown[id] && (cs_get_user_team(id) != cs_get_user_team(tid) || sh_friendlyfire_on()) )
            leech_player(tid, id);
    }
}
//----------------------------------------------------------------------------------------------
leech_player(victim, attacker)
{
    if ( sh_is_active() && gHasTest[attacker] && is_user_alive(victim) )
    {
        //first lets stun the player, we'll let them move a little cause stoping them all together can get cheap
        sh_set_stun(victim, 3.0, 75.0);
        
        //start the drain loop
        new args[3]; args[0] = victim; args[1] = attacker; 
        args[2] = floatround(floatclamp(get_pcvar_float(pcvar_dmg) * get_user_health(victim) / 10.0, 1.0, float(sh_get_max_hp(victim))));
        set_task(0.3, "drain_health", attacker, args, 3, "a", 10);        //loops our task to occur 10 times over a 3 second interval
        
        //add some effects
        message_begin(MSG_BROADCAST, SVC_TEMPENTITY);
        write_byte(TE_BEAMENTS);
        write_short(attacker);            // start entity
        write_short(victim);            // entity
        write_short(gSpriteLightning);    // model
        write_byte(0);                    // starting frame
        write_byte(15);                    // frame rate
        write_byte(30);                    // life in 0.1's   so 30 should = 3 seconds
        write_byte(60);                    // line width
        write_byte(10);                    // noise amplitude
        write_byte(255);                // r, g, b
        write_byte(128);                // r, g, b
        write_byte(0);                    // r, g, b
        write_byte(150);                // brightness
        write_byte(0);                    // scroll speed
        message_end();
        
        //set our cooldown now, assuming there is one
        if (get_pcvar_float(pcvar_cool) > 0.0) sh_set_cooldown(attacker, get_pcvar_float(pcvar_cool));
    }
}
//----------------------------------------------------------------------------------------------
public drain_health(args[])
{
    static victim, attacker, damage; victim = args[0]; attacker = args[1]; damage = args[2];
    if ( !is_user_alive(victim) || !is_user_alive(attacker) )
    {
        remove_task(attacker);
        return;
    }
    
    sh_extra_damage(victim, attacker, damage, "leech life");
    sh_add_hp(attacker, damage, 0);
    
    //and finally some kind of sprite effect, for now i'm gonna copy drac and just have the red flash    
    sh_screen_fade(attacker, 0.5, 0.25, 255, 10, 10, 40); //Red Screen Flash
}
//----------------------------------------------------------------------------------------------
public client_connect(id)
    gHasTest[id] = false;
//---------------------------------------------------------------------------------------------- 


[The Art of War]

Now imma post this stuff here for the people that has been following if you want it. Plz rate (Yes G-Dog made almost everything )

Necromonger: Suck the life out of those who deny you!

http://en.wikipedia.org/wiki/The_Chronicles_of_Riddick

[IMG]http://img706.**************/img706/6251/scifinecromonger.jpg[/IMG]


[IMG]http://img28.**************/img28/774/necroicon.jpg[/IMG]

[The Art of War]

I tried to add a max range cvar by using the old hero "Explosion", I took the distanceBetween = get_distance(origin, origin1 ) and changed to attacker, victim, and if( distanceBetween < !attacker, victim) and so on.... I know I didnt used the orígin part, I dont get it xD

Please help if anyone got time! thx

[kanatzu]

PHP Code:

register_plugin("SUPERHERO Necromonger", "0.2", "The Art of War"); 


This is what i meant before. You should also add G-Dog as author.