[xines]

Just ran a quick test on srcds with bots, the disable buyzone function works but its not activating again not even after new round

[Bacardi]

aaa ? I tested and it should.
Bu if you haven't change mp_buytime 0.25, what is 15 seconds.
Set mp_buytime 999 and you should see it again.

[xines]

even with "mp_buytime 999" it just says "you are not in a buyzone" even 2 mins after new round :/?

[Bacardi]

ok, I think I found bug. Entity own timer stop when round restart before it execute "Enable".


another method would also to set mp_buytime to 0 and back...

But using same method as before, enable func_buyzone when round restart.

Spoiler

PHP Code:

#include <sdktools>

public Plugin:myinfo = {
    name = "Knife Round",
    author = "Bacardi"
};

public OnPluginStart()
{
    RegAdminCmd("sm_kniferound", cmd_knife, ADMFLAG_CUSTOM1, "Remove all weapons except knife on next round start");
    //RegAdminCmd("sm_knife", cmd_knife, ADMFLAG_CUSTOM1, "Remove all weapons except knife on next round start");

    HookEvent("round_start", round_start, EventHookMode_PostNoCopy);
}

public Action:cmd_knife(client, args)
{
    round_start(INVALID_HANDLE, "round_knife", false);

    return Plugin_Handled;
}


public round_start(Handle:event, const String:name[], bool:dontBroadcast)
{
    static bool:IsKnifeRound = false;

    if(StrEqual(name, "round_knife"))
    {
        IsKnifeRound = true;
        PrintToChatAll("\x01[SM] \x04Knifes in the next round starts!");
        return;
    }

    if( !IsKnifeRound )
    {
        Strip(false);
    }


    if( IsKnifeRound )
    {
        CreateTimer(4.0, delay, _, TIMER_FLAG_NO_MAPCHANGE);
    }
    IsKnifeRound = false;
}

public Action:delay(Handle:timer)
{
    Strip(true);
}

Strip(bool:TimerExecuted)
{
    new ent = MaxClients+1;

    while( (ent = FindEntityByClassname(ent, "func_buyzone")) != -1 )
    {
        if( TimerExecuted )
        {
            AcceptEntityInput(ent, "Disable");
            SetVariantString("OnUser1 !self,Enable,,60.0,-1");
            AcceptEntityInput(ent, "AddOutput");
            AcceptEntityInput(ent, "FireUser1");
        }
        else
        {
            AcceptEntityInput(ent, "Enable");
        }
    }

    if( !TimerExecuted )
    {
        return;
    }

    new String:clsname[] = "weapon_knife";
    ent = MaxClients+1;

    while( (ent = FindEntityByClassname(ent, "weapon_*")) != -1 )
    {
        if( GetEntityClassname(ent, clsname, sizeof(clsname)) )
        {
            if( !StrEqual(clsname, "weapon_knife") )
            {
                if( GetEntProp(ent, Prop_Send, "m_iState") == 2 ) // player hold this weapon currently
                {
                    new client = GetEntPropEnt(ent, Prop_Send, "m_hOwnerEntity");

                    if( GetPlayerWeaponSlot(client, 3) == -1 ) // Not own knife ?
                    {
                        CreateTimer(0.0, give_knife, GetClientUserId(client), TIMER_FLAG_NO_MAPCHANGE);
                    }

                    FakeClientCommandEx(client, "use weapon_knife");
                    PrintToChat(client, "\x01[SM] \x04Did you hear ? It's knife round!");
                }

                AcceptEntityInput(ent, "Kill");
            }
            else if( GetEntProp(ent, Prop_Send, "m_iState") == 0 ) // Extra knifes on field, wonder why...
            {
                AcceptEntityInput(ent, "Kill");
            }
        }
    }
}

public Action:give_knife(Handle:timer, any:userid)
{
    new client = GetClientOfUserId(userid);

    if(client != 0 && IsClientInGame(client) && GetClientTeam(client) >= 2 && IsPlayerAlive(client) )
    {
        GivePlayerItem(client, "weapon_knife");
    }
} 


[xines]

okay this seems to be working pretty good ! gonna test this with good amount of players online and see what happens !!
ill post the results

[xines]

Its working perfectly no crash no lag nothing<3 Thank you Bacardi!

[Bacardi]

You're welcome.