[roniold]

Hello. I want help with a plugin for headshot only.

It's possible to make the plugin:

#include <amxmodx>
#include <fun>

public aim_prac(id)
{
	if (id && !((get_user_flags(id) & ADMIN_LEVEL_A)))
	{
		client_print(id, print_console, "[AMXX] You do not have access to this command")
		return PLUGIN_CONTINUE
	}
	new arg[8]
	read_argv(1, arg, 7)

	if((equali(arg, "on"))||(equali(arg, "1")))
	{
		set_user_hitzones(0 ,0, 2)
		client_print(id, print_console, "[AMXX] ENABLED Headshot only mode")
		client_print(0, print_chat, "[AMXX] ENABLED Headshot only mode")
	}
	else
	{
		set_user_hitzones(0, 0, 255)
		client_print(id, print_console, "[AMXX] DISABLED Headshot only mode")
		client_print(0, print_chat, "[AMXX] DISABLED Headshot only mode")
	}
	return PLUGIN_HANDLED
}

public plugin_init()
{
	register_plugin("Aim Practice","1.0","James Romeril")
	register_concmd("aim_prac", "aim_prac", ADMIN_LEVEL_A, "aim_prac <on|off> or <1|0>")
}

to activate just for who write /hsonly 1?

Example:
When I write /hsonly 1, the server will activate Headshot Only just for me, not for all. Can you make this, please?
Thank you very much!

[Moody92]

PHP Code:

#include <amxmodx>
#include <fun>


public plugin_init()
{
    register_plugin("Aim Practice","1.0","James Romeril")
    register_clcmd("say", "aim_prac", ADMIN_ALL)
}

public aim_prac(id)
{
    new said[32]
    read_args(said,charsmax(said))
    remove_quotes(said)
    
    new arg1[8], arg2[8]
    parse(said, arg1, 7, arg2, 7)

    
    if(equali(arg1, "/hsonly")){
        
        
        if((equali(arg2, "on"))||(equali(arg2, "1")))
        {
            set_user_hitzones(id ,0, 2)
            client_print(id, print_console, "[AMXX] You ENABLED Headshot only mode")
            client_print(id, print_chat, "[AMXX] You ENABLED Headshot only mode")
        }
        else
        {
            set_user_hitzones(id, 0, 255)
            client_print(id, print_console, "[AMXX] You DISABLED Headshot only mode")
            client_print(id, print_chat, "[AMXX] You DISABLED Headshot only mode")
        }
        return PLUGIN_HANDLED
    }
    return PLUGIN_CONTINUE
} 


[roniold]

Hi, Moody!

It's working.

Thank you very much for your time!