[lexzor]

can this code produce issues or it s a better way to do it ?

PHP Code:

public open_all_clans_menu(id)
{
    new szQuery2[512], szData[1];
    szData[0] = id;
    formatex(szQuery2, charsmax(szQuery2), "SELECT * FROM `%s` ORDER BY (total_clan_kills) DESC", g_szTables[0]);
    SQL_ThreadQuery(g_SqlTuple, "ShowAllClans", szQuery2, szData, sizeof(szData));
}

public ShowAllClans(FailState, Handle:Query, szError[], ErrorCode, szData[], iSize)
{  
    if(FailState || ErrorCode)
        log_amx("^nSQL ERROR: %s^n", szError);

    new id = szData[0];
    if(!is_user_connected(id))
        return PLUGIN_HANDLED;

    new szTitle[64], szClanName[32], szClanLeader[64], szPassData[64], szItem[128];
    new iResults = SQL_NumResults(Query);
    new iTotalClanKills;
    new iClanRank = 0;

    formatex(szTitle, charsmax(szTitle), "%L", id, "FRAGTOP_CLANS_MENU_TITLE");
    new iMenu = menu_create(szTitle, "show_all_clans_handler");

    formatex(szItem, charsmax(szItem), "%L", id, "FRAGTOP_CLANS_MENU_FIRST_OPTION");
    menu_additem(iMenu, szItem);

    if(iResults > 0)
    {
        for(new i = 0 ; i < iResults; i++)
        {
            SQL_ReadResult(Query, 1, szClanName, charsmax(szClanName));
            SQL_ReadResult(Query, 3, szClanLeader, charsmax(szClanLeader));
            iTotalClanKills = SQL_ReadResult(Query, 6);
            iClanRank += 1;
            formatex(szPassData, charsmax(szPassData), "^"%s^" %i %i", szClanLeader, iTotalClanKills, iClanRank);
            formatex(szItem, charsmax(szItem), "\r[\w%s\r]\d - \r[\w%s\r]\d - \r[\w%i\r]", szClanName, szClanLeader, iTotalClanKills);
            menu_additem(iMenu, szItem, szPassData);

            SQL_NextRow(Query);
        }
    }

    menu_setprop(iMenu, MPROP_EXIT, MEXIT_ALL);
    menu_display(id, iMenu, 0, -1);
    
    SQL_FreeHandle(Query);

    return PLUGIN_CONTINUE;
} 


[CrazY.]

Your code is okay but there is a better alternative. Instead of loading from the SQL database everytime you open a menu, load it one time on plugin_cfg/plugin_init and store everything in a trie or an array, the one that looks better for you. Do the same to update the db, one time but on plugin_end. You could also periodically update the db setting a repeatable task for example, if your server doesn't crash frequently you don't need that. If you need an example I may provide.

[Bugsy]

I'd do pretty much what CrazY. said.

@plugin_init/plugin_cfg
Load data from db table into a variable/array

@During gameplay, increment variables as needed (kills, deaths, etc.)
If you do not do this, your plugin will only have the values from map start, and not reflect current changes from gameplay

@plugin_end
Call an UPDATE statement to set variable values that have changed back into table fields

[lexzor]

i want something like "live top". thanks you all

[Bugsy]

What is live top

[lexzor]

plugin calculate total clan kills for every created clan after saving online members kills then show the top

like

PHP Code:

public ReadClansTable(FailState, Handle:Query, szError[], ErrorCode, szData[], iSize)
{
    if(FailState || ErrorCode)
        log_amx("^nSQL ERROR: %s^n", szError);

    new iResults = SQL_NumResults(Query);
    new szClanName[64];
    new szQuery[512];
    new szPassData[64];
    new id = szData[0];

    if(iResults > 0)
    {
        for(new i = 0; i < iResults; i++)
        {
            SQL_ReadResult(Query, 1, szClanName, charsmax(szClanName));
            formatex(szPassData, charsmax(szPassData), "%s %i", szClanName, id);
            formatex(szQuery, charsmax(szQuery), "SELECT * FROM `%s` ORDER BY (id) ASC", szClanName);
            SQL_ThreadQuery(g_SqlTuple, "GetFrags", szQuery, szPassData, charsmax(szPassData));

            SQL_NextRow(Query);
        }
    }
    else
    {
        clan_menu(id);
        client_print_color(id, print_team_default, "%s %L", g_szTag, id, "NO_CLANS");
    }

    SQL_FreeHandle(Query);
}

