[HSFighter]

Hi all,

i try to Hook the owner of smoke from a smokegrenade.

But i get a "-1" back when i try to get the clientID What i doing wrong?

PHP Code:

public OnEntityCreated(entity, const String:classname[])
{    
    if (entity > MaxClients && IsValidEntity(entity))
    {
        if(StrEqual(classname, "env_particlesmokegrenade", false))
        {
            SDKHook(entity, SDKHook_Spawn, OnSpawnParticles);
        }
    }
}

// EntitySpawned
public OnSpawnParticles(entity)
{
    // Get owner from entity
    new client = GetEntPropEnt(entity, Prop_Data, "m_hOwnerEntity");
    
    PrintToChatAll("Client --> %i", client);
    PrintToChatAll("Entity --> %i", entity);
} 


[Bacardi]

Aaaf...

Spoiler

PHP Code:

#include <sdkhooks>
#include <sdktools>

public OnEntityCreated(entity, const String:classname[])
{    
    if (entity > MaxClients && IsValidEntity(entity))
    {
        if(StrEqual(classname, "env_particlesmokegrenade", false))
        {
            CreateTimer(0.1, timer, entity)
        }
    }
}

public Action:timer(Handle:timer, any:entity)
{
    new Float:origin[3];
    GetEntPropVector(entity, Prop_Send, "m_vecOrigin", origin);

    new ent = -1;
    new Float:origin2[3];

    while((ent = FindEntityByClassname(ent, "smokegrenade_projectile")) != -1)
    {
        GetEntPropVector(ent, Prop_Send, "m_vecOrigin", origin2);

        //PrintToServer("%f %f %f\n%f %f %f", origin[0], origin[1], origin[2], origin2[0], origin2[1], origin2[2]);

        if(origin2[0] == origin[0] && origin2[1] == origin[1] && origin2[2] == origin[2])
        {
            new client = GetEntPropEnt(ent, Prop_Send, "m_hOwnerEntity");
            PrintToChatAll("Client --> %i", client);
            PrintToChatAll("smokegrenade_projectile --> %i", ent);
            PrintToChatAll("env_particlesmokegrenade --> %i", entity);
            break;
        }
    }
} 


*edit
Those who have not know.
smokegrenade_projectiles stay on ground, not get removed, but disappear until new round.

*edit edit
Maybe this better ?

PHP Code:

#include <sdktools>

public OnPluginStart()
{
    HookEvent("smokegrenade_detonate", smokegrenade_detonate);
}

public smokegrenade_detonate(Handle:event, const String:name[], bool:dontBroadcast)
{
/*
    "smokegrenade_detonate"
    {
        "userid"    "short"
            "x"        "float"
            "y"        "float"
            "z"        "float"
    }
*/
    new client = GetClientOfUserId(GetEventInt(event, "userid"));

    new Float:a[3], Float:b[3];
    a[0] = GetEventFloat(event, "x");
    a[1] = GetEventFloat(event, "y");
    a[2] = GetEventFloat(event, "z");

    new ent = -1;

    while((ent = FindEntityByClassname(ent, "env_particlesmokegrenade")) != -1)
    {
        GetEntPropVector(ent, Prop_Send, "m_vecOrigin", b);

        //PrintToServer("%f %f %f\n%f %f %f", a[0], a[1], a[2], b[0], b[1], b[2]);

        if(a[0] == b[0] && a[1] == b[1] && a[2] == b[2])
        {
            PrintToChatAll("Client --> %i", client);
            PrintToChatAll("env_particlesmokegrenade --> %i", ent);
            break;
        }
    }    
} 


[HSFighter]

My first try was to look of this plugin: http://forums.alliedmods.net/showthread.php?t=158363
But i'm not the Sourcepawn Array Master.

--

Thank you Bacardi.
Very nice Idea. I try it and will report soon.


-

[HSFighter]

* Doublepost Sorry *

[Bacardi]

Yeah, Peace-Maker have done looking smokegrenade projectile owners and save in array (Haven't spend much time about those arrayes).
Next when smoke particle spawn XYZ, it check array list all smokegrenade projectiles what match with same location.

But I don't see huge difference what I posted... maybe I'm blind.

[HSFighter]

Originally Posted by Bacardi Yeah, Peace-Maker have done looking smokegrenade projectile owners and save in array (Haven't spend much time about those arrayes). Next when smoke particle spawn XYZ, it check array list all smokegrenade projectiles what match with same location. But I don't see huge difference what I posted... maybe I'm blind.

Your example is easier to understand for me
And it work's fine. Thank You Bacardi.

But now i have an other problem.
I try to change the render settings of the smoke.

I seen that Peace-Maker have spawn a light in the smoke.
This will work for 5 sec. (only to test):

PHP Code:

LightCreate(Float:Pos[3])   
{  
    new iEntity = CreateEntityByName("light_dynamic");
    DispatchKeyValue(iEntity, "inner_cone", "0");
    DispatchKeyValue(iEntity, "cone", "80");
    DispatchKeyValue(iEntity, "brightness", "1");
    DispatchKeyValueFloat(iEntity, "spotlight_radius", 150.0);
    DispatchKeyValue(iEntity, "pitch", "90");
    DispatchKeyValue(iEntity, "style", "1");
    DispatchKeyValue(iEntity, "_light", "75 75 255 255");
    DispatchKeyValueFloat(iEntity, "distance", freezedistance);
    EmitSoundToAll(SOUND_FREEZE_EXPLODE, iEntity, SNDCHAN_WEAPON);
    CreateTimer(5.0, Delete, iEntity, TIMER_FLAG_NO_MAPCHANGE);

    DispatchSpawn(iEntity);
    TeleportEntity(iEntity, Pos, NULL_VECTOR, NULL_VECTOR);
    AcceptEntityInput(iEntity, "TurnOn");
}

public Action:Delete(Handle:timer, any:entity)
{
    if(IsValidEdict(entity)) AcceptEntityInput(entity, "kill");
} 


But i search an easier way if it's possible?

Here my Code.
But nothing happens :

PHP Code:


#include <sdktools>

#define K_RENDER_NORMAL            0
#define K_RENDER_TRANS_COLOR    1

new g_Color[4]   = {255, 0, 0, 255}; // Red

new g_RenderModeOffset;
new g_RenderClrOffset;

public OnPluginStart()
{
    g_RenderModeOffset = FindSendPropOffs("ParticleSmokeGrenade", "m_nRenderMode");
    g_RenderClrOffset = FindSendPropOffs("ParticleSmokeGrenade", "m_clrRender");
}


// public Action here...
{
    UTIL_Render(ent, g_Color);    
}


UTIL_Render(ent, const color[4])
{
    PrintToChatAll("Ent ---> %i", ent);
    new mode = (color[3] == 255) ? K_RENDER_NORMAL : K_RENDER_TRANS_COLOR;
    
    SetEntData(ent, g_RenderModeOffset, mode, 1);
    SetEntDataArray(ent, g_RenderClrOffset, color, 4, 1);
    ChangeEdictState(ent);
    
}