[Brreaker]

No more cs 1.6 models on fpsbanana?!?!?!I'll let u know if I find something

Edit:
You could use the bazooka model from the bazooka plugin :-??

[Arkshine]

@Arkshine: I don't know, If I post the whole code to the public, shouldn't I first get permission from DevconeS? (the author of WeaponMod)

The code is open-source, you are free to do what you want, just leave the proper credits. But you can ask him if you want, it will not hurt. I suggest you to make a depositary because it seems your knowledge is limited :p and i'm afraid the code is getting worse than the original. If we see your changes, people can make comments and help you more easily to improve WM. ;)


About WM, the way of choosing the weapon pisses me off. :p
If I was going to improve WM, I would do for the next major version, at least :

- Moving the core into a module.

In the same way as MonsterAI, I would like to see the core as module and weapon as pawn plugin. This way, you gain a lot in efficiency. You could also simplified a lot of things. Making weapons more easily. etc. But there is not much people who can make modules.

- Dropping the multimod support, only CS/CZ.

Really, it's a pain to add support for others mods, more when they are almost no more played. Except if there are some people ready to test, giving ideas, helping etc., I would prefer to focus on the most played game and doing something nice. Maybe if there are much requests to port on another game, from this time we could considerate to do find specific to this game, but I doubt it will happen.

- Changing the way of choosing a weapon.

Really, I don't like the actual system. I know Devcones has tried to find the best way for all the mods supported, still really unpractical with too many weapons.

A better system for me (cs/cz), would be to use the existing slots. The mouse scroll would work and it would be more easier to select a weapon.
I think there are 2 specifics situations where WM should handle differently the things:

- You care about the default weapons and you want the new weapons be integrated properly, keeping the same system.

* The VGUI menu should be disabled.
* The whole buying menu should be redone including the new weapons/item/etc.
* Each new weapon should be associated to a slot : primary/handguns/melee/grenade/c4/misc, to keep the same way as the default one.
* Default gameplay, you can't have more than one weapon for primary/handguns/melee

- You don't care about the defaut weapons, you want only new weapons.

* We have 6 availables slots. We could try to associate each with a specific meaning like : melee/handguns/normal/heavy/explosive/misc
* Associating each new weapon with a default weapon. I mean for example, all the melee associated to the knife.
* Defining how many weapons we can have by slot.
* When we select a slot, we should see below a list of availables weapons of this slot. For example, if you have severals melee weapons, you would see only severals knifes. So, to help to choose we can give a list of these weapons with their name. Of course the selection weapon is also selected in the list. You get the idea.
* If buying is necessary in this situation, a differente menu should be done and organized by type.

- Using now Orpheu to gain in effiency. (in case where the core is still as pawn plugin)

We should use the available internal CS functions when we can.

Just some random thoughts.
After that, WM needs also more flexibily because some weapons can't follow the WM design. When I've done the HL1 Gauss weapon, I had really a hard time to make it working with WM.
EDIT : One thing which it needs to be considerate is too much weapons = too much resources to download. One thing which could reduce is to provide default weapons and merging severals p_ w_ into one model.

[SeriousSam]

Well, as far as I know, some guy from the staff deleted it as a joke when he left the staff, and now they obviously don't have a backup, so they just made it again, and people started uploading models again, but ATM there are only a handfull of models for cs 1.6, so sad. So now I'm downloading condition zero models, they work in cs 1.6 just fine.

@Arkshine: you have some good ideas, but most of them are far away from me, because as you mentioned, my knowledge in pawn is of a novice. I should add to the ideas to work on your idea of having only one primary and one pistol. I have no idea on how to change the slot of the weapon and add a sprite for the weapon. I do want to do a whole new VGUI menu, but I wonder if it is even possible, or if we're only allowed to use text menus in pawn?

[Arkshine]

You can't mess with the HUD sprites, nor creating a new VGUI. Sorry If I've explained badly. Because of we can have such things we have to find alternative solution or add some things to help.

[SeriousSam]

