[Inhib]

PHP Code:

SetEntDataFloat(rocket_entity, FindSendPropOffs("CTFProjectile_Rocket", "m_iDeflected") + 4, 100.0, true); 


Still no damage

[Chdata]

How are you testing it?

[Inhib]

Originally Posted by Chdata How are you testing it?

Full Code:

PHP Code:

#include <sourcemod>
#include <clients>
#include <console>
#include <events>
#include <tf2>
#include <tf2_stocks>
#include <string>
#include <entity_prop_stocks>
#include <sdkhooks>
#include <sdktools_trace>
#include <sdktools_engine>
#include <handles>

public Plugin:myinfo =
{
    name = "New Plugin",
    author = "Your Lord and Saviour",
    description = "Test",
    version = "1.0",
    url = "http://www.sourcemod.net/"
};

public OnPluginStart()
{
    for(new i; i <= MAXPLAYERS; i++)
    {
        if(IsValidEntity(i))
        {
            SDKHook(i, SDKHook_OnTakeDamage, ontakedamage);
            PrecacheModel("models/props_farm/wooden_barrel.mdl");
            PrecacheModel("models/weapons/w_models/w_rocket.mdl")
        }
    }
}

public Action:ontakedamage(client, &attacker, &inflictor, &Float:damage, &damagetype)
{
    PrintToServer("DamageTaken");
    if(damagetype & DMG_FALL)
    {
        PrintToServer("IsFallDamage");
        new TFClassType:playerclass = TF2_GetPlayerClass(client);
        if(playerclass==TFClass_Pyro)
        {
            damage=damage*3;
            PrintToServer("IsPyro");
            return Plugin_Changed;
        }
    }
    return Plugin_Continue;
}



