[Alienmario]

Hi there. First of all, this extension has been great help. The plugin I'm making couldn't be done without it.

After weeks of trying to hook bullet spread of weapons in HL2DM I have found a solution and a little bug with this extension.

The problem lies in this function: DHookSetParamObjectPtrVarVector(hParams, 1, 28, ObjectValueType_Vector, vec) reporting:

L 08/02/2015 - 15:030: [SM] Native "DHookSetParamObjectPtrVarVector" reported: Invalid Object value type (not a type of vector) L 08/02/2015 - 15:030: [SM] Displaying call stack trace for plugin "customguns.smx":

while everything else seems to be correct. Reading the vector at same offset also works as expected.
I have solved this by passing 3 floats instead of the vector (I wish I realized that earlier lol) like so:

PHP Code:

    DHookSetParamObjectPtrVar(hParams, 1, 28, ObjectValueType_Float, vec[0]);
    DHookSetParamObjectPtrVar(hParams, 1, 32, ObjectValueType_Float, vec[1]);
    DHookSetParamObjectPtrVar(hParams, 1, 36, ObjectValueType_Float, vec[2]); 


Here is the full code of FireBullets hook for anyone interested:

PHP Code:

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>
#include <dhooks>


Handle DHOOK_FireBullets;

public OnPluginStart()
{
    new Handle:gamedata = LoadGameConfigFile("urgamedata");
    
    if(gamedata == INVALID_HANDLE)
    {
        SetFailState("Failed to find gamedata");
    }
    
    int offset;
    
    // void CHL2MP_Player::FireBullets ( const FireBulletsInfo_t &info )
     offset = GameConfGetOffset(gamedata, "FireBullets");
    DHOOK_FireBullets = DHookCreate(offset, HookType_Entity, ReturnType_Void, ThisPointer_CBaseEntity, FireBullets);
    DHookAddParam(DHOOK_FireBullets, HookParamType_ObjectPtr, -1, DHookPass_ByVal);
    
    CloseHandle(gamedata);
}

public OnClientPutInServer(client){
    DHookEntity(DHOOK_FireBullets, false, client);
}


// void CHL2MP_Player::FireBullets ( const FireBulletsInfo_t &info )
/* "FireBulletsInfo_t":
     0 int m_iShots;
    4 Vector m_vecSrc;
    16 Vector m_vecDirShooting;
    28 Vector m_vecSpread;
    40 float m_flDistance;
    44 int m_iAmmoType;
    48 int m_iTracerFreq;
    52 float m_flDamage;
    56 int m_iPlayerDamage;    
    60 int m_nFlags;
    64 float m_flDamageForceScale;
    68 CBaseEntity *m_pAttacker;
    72 CBaseEntity *m_pAdditionalIgnoreEnt;
    76 bool m_bPrimaryAttack; 
*/
public MRESReturn:FireBullets(int client, Handle hParams){
    //DHookSetParamObjectPtrVar( hParams, 1, 0, ObjectValueType_Int, 0);
    
    float vec[3];
    DHookGetParamObjectPtrVarVector(hParams, 1, 28, ObjectValueType_Vector, vec);
    PrintToChatAll("%f %f %f", vec[0],vec[1],vec[2]); // << works
    
    float VECTOR_CONE_5DEGREES[] = {0.04362, 0.04362, 0.04362};
    //DHookSetParamObjectPtrVarVector(hParams, 1, 28, ObjectValueType_Vector, VECTOR_CONE_5DEGREES); // << fails
     DHookSetParamObjectPtrVar(hParams, 1, 28, ObjectValueType_Float, VECTOR_CONE_5DEGREES[0]);
    DHookSetParamObjectPtrVar(hParams, 1, 32, ObjectValueType_Float, VECTOR_CONE_5DEGREES[1]);
    DHookSetParamObjectPtrVar(hParams, 1, 36, ObjectValueType_Float, VECTOR_CONE_5DEGREES[2]);
    return MRES_Handled;
} 


[Miu]

yea its missing check here, i guess vectors by value aren't common

[Dr!fter]

Originally Posted by Alienmario Hi there. First of all, this extension has been great help. The plugin I'm making couldn't be done without it. After weeks of trying to hook bullet spread of weapons in HL2DM I have found a solution and a little bug with this extension. The problem lies in this function: DHookSetParamObjectPtrVarVector(hParams, 1, 28, ObjectValueType_Vector, vec) reporting: while everything else seems to be correct. Reading the vector at same offset also works as expected. I have solved this by passing 3 floats instead of the vector (I wish I realized that earlier lol) like so:

