[SilentBr]

Originally Posted by cravenge That command is for turning his teammates invisible, one of his requests. Btw, I updated the code to include those teammates to have no sounds emitted.

I thought that only me as the invisible-nosound zombie is the best. I will start recording my gameplay and change my nickname (before join)... 3 times the same player kills me far away, and the opposite way they are going, I'm pretty sure he is using something. So I will ban and ask him to go to my forum and explain why he killed me.

I don't want any in my server know that this plugin is installed. So, I don't want to give any player the invisble and nosound effects.

I'm confused, how I turn me into an invisible-nosound infected. Is there a command? I don't want be all the time. Only when I think there is a wallhacker.

EDIT: When I said "+ maybe is possible to be also invisible for teammates;"
I meant that root admin will be insible to everyone, even the teammates will not see , and will not know that you are alive.

I think the way I've said was not clear enough. Sorry.

[cravenge]

Originally Posted by SilentBr [...]

Thanks for the clarification, SilentBr.

One thing I have to say about your killer, though, it's obvious he/she's using aimbot, an addon which provides that cheat, or a script that he/she can run in client side.

My suggestions:

1. Install latest version of SMAC aimbot and spinhack detectors, taking out hypothesis no. 1.
2. If you're using Left 4 Downtown 2 extension, prevent clients from using addons with the Server Addons Disabler function (included in the latest version provided by Accelerator or Spirit with the convar "l4d_addons_eclipse") which takes out hypothesis no. 2.
3. Temporarily ban that client from your servers, which is the best solution in taking out all the hypotheses and once it is confirmed that he/she is using 3PP/Illegal Hack program, make that ban permanent.

[cravenge]

Okay, I've corrected the code to your liking. You might want to take a look at it.

[Psyk0tik]

Originally Posted by cravenge Okay, I've corrected the code to your liking. You might want to take a look at it.

I'm looking at your current code and I don't see where you've defined IsSurvivor and OnCDCVarChanged, and that's why it can't compile.

[SilentBr]

Originally Posted by cravenge Okay, I've corrected the code to your liking. You might want to take a look at it.

Hello cravenge

Sorry the dealy, I was on vacation. Happy new year!!!

Ok, so I understand to become an invisible-nosound zombie you shout type sm_cd_team, is that right?

By the way, it is not compiling.

/groups/sourcemod/upload_tmp/textDKTMON.sp(24) : error 017: undefined symbol "OnCDCVarChanged" /groups/sourcemod/upload_tmp/textDKTMON.sp(29) : error 100: function prototypes do not match /groups/sourcemod/upload_tmp/textDKTMON.sp(114) : error 017: undefined symbol "OnCDCVarChanged" /groups/sourcemod/upload_tmp/textDKTMON.sp(120) : error 100: function prototypes do not match /groups/sourcemod/upload_tmp/textDKTMON.sp(18 : warning 213: tag mismatch

[Lux]

Originally Posted by cravenge Thanks for the clarification, SilentBr. One thing I have to say about your killer, though, it's obvious he/she's using aimbot, an addon which provides that cheat, or a script that he/she can run in client side. If you're using Left 4 Downtown 2 extension, prevent clients from using addons with the Server Addons Disabler function (included in the latest version provided by Accelerator or Spirit with the convar "l4d_addons_eclipse") which takes out hypothesis

You don't need downtown to disable peoples addons
you can just use whitelisting

/left4dead2/whitelist.cfg

you can disable all addons with a few letters or you can disable specific addons if you put the full path.

[midnight9]

Originally Posted by Lux You don't need downtown to disable peoples addons you can just use whitelisting /left4dead2/whitelist.cfg you can disable all addons with a few letters or you can disable specific addons if you put the full path.

I've never tried doing it that way, but there is dedicated config file to allow/disallow addons: cfg/addonconfig.cfg

[Psyk0tik]

Originally Posted by SilentBr Hello cravenge Sorry the dealy, I was on vacation. Happy new year!!! Ok, so I understand to become an invisible-nosound zombie you shout type sm_cd_team, is that right? By the way, it is not compiling.

Try this one.

PHP Code:

#include <sourcemod>
#include <sdkhooks>
#include <sdktools>
#pragma semicolon 1
#pragma newdecls required

ConVar cvPlayToSelf;
bool bCloaked[MAXPLAYERS+1];
bool bPlayToSelf;

public Plugin myinfo =
{
    name = "Cheater Detector",
    author = "cravenge (requested by SilentBr)",
    description = "Lets root admins be able to detect cheaters.",
    version = "1.2",
    url = "https://forums.alliedmods.net/forumdisplay.php?f=108"
}

public void OnPluginStart()
{
    RegAdminCmd("sm_cdetect", OnCDCmd, ADMFLAG_ROOT, "Apply cloaking function");
    CreateConVar("cheater_detector_version", "1.2", "Cheater Detector Version", FCVAR_NOTIFY);
    cvPlayToSelf = CreateConVar("cd_play_to_self", "0", "Play own sounds to yourself?");
    cvPlayToSelf.AddChangeHook(OnCDCVarChanged);
    HookEvent("player_death", OnPlayerDeath, EventHookMode_Pre);
    AddAmbientSoundHook(OnAdminASCheck);
    AddNormalSoundHook(OnAdminNSCheck);
    AutoExecConfig(true, "cheater_detector");
}

public void OnCDCVarChanged(Handle convar, const char[] oldValue, const char[] newValue)
{
    bPlayToSelf = cvPlayToSelf.BoolValue;
}

public Action OnCDCmd(int client, int args)
{
    if(client == 0 || !IsClientInGame(client) || GetClientTeam(client) != 3 || !IsPlayerAlive(client))
    {
        return Plugin_Handled;
    }

    if(bCloaked[client])
    {
        SDKUnhook(client, SDKHook_SetTransmit, OnSetTransmit);
        SetEntityRenderMode(client, RENDER_NORMAL);
        SetEntityRenderColor(client, _, _, _, 255);
        bCloaked[client] = false;
    }

    else
    {
        bCloaked[client] = true;
        SetEntityRenderMode(client, RENDER_TRANSALPHA);
        SetEntityRenderColor(client, _, _, _, 0);
        SDKHook(client, SDKHook_SetTransmit, OnSetTransmit);
    }

    return Plugin_Handled;
}

public Action OnSetTransmit(int entity, int other)
{
    if(bIsRootAdmin(other))
    {
        return Plugin_Continue;
    }

    return Plugin_Handled;
}

public Action OnAdminASCheck(char sample[PLATFORM_MAX_PATH], int &entity, float &volume, int &level, int &pitch, float pos[3], int &flags, float &delay)
{
    if(!bIsInfected(entity) || !bIsRootAdmin(entity) || !bCloaked[entity])
    {
        return Plugin_Continue;
    }

    return Plugin_Stop;
}

public Action OnAdminNSCheck(int clients[MAXPLAYERS], int &numClients, char sample[PLATFORM_MAX_PATH], int &entity, int &channel, float &volume, int &level, int &pitch, int &flags, char soundEntry[PLATFORM_MAX_PATH], int &seed)
{
    if(!bIsInfected(entity) || !bIsRootAdmin(entity) || !bCloaked[entity])
    {
        return Plugin_Continue;
    }

    if(!bPlayToSelf)
    {
        return Plugin_Stop;
    }

    numClients = 0;
    for(int i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(i) && GetClientTeam(i) == 3 && bIsRootAdmin(i) && i == entity)
        {
            clients[numClients] = i;
            numClients++;
        }
    }

    return Plugin_Changed;
}