I entered code.google.com as you told me and logged into my google account, but I couldn't find where to enter to add a new project
Too bad that we can't edit the VGUI buy menu or make a new one. Making an all-text buy menu containing both original and custom weapons will be bad in a way too, as it will get too full of weapons, so I kind of like it having the original weapons in one and the new in another. Also, if we make a menu with all the weapons in it, we will probably have to block the original menu, and then a lot of players in the server will complain about not being able to buy weapons until they find out how to activate the new menu. As for the hud sprites for the weapon slots and the killer X victim announcements, I think it will be a good idea to at least add text variants somewhere on the hud, using the weapon shortnames. Right now, my main concern is the bug where you zoom in a sniper weapon, then switch to another and the zoom stays on. I tried using the hide event to reset the zoom, but it seems to only work when switching to a knife.

[Arkshine]

http://code.google.com/hosting/

[SeriousSam]

Finally made the bullets to go through walls, yahoi! They do a bullet hole and sparkles on both first and second wall, and do damage if hit an enemy behind the wall. The damage and accuracy is the same as before the wall though, I'm not sure if I should decrease them or leave them be

EDIT: Oh, shit! I just realized, the way I calculate how long should the gibs stay is wrong! if I'm getting when the round has started and according to that and the fact that rounds in my server are 6 minutes long, I calculate how long is left till the round ends and pass it as a stay time for the gibs. At first I thought it was a good idea, but that doesn't take into account the fact that most of the time the round ends sooner because of a team being defeated! The idea now gets scrapped, and I'm open to suggestions

EDIT 2: I did make a project in code.google.com, but after looking around the menu for about half an hour, I couldn't find from where to actually upload and edit code (rofl) That's not for me

@Brreaker: I think the "bazooka" you are talking about is the one from half-life. I don't want to add models with HEV suit hands in cs, and I'm not good in modeling so I cant replace the hands either.

[Arkshine]

It's very easy, once you get an svn software, you can have a directory where you want on computer and updating from where.

[NiHiLaNTh]

Originally Posted by Arkshine One thing which could reduce is to provide default weapons and merging severals p_ into one model.

Well I have merged few w_ models into 1, hooked FM_SetModel and setted right w_ model body using EV_INT_body.But how to do the same with p_ models(I already merged them, but I dont know how set right model bodypart ) ? I cant do entity_set_int( Player, EV_INT_body, ? ), right ?

[Arkshine]

@SS :

Look at the screenshots. Here a fast test plugin.

PHP Code:


#include <amxmodx>
#include <fakemeta>
#include <engine>

new cvarPointerZMax;
new spriteIndexBeam;

enum _:Coordinates { Float:x, Float:y, Float:z };
enum _:Angles { Float:pitch, Float:yaw, Float:roll };

#define message_begin_f(%0,%1,%2) ( engfunc( EngFunc_MessageBegin, %0, %1, %2 ) )
#define write_coord_f(%0)         ( engfunc( EngFunc_WriteCoord, %0 ) )
    
#define VectorAdd(%0,%1,%2)      ( %2[ x ] = %0[ x ] + %1[ x ], %2[ y ] = %0[ y ] + %1[ y ], %2[ z ] = %0[ z ] + %1[ z ] )
#define VectorSubtract(%0,%1,%2) ( %2[ x ] = %0[ x ] - %1[ x ], %2[ y ] = %0[ y ] - %1[ y ], %2[ z ] = %0[ z ] - %1[ z ] )
#define VectorMA(%0,%1,%2,%3)    ( %3[ x ] = %0[ x ] + %1 * %2[ x ], %3[ y ] = %0[ y ] + %1 * %2[ y ], %3[ z ] = %0[ z ] + %1 * %2[ z ] )
#define VectorLength(%0)         ( floatsqroot ( %0[ x ] * %0[ x ] + %0[ y ] * %0[ y ] + %0[ z ] * %0[ z ] ) )
    
public plugin_precache()
{
    spriteIndexBeam = precache_model( "sprites/laserbeam.spr" );
}
    
