[necavi]

I can't seem to get just the character at a certain index (if I use randomstr[2] it'll give me everything from the third character onwards) there has to be a way to do this, I simply haven't figured it out yet, despite looking all through the String docs.

[Scone]

Here's a function from my calculator plugin. It puts the character into a new integer, then works with that integer value. Hope that helps.

PHP Code:

ReadToken(const String:source[], &pos, &Float:num, &op) {

    new c = source[pos]; // This is the relevant line
    if(c == 0) return 0;
    
    decl String:tmp[20];
    
    if(IsCharNumeric(c) || c == '.' || c == '_') {
        new i = 0;
        while((c = source[pos]) != 0 && i < sizeof(tmp)-2 && (IsCharNumeric(c) || c == '.' || c == '_')) {
            if(c == '_') c = '-';
            tmp[i++] = c;
            pos++;
        }
        if(i > sizeof(tmp)-3) return -1;
        tmp[i] = 0;
        num = StringToFloat(tmp);
        return 2;
    }
    
    if(IsCharAlpha(c)) {
        new i = 0;
        while((c = source[pos]) != 0 && i < sizeof(tmp)-2 && IsCharAlpha(c)) {
            tmp[i++] = c;
            pos++;
        }
        if(i > sizeof(tmp)-3) return -1;
        if(c != '(') return -2;
        tmp[i] = 0;
        op = FindFunc(tmp);
        return 3;
    }
    
    op = c;
    pos++;
    return 1;
} 


[necavi]

Calculator plugin? That's exactly what I was going to do! XD


Edit: Ahhhh, requiring spaces, I was trying to avoid that (but it seems as if it would be far too hard without them)

[necavi]

Addendum: I'm trying to adapt that to a native for use in multiple plugins, but unfortunately I haven't figured out how to return a value on only one return (the compiler doesn't like it) but I don't think I can give it any value to indicate that the plugin failed to complete its task.

[Scone]

Sorry, I don't fully understand the question.

[berni]

Originally Posted by necavi I can't seem to get just the character at a certain index (if I use randomstr[2] it'll give me everything from the third character onwards) there has to be a way to do this, I simply haven't figured it out yet, despite looking all through the String docs.

randomstr[2] just is one character, however if you use it with string functions it will be used as pointer and returns the whole rest string of course.
don't use it with string functions.

[Powerlord]

Originally Posted by berni randomstr[2] just is one character, however if you use it with string functions it will be used as pointer and returns the whole rest string of course. don't use it with string functions.

Which is why you should strcopy it if you plan on doing further operations on it.

Keep in mind that a 1-character string still needs to be two characters long:

PHP Code:

decl String:newString[2];
strcopy(randomstr[2], newString); 


(assuming I have the right syntax for strcopy)

[McFlurry]

Originally Posted by Powerlord PHP Code: decl String:newString[2]; strcopy(randomstr[2], newString);  (assuming I have the right syntax for strcopy)

maxlength is missing. and destination string is first. unless randomstr was suppose to be the destination.

PHP Code:

decl String:newString[2];
strcopy(newString, sizeof(newString), randomstr[2]); 


A 1 character string should be [1], no? 0 is the valid string pointer and 1 is the null terminator.

[Scone]

The [2] in the declaration implies that there are two elements, [0] and [1]. Declaring it with [1] element would mean that there was only one, [0].

If you're only working with one character there's no need to declare a string, just use a single integer.

[asherkin]

Originally Posted by Scone If you're only working with one character there's no need to declare a string, just use a single integer.

This.
Just store it in a cell directly.