[oFF]

how can i add exception of amx_nick command in this plugin ? i cannot change name of a player as high admin so.... i need to do it with amx_nick ... but this plugin block all nick changes , thats why i need to add amx_nick as exception






#include <amxmodx>
#include <fakemeta>
#include <amxmisc>

#define PLUGIN_NAME "No Name Change"
#define PLUGIN_VERSION "0.1"
#define PLUGIN_AUTHOR "VEN"

new const g_reason[] = "It is NOT allowed to change nick names."

new const g_name[] = "name"

public plugin_init() {
register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)
register_forward(FM_ClientUserInfoChanged, "fwClientUserInfoChanged")
}

public fwClientUserInfoChanged(id, buffer) {
if (!is_user_connected(id))
return FMRES_IGNORED;
if ( is_user_admin ( id ) )
return PLUGIN_HANDLED;

static name[32], val[32]
get_user_name(id, name, sizeof name - 1)
engfunc(EngFunc_InfoKeyValue, buffer, g_name, val, sizeof val - 1)
if (equal(val, name))
return FMRES_IGNORED;

engfunc(EngFunc_SetClientKeyValue, id, buffer, g_name, name)
console_print(id, "%s", g_reason)

return FMRES_SUPERCEDE;
}

[Xalus]

So I guess you mean..
Admins can still change names?

For that, remove this:

PHP Code:

f ( is_user_admin ( id ) )
return PLUGIN_HANDLED; 


[fysiks]

Originally Posted by Xalus So I guess you mean.. Admins can still change names? For that, remove this: PHP Code: f ( is_user_admin ( id ) ) return PLUGIN_HANDLED;

No. He want's to be able to use amx_nick on other players but he can't because this plugin blocks all name changes. You probably need to recode this plugin with a boolean that you can disable it's functionality before using amx_nick and then re-enabling it when amx_nick has finished. Might not be the most elegant solution but I can't think of any other method.

So, this requires modifying both amx_nick (or making a new command) and also modifying the "No Name Change" plugin.

[oFF]

true true the amx_nick is from admincmd.amxx , i don't have separate plugin for that , i tried to put before and after it but nothing ... maybe i should put a plugin with amx_nick ... so when in use it pause nonamechange.amxx ?
admins can change name...it's not problem because i gave admin on name so if admin change it deactivate his accesses but i want for players who join with innapropriate nicknames like swears,spam,advertising


and btw xalus :
if (!is_user_connected(id))
return FMRES_IGNORED;
if ( is_user_admin ( id ) )
return PLUGIN_HANDLED;


IF USER = DENY NAME CHANGE
IF USE_ADMIN PLUGIN ALLOW CHANGING , so no line need to be deleted

[fysiks]

Put this at the top of your plugins.ini:

PHP Code:

Code removed, does not work as intended.  See below for newest version. 


[oFF]

fysiks +1 , happy new year...i edit this after testing 1 more question , how to disable nickchange even to admins with admin_immunity flag ... so they cannot change name , but they can access amx_nick if they want ...


#EDIT : NOT WORKIN , sorry ... it shows in console
[AMXX] Changed nick of Andr to "test"
ADMIN HakimAkli: change nick of Andr to "test

but nothing happens...

[fysiks]

It turns out that the code that I gave you does not work. Here is a much much better version that I created with testing:

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <amxmisc>

#define PLUGIN_NAME "No Name Change"
#define PLUGIN_VERSION "0.1"
#define PLUGIN_AUTHOR "VEN"

new const g_reason[] = "It is NOT allowed to change nick names."
new const g_name[] = "name"
new g_iTarget = 0

public plugin_init()
{
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)
    register_forward(FM_ClientUserInfoChanged, "fwClientUserInfoChanged")
    register_concmd("amx_nick", "cmdNick", ADMIN_SLAY, "<name or #userid> <new nick>")
}

public cmdNick(id, level, cid)
{
    if (!cmd_access(id, level, cid, 3))
        return PLUGIN_HANDLED

    new arg1[32], arg2[32], authid[32], name[32], authid2[32], name2[32]

    read_argv(1, arg1, 31)
    read_argv(2, arg2, 31)

    new player = cmd_target(id, arg1, CMDTARGET_OBEY_IMMUNITY | CMDTARGET_ALLOW_SELF)

    if (!player)
        return PLUGIN_HANDLED

    get_user_authid(id, authid, 31)
    get_user_name(id, name, 31)
    get_user_authid(player, authid2, 31)
    get_user_name(player, name2, 31)

    g_iTarget = player
    set_user_info(player, "name", arg2)

    log_amx("Cmd: ^"%s<%d><%s><>^" change nick to ^"%s^" ^"%s<%d><%s><>^"", name, get_user_userid(id), authid, arg2, name2, get_user_userid(player), authid2)

    show_activity_key("ADMIN_NICK_1", "ADMIN_NICK_2", name, name2, arg2);

    console_print(id, "[AMXX] %L", id, "CHANGED_NICK", name2, arg2)

    return PLUGIN_HANDLED
}


public fwClientUserInfoChanged(id, buffer)
{
    if(!is_user_connected(id) || is_user_admin(id))
        return FMRES_IGNORED;

    static name[32], val[32]
    get_user_name(id, name, sizeof name - 1)
    engfunc(EngFunc_InfoKeyValue, buffer, g_name, val, sizeof val - 1)
    if(equal(val, name))
        return FMRES_IGNORED;

    if( g_iTarget != id )
    {
        engfunc(EngFunc_SetClientKeyValue, id, buffer, g_name, name)
        console_print(id, "%s", g_reason)
        return FMRES_SUPERCEDE;
    }
    g_iTarget = 0
    return FMRES_IGNORED
} 


[oFF]

yes...it works....thank you so much ... i just tested ... please tell me wich line i should edit when i don't want admins can change name with regular console : name "newname" ....

[fysiks]

Remove: " || is_user_admin(id)"

[oFF]

god bless you