[Phil25]

Just to be clear, you only need to check one button?

[Bacardi]

...what if try something simple first.
Go touch that button and look your in game console.
Use command sm_button to look all func_buttons on map.

PHP Code:

#include <sdktools>


public void OnPluginStart()
{
    RegConsoleCmd("sm_button", sm_button);
    HookEntityOutput("func_button", "OnPressed", OnPressed);
}

public Action sm_button(int client, int args)
{
    int ent = MaxClients +1;

    while( (ent = FindEntityByClassname(ent, "func_button")) != -1 )
    {
        char m_iName[MAX_NAME_LENGTH];
        GetEntPropString(ent, Prop_Data, "m_iName", m_iName, sizeof(m_iName));
        PrintToConsole(client, "Button index %i name '%s'", ent, m_iName);
    }
    return Plugin_Handled;
}

public void OnPressed(const char[] output, int caller, int activator, float delay)
{
    if(0 < activator <= MaxClients && IsClientInGame(activator))
    {
        char m_iName[MAX_NAME_LENGTH];
        GetEntPropString(caller, Prop_Data, "m_iName", m_iName, sizeof(m_iName));
        PrintToConsole(activator, "Button index %i name '%s'", caller, m_iName);
    }
} 


[adma]

Hi guys, after a bit of testing this seems to work. Thanks for all your help.

#include <sourcemod>
#include <sdktools>
#include <morecolors>
#include <tf2jail>

#define MAXENTITIES 2048

new bool:isListening[MAXPLAYERS + 1] = false;
new button[MAXENTITIES + 1];

public Plugin:myinfo = 
{
  name = "Button Announce",
  author = "adma",
  description = "Announces button press in chat.",
  version = "3.0"
};

public OnPluginStart()
{
	RegConsoleCmd("sm_button", OnButtonListen, "Enables button stuff.");
	HookEntityOutput("func_button", "OnPressed", OnButtonPressed)
}

public Action:OnButtonListen(int client, int args)
{
	if (isListening[client])
	{
		isListening[client] = false;
		CReplyToCommand(client, "[SM] {uncommon}No longer listening for button presses.")
		return Plugin_Handled;
	}
	else
	{
		isListening[client] = true;
		CReplyToCommand(client, "[SM] {uncommon}Now listening for button presses");
		return Plugin_Handled;
	}
}

public OnButtonPressed(const String:output[], buttonEnt, attacker, Float:delay)
{
	decl String:entity[1024];
	
	GetEntPropString(buttonEnt, Prop_Data, "m_iName", entity, sizeof(entity));
	
	if (IsClientInGame(attacker) && IsPlayerAlive(attacker) && !isListening[attacker])
	{
		button[buttonEnt] = attacker;
	}
	
	if (IsClientInGame(attacker) && IsPlayerAlive(attacker) && isListening[attacker])
	{
		CPrintToChat(attacker, "%N {uncommon}was the last to press button {lime}%s", button[buttonEnt], entity);
	}
}

[Neuro Toxin]

new button[MAXENTITIES + 1];

This is a waste of memory. But makes your code simple.

[mottzi]

Originally Posted by Neuro Toxin new button[MAXENTITIES + 1]; This is a waste of memory. But makes your code simple.

This is a good example of when tries should be used. Simple and efficient.

[Neuro Toxin]

A trie wouldn't really be suitable either because they indexed by string.

The storage here is int to int (entity->client).

[ddhoward]

Regular ArrayList, with a blocksize of 2 would be best, methinks.