public void OnPluginEnd()
{
    cvPlayToSelf.RemoveChangeHook(OnCDCVarChanged);
    delete cvPlayToSelf;
    UnhookEvent("player_death", OnPlayerDeath, EventHookMode_Pre);
    RemoveAmbientSoundHook(OnAdminASCheck);
    RemoveNormalSoundHook(OnAdminNSCheck);
}

public void OnClientDisconnect(int client)
{
    if(!bIsRootAdmin(client) || !bCloaked[client])
    {
        return;
    }

    bCloaked[client] = false;
    SDKUnhook(client, SDKHook_SetTransmit, OnSetTransmit);
}

public Action OnPlayerDeath(Event event, const char[] name, bool dontBroadcast)
{
    int idied = GetClientOfUserId(event.GetInt("userid"));
    int ikiller = GetClientOfUserId(event.GetInt("attacker"));
    if(bIsInfected(idied) && bIsRootAdmin(idied) && bCloaked[idied] && bIsSurvivor(ikiller))
    {
        bCloaked[idied] = false;
        SDKUnhook(idied, SDKHook_SetTransmit, OnSetTransmit);
        SetEntityRenderMode(idied, RENDER_NORMAL);
        SetEntityRenderColor(idied, _, _, _, 255);
        PrintToChat(idied, "\x05[\x03CD\x05]\x04 %N\x01 killed you while you were cloaked!", ikiller);
    }

    return Plugin_Continue;
}

public void OnMapEnd()
{
    for(int i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(i) && bCloaked[i])
        {
            bCloaked[i] = false;
            SDKUnhook(i, SDKHook_SetTransmit, OnSetTransmit);
        }
    }
}

bool bIsSurvivor(int client)
{
    return (client > 0 && client <= MaxClients && IsClientConnected(client) && IsClientInGame(client) && GetClientTeam(client) == 2);
}

bool bIsInfected(int client)
{
    return (client > 0 && client <= MaxClients && IsClientConnected(client) && IsClientInGame(client) && GetClientTeam(client) == 3);
}

bool bIsRootAdmin(int client)
{
    return (CheckCommandAccess(client, "sm_cdetect", ADMFLAG_ROOT, false));
} 


[SilentBr]

Originally Posted by Crasher_3637 Try this one.

This was everything that I needed to identify some wallhackers on my versus server. It is working like a charm. Even my teammates are not able to see me.

In my opinion, this plugin should be released/official L4D2.

I've tried stop wallhackers blocking addons, SMAC Anti Wallhack (sound problem) without success.

I want to say thanks to cravenge and Crasher_3637 for helping me with this plugin idea.

PS: Sorry about the loooong delay to reply, I'm already using this on my server and loving it.