public Action:TF2_CalcIsAttackCritical(client, weapon, String:weaponname[], &bool:result)
{
    PrintToServer("Tick");
    new Float:vectorfloat[3];
    new String:vecstring[10];
    new String:vecstring2[10];
    new TFClassType:playerclass = TF2_GetPlayerClass(client);
    GetClientEyeAngles(client, Float:vectorfloat);
    Format(vecstring, sizeof(vecstring), "%.5f", vectorfloat[0]);
    Format(vecstring2, sizeof(vecstring2), "%.0f", vectorfloat[1]);
    PrintToServer(vecstring);
    PrintToServer(vecstring2);
    new Float:lateraljetpackvelocity=64.0;
    new Float:verticaljetpackvelocity=64.0;
    if(playerclass==TFClass_Heavy)
    {
        if(GetEntityFlags(client) & FL_ONGROUND)
        {
        lateraljetpackvelocity=4000.0;
        verticaljetpackvelocity=0.0;
        PrintToServer("Heavy Knockback");
        }
        else
        {
        lateraljetpackvelocity=0.0;
        verticaljetpackvelocity=0.0;
        PrintToServer("Heavy In Air")
        }
    }
    new Float:LateralEyeAngle=DegToRad(vectorfloat[1]);
    new Float:VerticalEyeAngle=DegToRad(vectorfloat[0]);
    new Float:velocityvector[3];
    new Float:zvelocity = verticaljetpackvelocity*Sine(VerticalEyeAngle);
    new Float:xvelocity = lateraljetpackvelocity*Cosine(VerticalEyeAngle)*Sine(LateralEyeAngle);
    new Float:yvelocity = lateraljetpackvelocity*Cosine(VerticalEyeAngle)*Cosine(LateralEyeAngle);
    GetEntPropVector(client, Prop_Data, "m_vecVelocity", velocityvector);
    velocityvector[2] += zvelocity;
    velocityvector[1] -= xvelocity;
    velocityvector[0] -= yvelocity;
    TeleportEntity(client, NULL_VECTOR, NULL_VECTOR, velocityvector); 

    if(playerclass==TFClass_DemoMan)
    {
        PrintToServer("Demoman Shot");
        new String:demomanweapon[30];
        new String:grenadelauncher[30]="tf_weapon_grenadelauncher";
        GetClientWeapon(client, demomanweapon, 30);
        PrintToServer(demomanweapon);
        PrintToServer(grenadelauncher);
        if(StrEqual(demomanweapon, grenadelauncher, true))
        {
            PrintToServer("Pipe Shot");            
        }
    }

    if(playerclass==TFClass_Engineer)
    {
        PrintToServer("Engy Shot");
        new ActiveWeapon = GetEntPropEnt(client, Prop_Send, "m_hActiveWeapon");
        new String:ActiveWeaponClassname[100];
        GetEdictClassname(ActiveWeapon, ActiveWeaponClassname, sizeof(ActiveWeaponClassname));
        if(StrEqual(ActiveWeaponClassname, "tf_weapon_pistol", true))
        {
            PrintToServer("Pistol Fired");
            if(vectorfloat[0]<=-88)
            {
                PrintToServer("DummyEngy");
                new barrel=CreateEntityByName("prop_physics_multiplayer");
                new Float:barrelpos[3];
                GetClientAbsOrigin(client, barrelpos);
                barrelpos[2]+=128;
                SetEntityModel(barrel, "models/props_farm/wooden_barrel.mdl");
                DispatchSpawn(barrel);
                TeleportEntity(barrel, barrelpos, NULL_VECTOR, NULL_VECTOR);
            }
        }
    }

    if(playerclass==TFClass_Soldier)
    {
        new rocketfired=FindEntityByClassname(-1, "tf_projectile_rocket");
        new Deflected=GetEntProp(rocketfired, Prop_Send, "m_iDeflected", 4, 0);
        new Critical=GetEntProp(rocketfired, Prop_Send, "m_bCritical", 1, 0);
        new String:DeflectedString[4];
        new String:CriticalString[4];
        Format(DeflectedString, sizeof(DeflectedString), "%i", Deflected);
        Format(CriticalString, sizeof(CriticalString), "%i", Critical);
        PrintToServer("Deflected:");
        PrintToServer(DeflectedString);
        PrintToServer("Crit:");
        PrintToServer(CriticalString);
    }
    if(playerclass==TFClass_Sniper)
    {
        PrintToServer("Sniper Shot");
        new ActiveWeapon = GetEntPropEnt(client, Prop_Send, "m_hActiveWeapon");
        new String:ActiveWeaponClassname[100];
        GetEdictClassname(ActiveWeapon, ActiveWeaponClassname, sizeof(ActiveWeaponClassname));
        if(StrEqual(ActiveWeaponClassname, "tf_weapon_sniperrifle", true))
        {
            PrintToServer("Rifle Fired");
            new Float:endpoint[3];
            TraceRayEnd(client, endpoint);
            new Float:zrocketpos = 64*Sine(VerticalEyeAngle);
            new Float:xrocketpos = 64*Cosine(VerticalEyeAngle)*Sine(LateralEyeAngle);
            new Float:yrocketpos = 64*Cosine(VerticalEyeAngle)*Cosine(LateralEyeAngle);
            new Float:rocketvel[3];
            rocketvel[0]=yrocketpos;
            rocketvel[1]=xrocketpos;
            rocketvel[2]=-zrocketpos; 
            new String:rocketvel0[10];
            new String:rocketvel1[10];
            new String:rocketvel2[10];
            new Float:rocketpos[3];
            rocketpos[0]=endpoint[0]-yrocketpos;
            rocketpos[1]=endpoint[1]-xrocketpos;
            rocketpos[2]=endpoint[2]+zrocketpos;
            Format(rocketvel0, sizeof(rocketvel0), "%.5f", rocketvel[0]);
            Format(rocketvel1, sizeof(rocketvel1), "%.5f", rocketvel[1]);
            Format(rocketvel2, sizeof(rocketvel2), "%.5f", rocketvel[2]);
            PrintToServer(rocketvel0);
            PrintToServer(rocketvel1);
            PrintToServer(rocketvel2);
            new rocket_entity = CreateEntityByName("tf_projectile_rocket");
            new team=GetClientTeam(client);
            SetEntProp(rocket_entity, Prop_Send, "m_hOwnerEntity", client, 21, 0);
            SetEntProp(rocket_entity, Prop_Send, "m_iTeamNum", team, true); 
            SetEntDataFloat(rocket_entity, FindSendPropOffs("CTFProjectile_Rocket", "m_iDeflected") + 4, 100.0, true);
            SetEntProp(rocket_entity, Prop_Send, "m_bCritical", 1, 1, 0);
            DispatchSpawn(rocket_entity);
            TeleportEntity(rocket_entity, rocketpos, vectorfloat, rocketvel);
        }
    }
    return Plugin_Continue;
}