public GetFrags(FailState, Handle:Query, szError[], ErrorCode, szData[], iSize)
{
    if(FailState || ErrorCode)
        log_amx("^nSQL ERROR: %s^n", szError);

    new iResults = SQL_NumResults(Query);
    new iMemberFrags, iClanFrags;

    new szClanName[64], szUserID[2];
    parse(szData, szClanName, charsmax(szClanName), szUserID, charsmax(szUserID));

    if(iResults > 0)
    {
        for(new i = 0; i < iResults; i++)
        {
            iMemberFrags = SQL_ReadResult(Query, 5);
            iClanFrags += iMemberFrags;
            SQL_NextRow(Query);
        }
    }

    new szQuery[512];
    formatex(szQuery, charsmax(szQuery), "UPDATE `%s` SET `total_clan_kills` = '%i' WHERE `clan_name` = '%s'",
    g_szTables[0], iClanFrags, szClanName);
    SQL_ThreadQuery(g_SqlTuple, "FreeHandle", szQuery);

    SQL_FreeHandle(Query);
} 


[JocAnis]

Hmm only possible issue could be if all 30 players execute that sql function in same second, but its really small chance.
I was thinking of your method + adding check of minimum 1 (or more) second gap between that function calls, meaning you would need also a global variable to store your inputs..but its not worth when we think better

Ps: excuse me if i totally missed your idea here)

[Bugsy]

I'd create 2 tables, one for clans and one for players.

At any given time you have easy access, in a variable, the total clan kills as well as total player kills. You can also print out what percentage of total clan kills an individual player did.

Let me know if you have any questions

PHP Code:


#include <amxmodx>

const MaxClans = 50;

enum ClanInfo
{
    ClanName[ 32 ],
    ClanKills
}
new g_ciClanData[ MaxClans ][ ClanInfo ];

/*

Clan table (tblClans)
    ID - Auto number, ClanID
    ClanName - Name of Clan
    ClanKills - Total clan Kills

Player table (tblPlayers)
    ID - Auto number, Player ID
    ClanID - ID from Clan table
    Name - Player name
    SteamID - Player steam ID
    PlayerKills - Player kills
    
*/

enum PlayerData
{
    ClanID,
    PlayerName[ 32 ],
    AuthID[ 34 ],
    PlayerKills
}
new g_pdData[ MAX_PLAYERS + 1 ][ PlayerData ];

public plugin_init() 
{
    
}

public plugin_cfg() 
{
    //SELECT ID, ClanName, ClanKills FROM tblClans
    
    //for ( new i = 0 ; i < NumResults ; i++ )
    //{
    //    g_ciClanData[ i ][ ClanName ] = tblClans.ClanName;
    //    g_ciClanData[ i ][ ClanKills ] = tblClans.ClanKills;
    //}    
}

public plugin_end() 
{
    //for ( new i = 0 ; i < MaxClans ; i++ )
    //{
    //    if ( g_ciClanData[ i ][ ClanName ][ 0 ] != EOS )
    //    {
    //        UPDATE tblClans SET ClanKills=g_ciClanData[ i ][ ClanKills ] WHERE ID=i
    //    }
    //}    
}
public client_authorized( id )
{
    get_user_authid( id , g_pdData[ id ][ AuthID ] , charsmax( g_pdData[][ AuthID ] ) );
    //SELECT ClanID, PlayerKills FROM tblPlayers WHERE SteamID=g_pdData[ id ][ AuthID ]
    
    g_pdData[ id ][ ClanID ] = tblPlayers.ClanID;
    g_pdData[ id ][ PlayerKills ] = tblPlayers.PlayerKills;
}

public PlayerKill( id )
{
    g_ciClanData[ g_pdData[ id ][ ClanID ] ][ ClanKills ]++;
    g_pdData[ id ][ PlayerKills ]++;
}

public client_disconnect( id )
{
    //UPDATE tblPlayers SET PlayerKills=g_pdData[ id ][ PlayerKills ] WHERE AuthID=g_pdData[ id ][ SteamID ];
} 


[lexzor]

i create 2 tables:

1 with all clans,
1 with user name steamid and clan

then if a players create a clan, a table with that name is created so every clan has his own table with all members

[Bugsy]

A separate table for each clan is overkill. I'd just do 1 table with all clans, and then link players to that table using clan ID.