public plugin_init()
{
    register_clcmd( "say /test", "ClientCommand_Test" );
    cvarPointerZMax = get_cvar_pointer( "sv_zmax" );
}

public ClientCommand_Test( const client )
{
    new Float:origin   [ Coordinates ];
    new Float:direction[ Coordinates ];
    
    GetGunPosition( client, origin );
    GetForwardDirection( client, direction );

    FireBullet( client, origin, direction );
}

FireBullet( const player, const Float:source[ Coordinates ], const Float:direction[ Coordinates ] )
{
    new Float:end    [ Coordinates ];
    new Float:endPos [ Coordinates ];
    new Float:endPos2[ Coordinates ]; 
    new Float:start  [ Coordinates ];
    
    VectorMA( source, get_pcvar_float( cvarPointerZMax ), direction, end );

    // -- T1 : source -> end
    trace_line( player, source, end, endPos );

    FX_BeamPoints( source, endPos, .red = 0, .green = 214, .blue = 198 );
    FX_DecalTrace( endPos );
    
    VectorMA( endPos, 8.0, direction, start );
    
    // -- T2 : End Position #1 + 8 units -> end.
    trace_line( player, start, end, endPos2 );
    
    if ( !traceresult( TR_AllSolid ) )
    {
        new Float:endPos3[ Coordinates ];
        new Float:wall   [ Coordinates ];
        
        // -- T3 : End Position #2 -> End Position #1.
        trace_line( player, endPos2, endPos, endPos3 );
        
        FX_DecalTrace( endPos3 );
        
        VectorSubtract( endPos3, endPos, wall );
        client_print( 0, print_chat, "Wall thickness = %f unit(s)", VectorLength( wall ) );
        
        // -- T4 : End Position #3 -> End
        trace_line( player, endPos3, end, endPos );

        FX_BeamPoints( source, endPos, .red = 0, .green = 214, .blue = 198 );
        FX_DecalTrace( endPos );
    }
}

GetGunPosition( const player, Float:origin[ Coordinates ] )
{
    new Float:viewOfs[ Coordinates ];
    
    pev( player, pev_origin, origin );
    pev( player, pev_view_ofs, viewOfs );
    
    VectorAdd( origin, viewOfs, origin );
}

GetForwardDirection( const player, Float:direction[ Coordinates ] )
{
    new Float:viewAngles [ Angles ]; 
    new Float:punchAngles[ Angles ];
    
    pev( player, pev_v_angle, viewAngles );
    pev( player, pev_punchangle, punchAngles );
    
    VectorAdd( viewAngles, punchAngles, viewAngles );
    engfunc( EngFunc_MakeVectors, viewAngles );
    
    global_get( glb_v_forward, direction );
}

FX_DecalTrace( const Float:origin[ Coordinates ] )
{
    message_begin( MSG_BROADCAST, SVC_TEMPENTITY );
    {
        write_byte( TE_WORLDDECAL );
        write_coord_f( origin[ x ] );
        write_coord_f( origin[ y ] );
        write_coord_f( origin[ z ] );
        write_byte( get_decal_index( "{shot1" ) - random_num( 0, 4 ) );
    }
    message_end();
}   

FX_BeamPoints( const Float:startPosition[ Coordinates ], const Float:endPosition[ Coordinates ], const red, const green, const blue )
{
    message_begin( MSG_BROADCAST, SVC_TEMPENTITY );
    {
        write_byte( TE_BEAMPOINTS )
        write_coord_f( startPosition[ x ] );
        write_coord_f( startPosition[ y ] );
        write_coord_f( startPosition[ z ] );
        write_coord_f( endPosition[ x ] );
        write_coord_f( endPosition[ y ] );
        write_coord_f( endPosition[ z ] );
        write_short( spriteIndexBeam ) ;
        write_byte( 0 ) 
        write_byte( 1 ); 
        write_byte( 255 ) 
        write_byte( 4 ); 
        write_byte( 0 ); 
        write_byte( red );
        write_byte( green );
        write_byte( blue);
        write_byte( 64 );
        write_byte( 0 );
    }
    message_end();
}