[FurYXO]

Hey!
I have an plugin which gives healthshot to VIP players.
I have a problem with it, when the round ends, and the next round is starting, the healthshots is getting dropped into to floor, because the limit is 1 in the server.

I want to remove the non used healthshots at the end of the round. Here is the code:

PHP Code:

#include <sourcemod>
#include <sdkhooks>
#include <sdktools>

#pragma semicolon 1
#pragma newdecls required

public Plugin myinfo =
{
    name = "MagyarHNS VIP Gránátok",
    description = "Healthshot a VIP-eknek",
    author = "Ervin",
    version = "1.0.0",
    url = "www.magyarhns.hu"
};

public void OnPluginStart()
{
    HookEvent("player_spawn", Event_PlayerSpawn, EventHookMode_Post);
}

public void Event_PlayerSpawn(Event hEvent, const char[] sEventName, bool bDontBroadcast)
{
    int userid = hEvent.GetInt("userid");
    
    if (IsClientInGame(GetClientOfUserId(userid)))
    {
        CreateTimer(0.3, Timer_Delay, userid, TIMER_FLAG_NO_MAPCHANGE);
    }
}

public Action Timer_Delay(Handle hTimer, int userid)
{
    int client = GetClientOfUserId(userid);

    if(IsClientInGame(client) && CheckCommandAccess(client, "lofasz", ADMFLAG_CUSTOM6))
    {
        switch (GetClientTeam(client))
        {
            case 2:
            {
                GivePlayerItem(client, "weapon_healthshot");
            }
            case 3:
            {
                GivePlayerItem(client, "weapon_healthshot");
            }
        }
    }
} 


[Rohanlogs]

A wise man once said

Originally Posted by headline If you don't want to give someone the same gun twice, check if they already have it.

So, try this.

Spoiler

PHP Code:

#include <sourcemod>
#include <sdkhooks>
#include <sdktools>

#pragma semicolon 1
#pragma newdecls required


public Plugin myinfo =
{
    name = "MagyarHNS VIP Gránátok",
    description = "Healthshot a VIP-eknek",
    author = "Ervin",
    version = "1.0.0",
    url = "www.magyarhns.hu"
};


public void OnPluginStart()
{
    HookEvent("player_spawn", Event_PlayerSpawn, EventHookMode_Post);
}


public void Event_PlayerSpawn( Event hEvent, const char[] sEventName, bool bDontBroadcast )
{
    int userid = hEvent.GetInt("userid");
    
    if( IsClientInGame( GetClientOfUserId(userid) ) )
        CreateTimer(0.3, Timer_Delay, userid, TIMER_FLAG_NO_MAPCHANGE);
}


public Action Timer_Delay(Handle hTimer, int userid)
{
    int client = GetClientOfUserId(userid);
    
    if( IsClientInGame(client) && CheckCommandAccess(client, "lofasz", ADMFLAG_CUSTOM6) )
    {
        // Check if client already has the item
        if( !_fwHasWeapon(client, "weapon_healthshot") )
        {
            switch( GetClientTeam(client) )
            {
                case 2: GivePlayerItem(client, "weapon_healthshot");
                case 3: GivePlayerItem(client, "weapon_healthshot");
            }
        }
    }
}


stock bool _fwHasWeapon( int iClient, const char[] sWeap )
{
    int iLen = GetEntPropArraySize(iClient, Prop_Send, "m_hMyWeapons"); 
    
    for (int i= 0; i < iLen; i++)  
    {
        int item = GetEntPropEnt(iClient, Prop_Send, "m_hMyWeapons", i);  
        
        if (item != -1)  
        {
            char sClass[64]; 
            
            if( GetEntityClassname( item, sClass, sizeof(sClass) ) )
                if( StrEqual(sWeap, sClass, false) ) return true;
        }
    }
    return false;
} 


[8guawong]

maybe this is what you want

"mp_equipment_reset_rounds" = "0"
FCVAR_GAMEDLL FCVAR_REPLICATED FCVAR_RELEASE
- Reset all player equipment every N rounds (0 for never)

[Austin]

This probably doesn't apply to your question,
but FYI you can set the number to have and if they are dropped on death.

ammo_item_limit_healthshot 4
mp_death_drop_healthshot 1