[asherkin]

At this point, the answer is quite clear.

[Oshizu]

Jesus guys where did all those outdated snippets come from

[luki1412]

Originally Posted by asherkin At this point, the answer is quite clear.

Sadly, yes.

[luki1412]

Originally Posted by Oshizu Jesus guys where did all those outdated snippets come from

Old plugins.
Your post isn't helping either.

[luki1412]

There is a way, actually! Got it to work without tf2items.

[gvngngr]

Hello, could you share how you managed to do it, if you still have/remember the code?

[PC Gamer]

Originally Posted by gvngngr Hello, could you share how you managed to do it, if you still have/remember the code?

Here's a link to the terrific plugin made by Luki1412 to give weapons to Bots: https://forums.alliedmods.net/showthread.php?p=2453169

Code snippet. Requires a gamedata file for WeaponEquip:

PHP Code:

bool CreateWeapon(int client, char[] classname, int itemindex, int level = 0)
{
    int weapon = CreateEntityByName(classname);
    
    if (!IsValidEntity(weapon))
    {
        return false;
    }
    
    char entclass[64];
    GetEntityNetClass(weapon, entclass, sizeof(entclass));
    SetEntData(weapon, FindSendPropInfo(entclass, "m_iItemDefinitionIndex"), itemindex);     
    SetEntData(weapon, FindSendPropInfo(entclass, "m_bInitialized"), 1);
    SetEntData(weapon, FindSendPropInfo(entclass, "m_iEntityQuality"), 6);

    if (level)
    {
        SetEntData(weapon, FindSendPropInfo(entclass, "m_iEntityLevel"), level);
    }
    else
    {
        SetEntData(weapon, FindSendPropInfo(entclass, "m_iEntityLevel"), GetRandomUInt(1,99));
    }

    switch (itemindex)
    {
        case 810:
        {
            SetEntData(weapon, FindSendPropInfo(entclass, "m_iObjectType"), 3);
        }
        case 998:
        {
            SetEntData(weapon, FindSendPropInfo(entclass, "m_nChargeResistType"), GetRandomUInt(0,2));
        }
    }
    
    DispatchSpawn(weapon);
    SDKCall(g_hWeaponEquip, client, weapon);
    return true;
} 


[gvngngr]

Originally Posted by PC Gamer Here's a link to the terrific plugin made by Luki1412 to give weapons to Bots: https://forums.alliedmods.net/showthread.php?p=2453169 Code snippet. Requires a gamedata file for WeaponEquip: PHP Code: bool CreateWeapon(int client, char[] classname, int itemindex, int level = 0) {     int weapon = CreateEntityByName(classname);          if (!IsValidEntity(weapon))     {         return false;     }          char entclass[64];     GetEntityNetClass(weapon, entclass, sizeof(entclass));     SetEntData(weapon, FindSendPropInfo(entclass, "m_iItemDefinitionIndex"), itemindex);          SetEntData(weapon, FindSendPropInfo(entclass, "m_bInitialized"), 1);     SetEntData(weapon, FindSendPropInfo(entclass, "m_iEntityQuality"), 6);     if (level)     {         SetEntData(weapon, FindSendPropInfo(entclass, "m_iEntityLevel"), level);     }     else     {         SetEntData(weapon, FindSendPropInfo(entclass, "m_iEntityLevel"), GetRandomUInt(1,99));     }     switch (itemindex)     {         case 810:         {             SetEntData(weapon, FindSendPropInfo(entclass, "m_iObjectType"), 3);         }         case 998:         {             SetEntData(weapon, FindSendPropInfo(entclass, "m_nChargeResistType"), GetRandomUInt(0,2));         }     }          DispatchSpawn(weapon);     SDKCall(g_hWeaponEquip, client, weapon);     return true; }

Thank you for your reply.
I also saw the plugin afterwards and been trying to implement the relevant parts inside my code.
I am creating this for TF2Classic so it is not possible to use TF2Items. Only base Sourcemod works. That's why I need this one.
But m_bInitialized causes an error. And when I comment it out, there is no error but I don't have the weapon I desire either.

Below is what I have inside the code. I am a new starter in sourcemod coding so I'm sorry if it's poorly written. I'm trying to give the client a Sniper rifle when s/he changes class to Scout. This is not what I am ultimately trying to achieve but it's just a simple example case to make it work as a first step.

PHP Code:

Handle g_hWeaponEquip;
Handle g_hGameConfig;

public void OnPluginStart()
{
HookEvent("player_changeclass", Event_PlayerClass);

g_hGameConfig = LoadGameConfigFile("give.bots.weapons");
    
    if (!g_hGameConfig){
    SetFailState("Failed to find give.bots.weapons.txt gamedata! Can't continue.");
    }
    
    StartPrepSDKCall(SDKCall_Player);
    PrepSDKCall_SetFromConf(g_hGameConfig, SDKConf_Virtual, "WeaponEquip");
    PrepSDKCall_AddParameter(SDKType_CBaseEntity, SDKPass_Pointer);
    g_hWeaponEquip = EndPrepSDKCall();
    
    if (!g_hWeaponEquip){
    SetFailState("Failed to prepare the SDKCall for giving weapons. Try updating gamedata or restarting your server.");
    }
}

