[YamiKaitou]

Please list required modules in the first post.

If you are only using 1 function from fakemeta_util, it would be easiest just to include that function in your plugin and give credit for it.

For you if(get_pcvar_num(cvar)==[0|1|2]) stuff, use a switch or an if, ifelse, else statement.


Also, don't double post, edit your previous post

[maplebest]

Wow... Nice idea, +karma!

[TheRadiance]

ok sorry for flood.
First post updated.
now you can switch modes beetwen 0|1|2
0 - disables plugin
1 - team mode
2 - random colores mode

[vorass]

I cant download it some is bad with link or sth!

[YamiKaitou]

Originally Posted by YamiKaitou Please list required modules in the first post. If you are only using 1 function from fakemeta_util, it would be easiest just to include that function in your plugin and give credit for it. For you if(get_pcvar_num(cvar)==[0|1|2]) stuff, use a switch or an if, ifelse, else statement. Also, don't double post, edit your previous post

Still holds true, but now I have more.

Instead of declaring 3 variables, use 1 variable and set it to a number (ie, 1 or 2 or 3).


PM me if you want me to assist you in optimizing this

Originally Posted by vorass I cant download it some is bad with link or sth!

I downloaded it fine. You have to compile it locally though

[TheRadiance]

Updated again.
thnx YamiKaitou

[atomen]

Why have you included fun and fakemeta ?

[ConnorMcLeod]

Fun is not needed, but it's not a problem to include both fakemata and fakemeta_util, as fakemeta_util won't include fakemeta then.

[Arkshine]

Here an optimized version of your current plugin.

• Use a swith() when you can. Instead using several if() in the forward, it's better to use a switch in such case.
• No need to create several variables 'r', 'g', 'b', use random_num() directly in the fm_set_rendering() function.
• It's more readable to write the defined name 'PLUGIN_HANDLED', 'FMRES_IGNORED', etc.. instead of writing its value.
• cmd_access ( id, level, cid, 2 ) : The correct value is 2 because you have to count the command + the argument, so 2.
• In your plugin/case, no need to return something in each 'case:'. It's more readable to remove them.
• You have forget to retrieve the mode value passed into the command.
• Since you're using one function from fakemeta_util, just copy it into your plugin.
• You have missed the mode value into the command function.
• Like connor said, fun is not used, remove it.
• (Optionnal) : Since fakemeta is using, you can use the player's private data to retrieve the team value. Then you can remove cstrike requirement.

PHP Code:

 
    #include <amxmodx>
    #include <amxmisc>
    #include <fakemeta>

    new gi_Mode;
    new gi_MaxClients;

    enum
    {
        CS_TEAM_T = 1,
        CS_TEAM_CT
    }

    #define OFFSET_TEAM 114
    #define cs_get_user_team(%1)  get_pdata_int( %1, OFFSET_TEAM )

    public plugin_init ()
    {
        register_plugin ( "wp_glow", "0.2a", "Radiance" );

        register_forward ( FM_SetModel, "fw_model" );
        register_concmd ( "amx_wpglow", "cmd_wpglow", ADMIN_LEVEL_A, "cmd_wpglow <1|2|3> : switches wpglow modes" );
    }

    public plugin_cfg ()
    {
        gi_MaxClients = global_get ( glb_maxClients );
    }

    public cmd_wpglow ( id, level, cid )
    {
        if ( !cmd_access ( id, level, cid, 2 ) )
        {
            return PLUGIN_HANDLED;
        }

        new s_Arg[ 2 ];
        read_argv ( 1, s_Arg, sizeof s_Arg - 1 );
        
        gi_Mode = str_to_num ( s_Arg );

        switch ( gi_Mode )
        {
            case 1  : client_print ( id, print_console, "%s", "[AMXX] wp_glow switched to <team mode>." );
            case 2  : client_print ( id, print_console, "%s", "[AMXX] wp_glow switched to <random mode>." );
            default : client_print ( id, print_console, "%s", "[AMXX] wp_glow disabled." );
        }

        return PLUGIN_HANDLED;
    }

    public fw_model ( i_Ent,  const s_Model[] )
    {
        static id;
        id = pev ( i_Ent, pev_owner );

        if ( !( 1 <= id <= gi_MaxClients ) )
        {
            return FMRES_IGNORED;
        }

        switch ( gi_Mode )
        {
            case 1 :
            {
                switch ( cs_get_user_team ( id ) )
                {
                    case CS_TEAM_T  : fm_set_rendering ( i_Ent, kRenderFxGlowShell, 255, 0, 0, kRenderNormal, 10 );
                    case CS_TEAM_CT : fm_set_rendering ( i_Ent, kRenderFxGlowShell, 0, 0, 255, kRenderNormal, 10 );
                }
            }
            case 2 :
            {
                fm_set_rendering( i_Ent, kRenderFxGlowShell, random_num( 1,255 ), random_num( 1, 255 ), random_num( 1, 255 ), kRenderNormal, 10 );
            }
        }

        return FMRES_IGNORED;
    }

    fm_set_rendering ( i_Ent, i_Fx = kRenderFxNone, i_R = 0, i_G = 0, i_B = 0, i_Render = kRenderNormal, i_Amount = 16 )
    {
        static Float:vf_RenderColor[3];

        vf_RenderColor[ 0 ] = float( i_R );
        vf_RenderColor[ 1 ] = float( i_G );
        vf_RenderColor[ 2 ] = float( i_B );

        set_pev ( i_Ent, pev_renderfx   , i_Fx );
        set_pev ( i_Ent, pev_rendercolor, vf_RenderColor );
        set_pev ( i_Ent, pev_rendermode , i_Render );
        set_pev ( i_Ent, pev_renderamt  , float ( i_Amount ) );
    } 


[Orangutanz]

I don't understand why people are not using get_user_team

It does what its suppose to do, if scripters are switching teams unofficially (using offsets) then they should be complying with standards and sending the correct network messages!

If anyone can find any plugins where they don't comply with these standards, then I'll unapprove the plugin(s).


Regards,

Orangutanz