public bool:rayhitplayer(entity,mask,any:data) 
{  
    if(entity==data)
    {
        return false;  
    }  
    else
    {  
        return true;  
    }  
}

public TraceRayEnd(client, Float:endpoint[3])
{
    new Float:origin[3];
    new Float:angles[3];
    GetClientEyePosition(client, origin);
    GetClientEyeAngles(client, angles);
    TR_TraceRayFilter(origin, angles, MASK_SHOT, RayType_Infinite, rayhitplayer, client);
    if(TR_DidHit(INVALID_HANDLE))
    {
        TR_GetEndPosition(endpoint, INVALID_HANDLE);
    }
    return;
} 


I fire my rifle as sniper in the server, rocket spawns, doesnt hurt me or any bots i spawn in

[asherkin]

Your problem is that you're corrupting the owner entity because you're using the wrong function and have sprinkled some random parameters on the SetEntProp calls.

SetEntPropEnt(rocket_entity, Prop_Send, "m_hOwnerEntity", client);
SetEntProp(rocket_entity, Prop_Send, "m_iTeamNum", team); 
SetEntDataFloat(rocket_entity, FindSendPropOffs("CTFProjectile_Rocket", "m_iDeflected") + 4, 100.0, true);
SetEntProp(rocket_entity, Prop_Send, "m_bCritical", true);

Also, I believe the owner of the rocket should be the weapon rather than the client, and I notice you're getting the active weapon rather than using the weapon parameter from the forward... why?

[Chdata]

I think m_hOwnerEntity doesn't really matter. Rockets get their stats from the weapon via m_hLauncher / m_hOriginalLauncher.

Fakedit: Yep, I always set m_hOwnerEntity to the client, no problem.

Realedit: Yep, and that thing about the garble you put in those SetEntProps asherkin quoted.

PHP Code:

