[M249-M4A1]

I fixed a lot of crap for you, so use this as a base to do what connorr said.
This isn't complete, as it still needs a lot of work. However, this should be a lot nicer to look at and code with now.

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <fun>

#define PLUGIN "Round Survival Money"
#define VERSION "1.0"
#define AUTHOR "X-Script"

new roundsurvival, roundreward

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_logevent("new_round", 2, "0=World triggered", "1=Round_Start")
    
    roundsurvival = register_cvar("amx_survivemode", "1")
    roundreward = register_cvar("amx_survivecash", "3000")
}

public new_round()
{
    if (get_pcvar_num(roundsurvival) < 1)
        return PLUGIN_HANDLED
    
    client_print(0, print_chat, "[AMXX] ROUND STARTED: Survive to get $%i at the end of the round!", get_pcvar_num(roundreward))
    return PLUGIN_HANDLED
}

public round_end(id)
{
    if (get_pcvar_num(roundsurvival) < 1)
        return PLUGIN_HANDLED
    
    if (is_user_alive(id))
    {
        new newmoney = cs_get_user_money(id) + get_pcvar_num(roundreward)
        cs_set_user_money(id, newmoney)
        
        client_print(id, print_chat, "[AMXX] ROUND ENDED: You have survived and been awarded $%i!", get_pcvar_num(roundreward))
        
        set_user_rendering(id,  kRenderFxSolidSlow, 10, 100, 10, kRenderNormal, 25)
        set_task(8.0, "glow_off", id)
    }
    return PLUGIN_HANDLED
}

public glow_off(id)
{
    set_user_rendering(id)
} 


[X-Script]

I'm going to release it for now, and work on it later.

;)

thanks.

[M249-M4A1]

Originally Posted by X-Script I'm going to release it for now, and work on it later. ;) thanks.

I made all the necessary changes for you............

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <fun>

#define PLUGIN "Round Survival Money"
#define VERSION "1.0"
#define AUTHOR "X-Script"

new roundsurvival, roundreward

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_logevent("round_end", 2, "0=World triggered", "1=Round_End")
    register_logevent("new_round", 2, "0=World triggered", "1=Round_Start")
    
    roundsurvival = register_cvar("amx_survivemode", "1")
    roundreward = register_cvar("amx_survivecash", "3000")
}

public new_round()
{
    if (get_pcvar_num(roundsurvival) < 1)
        return PLUGIN_HANDLED
    
    client_print(0, print_chat, "[AMXX] ROUND STARTED: Survive this round and win an additional $%i!", get_pcvar_num(roundreward))
    return PLUGIN_HANDLED
}

public round_end()
{
    if (get_pcvar_num(roundsurvival) < 1)
        return PLUGIN_HANDLED
    
    new players[32], totalplayers
    get_players(players, totalplayers)
    
    for (new i = 0; i < totalplayers; i++) {
        if (is_user_alive(players[i])) {
            
            new newmoney = cs_get_user_money(players[i]) + get_pcvar_num(roundreward)
            cs_set_user_money(players[i], newmoney)
            
            client_print(players[i], print_chat, "[AMXX] ROUND ENDED: You survived and have been awarded $%i!", get_pcvar_num(roundreward))
            
            set_user_rendering(players[i],  kRenderFxGlowShell, 255, 255, 255, kRenderNormal, 0)
            set_task(8.0, "glow_off", players[i])
        }
        else 
            client_print(players[i], print_chat, "[AMXX] ROUND ENDED: You did not survive this round. No award for you. Better luck next time!")
    }    
    
    return PLUGIN_HANDLED
}

public glow_off(id)
{
    set_user_rendering(id)
} 


[ConnorMcLeod]

Optimized a bit cause you shouln't get tha cvar pointer twice in the same function.
Also added a taskID, not needed at the moment but you need to do another task it will.

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <fun>

#define PLUGIN "Round Survival Money"
#define VERSION "1.0"
#define AUTHOR "X-Script"

#define TASKID 978645

new roundsurvival, roundreward

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_logevent("round_end", 2, "0=World triggered", "1=Round_End")
    register_logevent("new_round", 2, "0=World triggered", "1=Round_Start")
    
    roundsurvival = register_cvar("amx_survivemode", "1")
    roundreward = register_cvar("amx_survivecash", "3000")
}

public new_round()
{
    if (!get_pcvar_num(roundsurvival))
        return PLUGIN_HANDLED
    
    client_print(0, print_chat, "[AMXX] ROUND STARTED: Survive this round and win an additional $%i!", get_pcvar_num(roundreward))
    return PLUGIN_HANDLED
}

public round_end()
{
    if (!get_pcvar_num(roundsurvival))
        return PLUGIN_HANDLED
    
    new players[32], totalplayers, player
    get_players(players, totalplayers)
    
    for (new i = 0; i < totalplayers; i++) {
        player = players[i]

        if (is_user_alive(player)) {
            
            new money_to_give = get_pcvar_num(roundreward)
            cs_set_user_money(player, cs_get_user_money(player) + money_to_give)
            
            client_print(player, print_chat, "[AMXX] ROUND ENDED: You survived and have been awarded $%i!", money_to_give)
            
            set_user_rendering(player,  kRenderFxGlowShell, 255, 255, 255, kRenderNormal, 0)
            set_task(8.0, "glow_off", player+TASKID)
        }
        else 
            client_print(player, print_chat, "[AMXX] ROUND ENDED: You did not survive this round. No award for you. Better luck next time!")
    }    
    
    return PLUGIN_HANDLED
}

public glow_off(id)
{
    id -= TASKID
    set_user_rendering(id)
}

[X-Script]

I just tried my version (without looking at your post) and it gave me two tag-mismatches and I completly HATE those, so i'll go with yours.

[M249-M4A1]

Thanks for the tip, connorr (@ player = players[i] and taskid)

@X-Script, you dislexic bastard lol. It's M249-M4A1, not M429-M4A1
jk, not a big deal... Are you tired or something? When I suggested $3000, you ended up putting $30,000 in the script, and you had a lot of careless errors. Get some sleep!

[X-Script]

Originally Posted by M249-M4A1 Thanks for the tip, connorr

[M249-M4A1]

Read the updated post, I wasn't finished with my thought when I hit the reply button. lol

[Arkshine]

Again, you don't have to return PLUGIN_HANDLED...

You should not return PLUGIN_HANDLED all the time... -_-

[X-Script]

@M4: I'm aware of it I always check for updated posts.

@arkshine: I use return PLUGIN_HANDLED because it makes the code look cleaner. ;)