[blanko]

At each roundstart, one random player will receive a desert eagle for free. +full ammo for deagle

[EFFx]

Here's:

PHP Code:

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>
#include <fun>
 
#define PLUGIN "Random deagle"
#define VERSION "1.0"
#define AUTHOR "EFFx"
 
public plugin_init() 
{
 register_plugin(PLUGIN, VERSION, AUTHOR)
 
 register_event("ResetHUD", "GiveDeagle", "b") 
}
public GiveDeagle()
{
 new players[32],iNum,random_player
 get_players(players,iNum)
 random_player = players[random(iNum)]
 new szName[33]
 get_user_name(random_player,szName,32)
 if(is_user_alive(random_player))
 {
  give_item(random_player,"weapon_deagle")
  cs_set_user_bpammo(random_player,CSW_DEAGLE,35)
 }
 client_print(0,print_chat,"[AMXX]: Random player is %s. He've received a eagle + full ammo",szName)
} 


[HamletEagle]

Originally Posted by EFFx Here's: PHP Code: #include <amxmodx> #include <cstrike> #include <hamsandwich> #include <fun>   #define PLUGIN "Random deagle" #define VERSION "1.0" #define AUTHOR "EFFx"   public plugin_init()  {  register_plugin(PLUGIN, VERSION, AUTHOR)    RegisterHam(Ham_Spawn,"player","GiveDeagle",1) } public GiveDeagle() {  new players[32],iNum,random_player  get_players(players,iNum)  random_player = players[random(iNum)]  new szName[33]  get_user_name(random_player,szName,32)  if(is_user_alive(random_player))  {   give_item(random_player,"weapon_deagle")   cs_set_user_bpammo(random_player,CSW_DEAGLE,35)  }  client_print(0,print_chat,"[AMXX]: Random player is %s. He've received a eagle + full ammo",szName) }

You have no ideea what you are doing, don't you?

[EpicMonkey]

GiveDeagle() will be executed for every player spawn ...

[EFFx]

Oh sorry, try now

[OciXCrom]

PHP Code:

#include <amxmodx>
#include <cstrike>
#include <fun>

public plugin_init()
{
    register_plugin("Random Deagle", "1.0", "OciXCrom")
    register_logevent("eventRoundStart", 2, "1=Round_Start")
}

public eventRoundStart()
{
    new iPlayers[32], iPnum
    get_players(iPlayers, iPnum, "a")
    
    if(!iPnum)
        return
    
    new id = iPlayers[random(iPnum)]
    
    if(id && is_user_alive(id))
    {
        new szName[32]
        get_user_name(id, szName, charsmax(szName))
        give_item(id, "weapon_deagle")
        cs_set_user_bpammo(id, CSW_DEAGLE, 35)
        client_print(0, print_chat, "[Random Deagle] The random player this round is %s", szName)
    }
} 


[blanko]

Originally Posted by OciXCrom PHP Code: #include <amxmodx> #include <cstrike> #include <fun> public plugin_init() {     register_plugin("Random Deagle", "1.0", "OciXCrom")     register_logevent("eventRoundStart", 2, "1=Round_Start") } public eventRoundStart() {     new iPlayers[32], iPnum     get_players(iPlayers, iPnum, "a")          if(!iPnum)         return          new id = iPlayers[random(iPnum)]          if(id && is_user_alive(id))     {         new szName[32]         get_user_name(id, szName, charsmax(szName))         give_item(id, "weapon_deagle")         cs_set_user_bpammo(id, CSW_DEAGLE, 35)         client_print(0, print_chat, "[Random Deagle] The random player this round is %s", szName)     } }

Thank you! I don't know to change the message color, is it possible?

[EFFx]

Just add colorchat include or stock:

PHP Code:

stock ChatColor(const id, const input[], any:...) 
{
 new count = 1, players[ 32 ]
 static msg[ 191 ]
 vformat( msg, 190, input, 3 )
   
 replace_all( msg, 190, "!g", "^4" )
 replace_all( msg, 190, "!y", "^1" )
 replace_all( msg, 190, "!t", "^3" )
   
 if(id) players[ 0 ] = id; else get_players( players, count, "ch" )
 {
  for(new i = 0; i < count; i++)
  {
   if( is_user_connected( players[ i ] ) )
   {
    message_begin( MSG_ONE_UNRELIABLE, get_user_msgid("SayText"), _, players[ i ] )  
    write_byte( players[ i ] )
    write_string( msg )
    message_end( )
   }
  }
 }
} 


PHP Code:

ChatColor(0,"!g[Random Deagle]!y The random player in this round is!g %s",szName) 


[blanko]

Oh, I forgot something very important: drop the current pistol before giving the random deagle.

[OciXCrom]

PHP Code:

#include <amxmodx>
#include <colorchat>
#include <cstrike>
#include <fun>
#include <stripweapons>

public plugin_init()
{
    register_plugin("Random Deagle", "1.1", "OciXCrom")
    register_logevent("eventRoundStart", 2, "1=Round_Start")
}

public eventRoundStart()
{
    new iPlayers[32], iPnum
    get_players(iPlayers, iPnum, "a")
    
    if(!iPnum)
        return
    
    new id = iPlayers[random(iPnum)]
    
    if(id && is_user_alive(id))
    {
        new szName[32]
        get_user_name(id, szName, charsmax(szName))
        StripWeapons(id, Secondary)
        give_item(id, "weapon_deagle")
        cs_set_user_bpammo(id, CSW_DEAGLE, 35)
        ColorChat(0, TEAM_COLOR, "^4[Random Deagle] ^1The random player this round is ^3%s", szName)
    }
} 


colorchat.inc, stripweapons.inc