/*
    iWeapon is one of the player's weapons to read attributes from, such as 99 ; 1.5 for extra explosive radius
*/
stock FireTeamRocket(Float:vPos[3], Float:vAng[3], iOwner = 0, iTeam = 0, Float:flSpeed = 1100.0, Float:flDamage = 90.0, bool:bCrit = false, iWeapon = -1)
{
    new iRocket = CreateEntityByName("tf_projectile_rocket");
    if (IsValidEntity(iRocket))
    {
        decl Float:vVel[3]; // Determine velocity based on given speed/angle
        GetAngleVectors(vAng, vVel, NULL_VECTOR, NULL_VECTOR);
        ScaleVector(vVel, flSpeed);
        
        SetEntProp(iRocket, Prop_Send, "m_bCritical", bCrit);

        SetRocketDamage(iRocket, flDamage);

        SetEntProp(iRocket, Prop_Send, "m_nSkin", max(0, iTeam - 2)); // 0 = RED 1 = BLU
        SetEntProp(iRocket, Prop_Send, "m_iTeamNum", iTeam, 1);
        SetVariantInt(iTeam);
        AcceptEntityInput(iRocket, "TeamNum");
        SetVariantInt(iTeam);
        AcceptEntityInput(iRocket, "SetTeam");

        if (iOwner != -1)
        {
            SetEntPropEnt(iRocket, Prop_Send, "m_hOwnerEntity", iOwner);
        }
        
        // I found this offset while trying to fix the sudden-explode issue with these rockets. it's another instance
        // of the owner entity, so why the hell not copy this over...probably useful for some things.
        // new iTestOffset = FindSendPropOffs("CTFProjectile_Rocket", "m_bCritical") - 4;
        // SetEntDataEnt2(iRocket, iTestOffset, iOwner, true); // GetEntDataEnt2(baseRocket, iTestOffset)

        TeleportEntity(iRocket, vPos, vAng, vVel);
        DispatchSpawn(iRocket);
        
        //SetEntProp(iRocket, Prop_Send, "m_nSolidType", );       // GetEntProp(baseRocket, Prop_Send, "m_nSolidType")
        //SetEntProp(iRocket, Prop_Send, "m_usSolidFlags", );     // GetEntProp(baseRocket, Prop_Send, "m_usSolidFlags")
        //SetEntProp(iRocket, Prop_Send, "m_CollisionGroup", );   // GetEntProp(baseRocket, Prop_Send, "m_CollisionGroup")
        // if (iOwner != -1)
        // {
        //     SetEntDataEnt2(iRocket, iTestOffset, iOwner, true);      // GetEntDataEnt2(baseRocket, testOffset)
        // }
        
        if (iWeapon != -1)
        {
            SetEntPropEnt(iRocket, Prop_Send, "m_hOriginalLauncher", iWeapon); // GetEntPropEnt(baseRocket, Prop_Send, "m_hOriginalLauncher")
            SetEntPropEnt(iRocket, Prop_Send, "m_hLauncher", iWeapon); // GetEntPropEnt(baseRocket, Prop_Send, "m_hLauncher")
        }
        

        //if (false) SetEntProp(iRocket, Prop_Send, "m_nModelIndex", ); // GetEntProp(baseRocket, Prop_Send, "m_nModelIndex")
        
        // trail override
        //if (strlen(MS_TrailEffectOverride[bossClientIdx]) > 3)
        //{
        //  new particle = AttachParticle(iRocket, MS_TrailEffectOverride[bossClientIdx]);
        //  if (IsValidEntity(particle))
        //      CreateTimer(MS_ROCKET_LIFE, RemoveEntity, EntIndexToEntRef(particle));
        //}
        
        return iRocket;
    }
    return -1;
}

static s_iRocketDmgOffset = -1;

stock SetRocketDamage(iRocket, Float:flDamage)
{
    if (s_iRocketDmgOffset == -1)
    {
        s_iRocketDmgOffset = FindSendPropOffs("CTFProjectile_Rocket", "m_iDeflected") + 4; // Credit to voogru
    }
    SetEntDataFloat(iRocket, s_iRocketDmgOffset, flDamage, true);
}

stock Float:GetRocketDamage(iRocket)
{
    if (s_iRocketDmgOffset == -1)
    {
        s_iRocketDmgOffset = FindSendPropOffs("CTFProjectile_Rocket", "m_iDeflected") + 4; // Credit to voogru
    }
    return GetEntDataFloat(iRocket, s_iRocketDmgOffset);
} 


[asherkin]

Originally Posted by Chdata I think m_hOwnerEntity doesn't really matter.

It does, a null / invalid owner causes issues with damage in TF2. It is possible they've fixed it since they broke it in 2010 to default to world rather than null when creating a new entity.

EDIT: And this is exactly what your code does, defaults to setting the owner to world (thanks to the mismatch between the default argument and the check in the function).

I mention it being the weapon rather than client as that is what the game does, and plugins with OnTakeDamage hooks expect.

[Chdata]

Whatever that mercurial link is requires a username/pass.

Also the function was set up that way intentionally to default the rocket to 'something' and prevent people from trying to set it to something invalid. Since I don't know what m_hOwnerEntity would default to if it's not set at all, I figured that'd be the safest.