[Bonkorn]

I'm using Help Menu, i just want Autoexec sm_helpmenu which displays help menu by client after 30sec.
I don't want to use Menu Based Rules which can auto display menu for connected players because it seems complicated to me.

This should be similar but failed, need help.
Used Fake Client Execute as reference.

public OnClientPutInServer(client) {
		CreateTimer(30.0, Timer_AutoShow, client);
}

public Action:Timer_AutoShow(client, args )
{
	for (new client = 1; client <= MaxClients; client++)
	{
		PerformFakeExec(client, sm_helpmenu);
	}
	
	return Plugin_Handled;
}

stock PerformFakeExec(client, const String:sm_helpmenu[])
{
	FakeClientCommandEx(client,sm_helpmenu);
}

[WatchDogs]

Hi,

This is the correct form of doing this:

PHP Code:

public OnClientPutInServer(client) 
{
    CreateTimer(30.0, Timer_AutoShow, GetClientUserId(client), TIMER_FLAG_NO_MAPCHANGE);
}

public Action:Timer_AutoShow(Handle:timer, any:userid)
{
    new client = GetClientOfUserId(userid);
    if(client > 0 && IsClientInGame(client))
    {
        FakeClientCommandEx(client, "sm_helpmenu");
    }
    return Plugin_Handled;
} 


Good luck ;)

[Unbelievable]

Can i add idea? Can you make it so it only displays once for new players then never shows again?

[WatchDogs]

Ya, with a simple change:

PHP Code:

#include <sourcemod>
#include <clientprefs>

Handle g_hClientCookies;

public void OnPluginStart()
{
    g_hClientCookies = RegClientCookie("HelpMenuCookie", "A cookie for storing data for help menu", CookieAccess_Private);
}

public void OnClientPutInServer(int client)
{
    if (AreClientCookiesCached(client))
    {
        char sCookie[8];
        GetClientCookie(client, g_hClientCookies, sCookie, sizeof(sCookie));
        if (!StrEqual(sCookie, "known"))
        {
            CreateTimer(30.0, Timer_AutoShow, GetClientUserId(client), TIMER_FLAG_NO_MAPCHANGE);
        }
    }
}

public Action Timer_AutoShow(Handle timer, any userid)
{
    int client = GetClientOfUserId(userid);
    if (client > 0 && IsClientInGame(client))
    {
        char sAuthId[32];
        GetClientAuthId(client, AuthId_Engine, sAuthId, sizeof(sAuthId));
        FakeClientCommandEx(client, "sm_helpmenu");
        SetAuthIdCookie(sAuthId, g_hClientCookies, "known");
    }
    return Plugin_Handled;
} 


[Unbelievable]

Thank you bro just one more question can you execute any sm command for clients using this plugin?.

[WatchDogs]

Yes, Just change the line:

PHP Code:

FakeClientCommandEx(client, "sm_helpmenu"); 


To

PHP Code:

FakeClientCommandEx(client, "your_command"); 


[SZOKOZ]

Originally Posted by Unbelievable Thank you bro just one more question can you execute any sm command for clients using this plugin?.

https://forums.alliedmods.net/showpo...61&postcount=3
Any server side command so yes any sm command will work. (:

[Unbelievable]

Cool thanks.

[Bonkorn]

Thanks to WatchDogs's help, it worked for me.

Originally Posted by WatchDogs PHP Code: public OnClientPutInServer(client)  {     CreateTimer(30.0, Timer_AutoShow, GetClientUserId(client), TIMER_FLAG_NO_MAPCHANGE); } public Action:Timer_AutoShow(Handle:timer, any:userid) {     new client = GetClientOfUserId(userid);     if(client > 0 && IsClientInGame(client))     {         FakeClientCommandEx(client, "sm_helpmenu");     }     return Plugin_Handled; }