public void Event_PlayerClass(Event event, const char[] name, bool dontBroadcast){
    
int iClient = GetClientOfUserId(event.GetInt("userid")),
    iClass = event.GetInt("class");
    
if (iClass==1){
    PrintToServer("Scout class is selected.");
        
    if(!g_hWeaponEquip){
    PrintToServer("g_hWeaponEquip is not valid."); /*just checking*/
    }
    
    TF2_RemoveWeaponSlot(iClient, 0);
    int weapon = CreateEntityByName("tf_weapon_sniperrifle");
    char entclass[64];
    GetEntityNetClass(weapon, entclass, sizeof(entclass));
    SetEntData(weapon, FindSendPropInfo(entclass, "m_iItemDefinitionIndex"),14);
    SetEntData(weapon, FindSendPropInfo(entclass, "m_bInitialized"),1);
    DispatchSpawn(weapon);
    SDKCall(g_hWeaponEquip, iClient, weapon);
}

} 


This is what I have inside "...\tf2classic\addons\sourcemod\gamedata\giv e.bots.weapons.txt", as created by Luki except the "tf2classic" part:

PHP Code:

"Games"
{
    /* Team Fortress 2 */
    "tf2classic" /*I think I tried it with "tf" as well*/
    {
        "Offsets"
        {
            "WeaponEquip"
            {
                "windows"    "264"
                "linux"        "265"
                "mac"        "265"
            }
            
            "EquipWearable"
            {
                "windows"    "430"
                "linux"        "431"
                "mac"        "431"
            }
        }
    }
} 


This is the error I get:

And Line 60 is this one: SetEntData(weapon, FindSendPropInfo(entclass, "m_bInitialized"),1); And as I said above, when I remove it, then there is no error, but I don't get a sniper rifle as a scout either. So, I am not sure but this line may be essential for the entity?

I have already deleted some properties like EntityQuality, thinking that it doesnot exist in TF2Classic. But this issue might also be due to TF2Classic itself.

Thanks in advance for any help/advice.

[PC Gamer]

The code you presented didn't work for me in TF2. The problem might be that the code is fired too early. The code fires when a player selects a class and before the player actually equips their weapons. You could probably test that theory by implementing a timer before removing/equipping weapons.

Alternatively, you could use a different event, like the player inventory event that fires when a player touches a locker or spawns. The following code was tested using player inventory event in TF2 and it works. I hope it helps!

PHP Code:

#include <sourcemod>
#include <tf2_stocks>

Handle g_hWeaponEquip;
Handle g_hGameConfig;

public void OnPluginStart()
{
    HookEvent("post_inventory_application", player_inv);
    g_hGameConfig = LoadGameConfigFile("give.bots.weapons");
    
    if (!g_hGameConfig){
        SetFailState("Failed to find give.bots.weapons.txt gamedata! Can't continue.");
    }
    
    StartPrepSDKCall(SDKCall_Player);
    PrepSDKCall_SetFromConf(g_hGameConfig, SDKConf_Virtual, "WeaponEquip");
    PrepSDKCall_AddParameter(SDKType_CBaseEntity, SDKPass_Pointer);
    g_hWeaponEquip = EndPrepSDKCall();
    
    if (!g_hWeaponEquip){
        SetFailState("Failed to prepare the SDKCall for giving weapons. Try updating gamedata or restarting your server.");
    }
}

public void player_inv(Handle event, const char[] name, bool dontBroadcast){
    
    int userd = GetEventInt(event, "userid");
    int iClient = GetClientOfUserId(userd);
    
    if (TF2_GetPlayerClass(iClient) == TFClass_Scout){
        PrintToServer("%N selected Scout class.", iClient);
        
        TF2_RemoveWeaponSlot(iClient, 0);

        int weaponprimary = CreateEntityByName("tf_weapon_sniperrifle");
        char entclass[64];
        GetEntityNetClass(weaponprimary, entclass, sizeof(entclass));
        SetEntData(weaponprimary, FindSendPropInfo(entclass, "m_iItemDefinitionIndex"), 14);     
        SetEntData(weaponprimary, FindSendPropInfo(entclass, "m_bInitialized"), 1);
        SetEntData(weaponprimary, FindSendPropInfo(entclass, "m_iEntityLevel"), 100);
        SetEntData(weaponprimary, FindSendPropInfo(entclass, "m_iEntityQuality"), 5);

        DispatchSpawn(weaponprimary);
        SDKCall(g_hWeaponEquip, iClient, weaponprimary);        
    }

} 


[StrikeR14]

I liked your solution PC Gamer, you should use SetEntProp with Prop_Send instead of SetEntData. It does not crash servers now.