Originally Posted by Miu yea its missing check here, i guess vectors by value aren't common

Oops thought i replied to this. Its a bug It has support for non ptr but the first if only checks for VectorPtr

[DeathChaos25]

So, I think I'm definitely doing something wrong here.

PHP Code:

new Handle:hSequenceSet;
public OnPluginStart()
{
    new Handle:temp = LoadGameConfigFile("l4d2_direct");
    
    if (temp == INVALID_HANDLE)
    {
        SetFailState("Error: Gamedata not found");
    }
    
    new offset;
    offset = GameConfGetOffset(temp, "CTerrorPlayer::SelectWeightedSequence");
    if (offset == -1)
    {
        CloseHandle(temp);
        LogError("Unable to get offset for CTerrorPlayer::SelectWeightedSequence");
        return;
    }
    hSequenceSet = DHookCreate(offset, HookType_Entity, ReturnType_Void, ThisPointer_CBaseEntity, OnSequenceSet);
    DHookAddParam(hSequenceSet, HookParamType_Int);
}

public MRESReturn:OnSequenceSet(client, Handle:hParams)
{
    if (IsSurvivor(client))
    {
        PrintToChat(client, "Current Sequence: #%i", DHookGetParam(hParams, 1));
    }
}

bool:IsSurvivor(client)
{
    return (client > 0 && client <= MaxClients && IsClientInGame(client) && GetClientTeam(client) == 2);
}

public OnClientPutInServer(client)
{
    if (!IsFakeClient(client))DHookEntity(hSequenceSet, false, client);
} 


All I am doing is hooking into the function and retrieving the value it is setting, but for some reason, the hook is preventing the function from actually setting the value, this is the function that handles the animations for survivors, but because the hook is preventing the function from working, resulting in "Jesus Pose";

Spoiler

[pcmaster]

You have to return MRES_Ignored on your hook.

[DeathChaos25]

Originally Posted by pcmaster You have to return MRES_Ignored on your hook.

Like so?

PHP Code:

public MRESReturn:OnSequenceSet(client, Handle:hParams)
{
    if (IsSurvivor(client))
    {
        PrintToChat(client, "Current Sequence: #%i", DHookGetParam(hParams, 1));
    }
    return MRES_Ignored;
} 


The issue still persists even with this change.

[Dr!fter]

You shouldnt have to return ignored, you can try using a post hook see if it still happens. Its weird since the function should still be called. The only thing i can think of is that the param's are wrong. But i havent checked the function.

[DeathChaos25]

Originally Posted by Dr!fter You shouldnt have to return ignored, you can try using a post hook see if it still happens. Its weird since the function should still be called. The only thing i can think of is that the param's are wrong. But i havent checked the function.

The params should be correct, but then again, I could've probably made a mistake somewhere;

PHP Code:

CTerrorPlayer::SelectWeightedSequence(Activity) 


Spoiler

"Games"
{
	"left4dead2"
	{
		"Offsets"
		{
			"CTerrorPlayer::SelectWeightedSequence"
			{
				"windows"	"206"
				"linux"		"207"
			}
		}
		
	}
}

Decided to change it into a post hook, while also simply controling the hook with sm_hook for easier testing, but the results are the same nonetheless;

PHP Code:

public Action:HOOKME(client, args)
{
    if (IsSurvivor(client))
    {
        if(clienthook[client] > 0)
        {
            DHookRemoveHookID(clienthook[client]);
            clienthook[client] = -1;
        }
        else clienthook[client] = DHookEntity(hSequenceSet, true, client);
    }
} 


[Dr!fter]

Its not a void return, it returns an int.

[Marounda]

Originally Posted by Dr!fter this is most likely not related to DHooks but whatever plugin uses it.

Hello,

I'm really in late and sorry to answer you at this late moment.

A lot of players crying about the spawns on my servers and i guess it's harder since some months.

Can you try to play on one of my DM Server and say me if the spawns are good for you please ?
connect 5.196.58.216:27035

I can understand it will take time, and if i can do something to thank you, say me.

I want to find a solution, but I don't know how...

As you saw my plugins, i don't have a lot of them.

Thanks in advance.

Best regards,
Marounda