[deville]

Hi. 2 of the plugins I am running on my server/s are being loaded but simply doesn't function. Can't find any output regarding this in the error logs. I thought maybe someone can see an immediate fix or maybe I have to wait until a new build? Im running linux btw

Here they are:


knife delay by Arkarr & thedudeguy1.
Source: https://forums.alliedmods.net/showpo...48&postcount=6

PHP Code:

#include <sourcemod>  
#include <sdktools>  
#include <sdkhooks>  

#define PLUGIN_AUTHOR     "Arkarr, thedudeguy1"  
#define PLUGIN_VERSION     "1.3"  

bool Marked[MAXPLAYERS + 1];  

public Plugin myinfo =   
{  
    name = "[ANY] Knife Attack Delay",   
    author = PLUGIN_AUTHOR,   
    description = "Set a delay between each attack on the same player.",   
    version = PLUGIN_VERSION,   
    url = "https://forums.alliedmods.net/showpost.php?p=2499248&postcount=6"  
};  

public void OnPluginStart()  
{  
    for (new i = 1; i <= MaxClients; i++)  
    {  
        if (IsClientInGame(i))  
            SDKHook(i, SDKHook_OnTakeDamage, OnTakeDamage);  
    }  
}  

public void OnClientPutInServer(int client)  
{  
    SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage);  
}  

public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype)  
{  
    if (victim < 1 || victim > MaxClients || attacker < 1 || attacker > MaxClients)  
        return Plugin_Continue;  
         
    char weapon[64];  
    GetClientWeapon(attacker, weapon, sizeof(weapon));  
      
    if (StrEqual(weapon, "weapon_knife", false))  
    {  
        if (!Marked[victim])  
        {  
            ImmunePlayer(victim);      
        }              
        else  
        {  
            return Plugin_Handled;  
        }  
    }  
      
    return Plugin_Continue;  
}  

public void ImmunePlayer(int client)  
{  
    Marked[client] = true;  
    SetEntityRenderMode(client, RENDER_TRANSCOLOR);  
    SetEntityRenderColor(client, 100, 255, 100, 200);  
      
    CreateTimer(3.0, TMR_Unmark, client);  
}  

public Action TMR_Unmark(Handle tmr, any client)  
{  
    Marked[client] = false;  
    SetEntityRenderMode(client, RENDER_TRANSCOLOR);  
    SetEntityRenderColor(client, 255, 255, 255, 255);  
} 


Antibackstab by unknown:

PHP Code:

#include <sdkhooks> 

public void OnPluginStart() 
{ 
    for (new client = 1; client <= MaxClients; client++) 
    { 
        if (!IsClientInGame(client)) 
            continue; 
             
        OnClientPutInServer(client); 
         
    }     
} 
public void OnClientPutInServer(int client) 
{ 
    SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage); 
} 

public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype) 
{ 
    if (victim < 1 || victim > MaxClients || attacker < 1 || attacker > MaxClients) 
        return Plugin_Continue; 

    if (damage > 55.0) 
    { 
        char weapon[64]; 
        GetClientWeapon(attacker, weapon, sizeof(weapon)); 
        if (StrEqual(weapon, "weapon_knife", false)) 
        { 
            damage = 55.0; 
            return Plugin_Changed; 
        } 
    } 
    return Plugin_Continue; 
} 


I've tried look up in the discussion thread of what I may change in order to fix it but couldn't find out much about it. Appreciate any help

[Totenfluch]

I've noticed those kind of plugins only not working with bayonetts. Normal knifes work fine for me

[deville]

Originally Posted by Totenfluch I've noticed those kind of plugins only not working with bayonetts. Normal knifes work fine for me

I know there was something similar with prestrafing on kztimer. I'll check once i get back. Thank you!

[OSWO]

Bayonets have had their name changed.

[deville]

Yup this seems to be the issue. How would I approach to resolving this issue in the code?

[OfficialSikari]

public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype)   
{   
    if (victim < 1 || victim > MaxClients || attacker < 1 || attacker > MaxClients)   
        return Plugin_Continue;   
          
    char weapon[64];   
    GetClientWeapon(attacker, weapon, sizeof(weapon));   
       
    if (StrEqual(weapon, "weapon_knife", false))   
    {   
        if (!Marked[victim])   
        {   
            ImmunePlayer(victim);       
        }               
        else   
        {   
            return Plugin_Handled;   
        }   
    }   
       
    return Plugin_Continue;   
}

Into

public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype)   
{   
    if (victim < 1 || victim > MaxClients || attacker < 1 || attacker > MaxClients)   
        return Plugin_Continue;   
          
    char weapon[64];   
    GetClientWeapon(attacker, weapon, sizeof(weapon));   
       
    if (StrEqual(weapon, "weapon_knife", false) || 
       StrEqual(weapon, "weapon_bayonet", false) ||
       StrContains(weapon, "weapon_knife_", false) != -1)
    {   
        if (!Marked[victim])   
        {   
            ImmunePlayer(victim);       
        }               
        else   
        {   
            return Plugin_Handled;   
        }   
    }   
       
    return Plugin_Continue;   
}

[deville]

Originally Posted by OfficialSikari public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype) { if (victim < 1 || victim > MaxClients || attacker < 1 || attacker > MaxClients) return Plugin_Continue; char weapon[64]; GetClientWeapon(attacker, weapon, sizeof(weapon)); if (StrEqual(weapon, "weapon_knife", false)) { if (!Marked[victim]) { ImmunePlayer(victim); } else { return Plugin_Handled; } } return Plugin_Continue; } Into public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype) { if (victim < 1 || victim > MaxClients || attacker < 1 || attacker > MaxClients) return Plugin_Continue; char weapon[64]; GetClientWeapon(attacker, weapon, sizeof(weapon)); if (StrEqual(weapon, "weapon_knife", false) || StrEqual(weapon, "weapon_bayonet", false) || StrContains(weapon, "weapon_knife_", false) != -1) { if (!Marked[victim]) { ImmunePlayer(victim); } else { return Plugin_Handled; } } return Plugin_Continue; }

Thanks a lot Sikari! This one fixed it for both plugins. I didn't really know what exactly got changed in the weapon index so I didn't know what to do. Now I understand.

A moderator can mark this as solved, or however things work in these forums :p