[PatPeter]

I've seen some plugins that outright block return to lobby/kick player/start new campaign/restart chapter/change all talk votes, but I want a plugin that ONLY blocks these votes when an admin is on.

Simplest plugin would check a user's identity; if admin check for "b" flag; disable votes.

More complex permission would ask the admin with the highest immunity level if the vote should go through, and then let it.

[Skyy]

is this a paid request?

[Mr. Zero]

Should do the job. Allows you to override the admin flag in case you decide to change your mind in the future by using "callvote_access" as override command.

[PatPeter]

Thank you Mr. Zero! I installed it on my server and will test it when possible. Also, I renamed the plugin to "disablesupervisedvotes".

[TnTSCS]

I use something very similar on our CS:GO servers...

[PatPeter]

Made it yourself or does it have a name TnTSCS?

[Dr. Greg House]

Have something similar to precisely reroute and force vote outcomes including admin protection etc.

[PatPeter]

Which is?

[Dr. Greg House]

It's not official, made it myself and haven't released it.

[TnTSCS]

Here is something I use which is very simple and you could modify to your needs. Even though it's for CS:GO, I'm sure L4D2 uses similar methods, but might have different voting parameters, I don't know.

No Votes When Admin In-Game

PHP Code:

/**
 * Credits to psychonic - https://forums.alliedmods.net/showthread.php?t=161586
 * 
 * 
 * 
 */

#pragma semicolon 1

#include <sourcemod>

#define PLUGIN_VERSION        "1.0.0.0"

new bool:PlayerIsAdmin[MAXPLAYERS+1] = {false, ...};

public Plugin:myinfo =
{
    name = "CS:GO Vote Control",
    author = "TnTSCS aKa ClarkKent",
    description = "Gives admins more control over the CS:GO voting system",
    version = PLUGIN_VERSION,
    url = "http://www.dhgamers.com"
};

public OnPluginStart()
{
    AddCommandListener(callvote, "callvote");
}

public OnClientPostAdminCheck(client)
{
    if (IsPlayerAdmin(client))
    {
        PlayerIsAdmin[client] = true;
    }
    else
    {
        PlayerIsAdmin[client] = false;
    }
}

bool:IsPlayerAdmin(client)
{
    if (CheckCommandAccess(client, "allow_csgo_votes", ADMFLAG_VOTE))
        return true;
    
    return false;
}

public Action:callvote(client, const String:cmd[], argc)
{
    // Player isn't admin, let's see if the vote is allowed
    if (!PlayerIsAdmin[client])
    {
        new bool:count = false;
        for (new i = 1; i <= MaxClients; i++)
        {
            if (IsClientInGame(i) && PlayerIsAdmin[i])
            {
                count = true;
                break;
            }
        }
        
        if (count)
        {
            PrintToChat(client, "Voting is not allowed right now.");
            return Plugin_Handled;
        }
    }
    
    decl String:votereason[25];
    votereason[0] = '\0';
    GetCmdArg(1, votereason, sizeof(votereason));
    
    if (StrContains(votereason, "restartgame", false) != -1)
    {
        if (CheckCommandAccess(client, "allow_restartggame", ADMFLAG_GENERIC))
        {
            return Plugin_Continue;
        }
        
        PrintToChat(client, "You are not allowed to start a vote to restart the game.");
        return Plugin_Handled;
    }
    
    if (StrContains(votereason, "changelevel", false) != -1)
    {
        if (CheckCommandAccess(client, "allow_changelevel", ADMFLAG_CHANGEMAP))
        {
            return Plugin_Continue;
        }
        
        PrintToChat(client, "You are not allowed to start a vote to change the map.");
        return Plugin_Handled;
    }
    
    if (StrContains(votereason, "swapteams", false) != -1)
    {
        if (CheckCommandAccess(client, "allow_swapteams", ADMFLAG_KICK))
        {
            return Plugin_Continue;
        }
        
        PrintToChat(client, "You are not allowed to start a vote to swap the teams.");
        return Plugin_Handled;
    }
    
    if (StrContains(votereason, "scrambleteams", false) != -1)
    {
        if (CheckCommandAccess(client, "allow_scrambleteams", ADMFLAG_KICK))
        {
            return Plugin_Continue;
        }
        
        PrintToChat(client, "You are not allowed to start a vote to scramble the teams.");
        return Plugin_Handled;
    }
    
    if (StrContains(votereason, "kick", false) != -1)
    {
        if (CheckCommandAccess(client, "allow_kick", ADMFLAG_KICK))
        {
            return Plugin_Continue;
        }
        
        PrintToChat(client, "You are not allowed to start a vote to kick a player.");
        return Plugin_Handled;
    }
    
    if (StrContains(votereason, "surrender", false) != -1)
    {
        PrintToChat(client, "You cannot vote to surrender.");
        return Plugin_Handled;
    }
    
    return Plugin_Continue;
}