[Pelipoika]

TF2 Building Spawner EXTREME

Ignore the red buildings it's fixed in the plugin

What is it?
Allows you to spawn absolutely any engineer building in the game

Commands:

sm_sbuildex : Opens the buildings menu[Default acces: ROOT]

Changelog:
1.0 Initial Release
2.0
- Completely revamped the menu system (Should be a lot cleaner now)
- Fixed dispenser heal radius.
2.1 Fixed a couple of typos in the menu and fixed some spawning issues.
2.1.1 Fixed teleporter skin issue.

Notes:
- Comes with handy stocks for you to use in your plugins to spawn your buildings
- Spawning a building as carried doesn't work yet (I need help with this one)
- Teleporters may not properly link to each other (Couldn't figure this out either)
- Sentries can be sapped, don't shoot from the floor and you can pickup your buildings if you're an engineer.
- Recommended to be used with this

The stocks:

Spoiler

PHP Code:

stock SpawnSentry(builder, Float:Position[3], Float:Angle[3], level, bool:mini=false, bool:disposable=false, flags=4)
{
    static const Float:m_vecMinsMini[3] = {-15.0, -15.0, 0.0}, Float:m_vecMaxsMini[3] = {15.0, 15.0, 49.5};
    static const Float:m_vecMinsDisp[3] = {-13.0, -13.0, 0.0}, Float:m_vecMaxsDisp[3] = {13.0, 13.0, 42.9};
    
    new sentry = CreateEntityByName("obj_sentrygun");
    
    if(IsValidEntity(sentry))
    {
        AcceptEntityInput(sentry, "SetBuilder", builder);

        DispatchKeyValueVector(sentry, "origin", Position);
        DispatchKeyValueVector(sentry, "angles", Angle);
        
        if(mini)
        {
            SetEntProp(sentry, Prop_Send, "m_bMiniBuilding", 1);
            SetEntProp(sentry, Prop_Send, "m_iUpgradeLevel", level);
            SetEntProp(sentry, Prop_Send, "m_iHighestUpgradeLevel", level);
            SetEntProp(sentry, Prop_Data, "m_spawnflags", flags);
            SetEntProp(sentry, Prop_Send, "m_bBuilding", 1);
            SetEntProp(sentry, Prop_Send, "m_nSkin", level == 1 ? GetClientTeam(builder) : GetClientTeam(builder) - 2);
            DispatchSpawn(sentry);
            
            SetVariantInt(100);
            AcceptEntityInput(sentry, "SetHealth");
            
            SetEntPropFloat(sentry, Prop_Send, "m_flModelScale", 0.75);
            SetEntPropVector(sentry, Prop_Send, "m_vecMins", m_vecMinsMini);
            SetEntPropVector(sentry, Prop_Send, "m_vecMaxs", m_vecMaxsMini);
        }
        else if(disposable)
        {
            SetEntProp(sentry, Prop_Send, "m_bMiniBuilding", 1);
            SetEntProp(sentry, Prop_Send, "m_bDisposableBuilding", 1);
            SetEntProp(sentry, Prop_Send, "m_iUpgradeLevel", level);
            SetEntProp(sentry, Prop_Send, "m_iHighestUpgradeLevel", level);
            SetEntProp(sentry, Prop_Data, "m_spawnflags", flags);
            SetEntProp(sentry, Prop_Send, "m_bBuilding", 1);
            SetEntProp(sentry, Prop_Send, "m_nSkin", level == 1 ? GetClientTeam(builder) : GetClientTeam(builder) - 2);
            DispatchSpawn(sentry);
            
            SetVariantInt(100);
            AcceptEntityInput(sentry, "SetHealth");
            
            SetEntPropFloat(sentry, Prop_Send, "m_flModelScale", 0.60);
            SetEntPropVector(sentry, Prop_Send, "m_vecMins", m_vecMinsDisp);
            SetEntPropVector(sentry, Prop_Send, "m_vecMaxs", m_vecMaxsDisp);
        }
        else
        {
            SetEntProp(sentry, Prop_Send, "m_iUpgradeLevel", level);
            SetEntProp(sentry, Prop_Send, "m_iHighestUpgradeLevel", level);
            SetEntProp(sentry, Prop_Data, "m_spawnflags", flags);
            SetEntProp(sentry, Prop_Send, "m_bBuilding", 1);
            SetEntProp(sentry, Prop_Send, "m_nSkin", GetClientTeam(builder) - 2);
            DispatchSpawn(sentry);
        }
    }
}

stock SpawnDispenser(builder, Float:Position[3], Float:Angle[3], level, flags=4)
{
    new dispenser = CreateEntityByName("obj_dispenser");
    
    if(IsValidEntity(dispenser))
    {
        DispatchKeyValueVector(dispenser, "origin", Position);
        DispatchKeyValueVector(dispenser, "angles", Angle);
        SetEntProp(dispenser, Prop_Send, "m_iHighestUpgradeLevel", level);
        SetEntProp(dispenser, Prop_Data, "m_spawnflags", flags);
        SetEntProp(dispenser, Prop_Send, "m_bBuilding", 1);
        DispatchSpawn(dispenser);

        SetVariantInt(GetClientTeam(builder));
        AcceptEntityInput(dispenser, "SetTeam");
        SetEntProp(dispenser, Prop_Send, "m_nSkin", GetClientTeam(builder) - 2);
        
        ActivateEntity(dispenser);
        
        AcceptEntityInput(dispenser, "SetBuilder", builder);
    }
}

stock SpawnTeleporter(builder, Float:Position[3], Float:Angle[3], level, TFObjectMode:mode, flags=4)
{
    new teleporter = CreateEntityByName("obj_teleporter");
    
    if(IsValidEntity(teleporter))
    {
        ActivateEntity(teleporter);
        
        DispatchKeyValueVector(teleporter, "origin", Position);
        DispatchKeyValueVector(teleporter, "angles", Angle);
        
        SetEntProp(teleporter, Prop_Send, "m_iHighestUpgradeLevel", level);
        SetEntProp(teleporter, Prop_Data, "m_spawnflags", flags);
        SetEntProp(teleporter, Prop_Send, "m_bBuilding", 1);
        SetEntProp(teleporter, Prop_Data, "m_iTeleportType", mode);
        SetEntProp(teleporter, Prop_Send, "m_iObjectMode", mode);
        SetEntProp(teleporter, Prop_Send, "m_nSkin", GetClientTeam(builder) - 2);
        DispatchSpawn(teleporter);
        
        AcceptEntityInput(teleporter, "SetBuilder", builder);
        
        SetVariantInt(GetClientTeam(builder));
        AcceptEntityInput(teleporter, "SetTeam");
    }
} 


[Sreaper]

Already exists: https://forums.alliedmods.net/showpost.php?p=1975241&postcount=6

[Pelipoika]

Originally Posted by Sreaper Already exists: https://forums.alliedmods.net/showpost.php?p=1975241&postcount=6

Mine can spawn Disposable sentries and mini sentris too at any level

[martellus]

Originally Posted by Pelipoika - Sentries can be sapped and don't shoot from the floor.

Thank you, that was the major problem with the other plugin

[Pelipoika]

Originally Posted by martellus Thank you, that was the major problem with the other plugin

You can also pickup your buildings if you're an engineer

[Sigara]

Really good mod but the dispensers are kind of wonky they don't have the beam so you have to rub yourself on the dispensers for them to work.Sentry-wise no issues.

[Pelipoika]

Originally Posted by Sigara Really good mod but the dispensers are kind of wonky they don't have the beam so you have to rub yourself on the dispensers for them to work.Sentry-wise no issues.

Fixed.

[mmmm124]

Plugin failed to compile!

[Pelipoika]

Originally Posted by mmmm124 Plugin failed to compile!

Uploaded .smx till AlliedModders is fixed

[martellus]

I noticed spawning buildings near you seems to have them floating in air while spawning them far away embeds them in the ground.