SUPER FAST JUMP

s3rserii · **Author**

Hey,
i need a superjump but i cannot find this in the forum or im to dump du find it sry :/

If you coruch and than jump in crouchposition, then u make a super fast jump forward...
It is with cvar for only CT, T or Booth
and with a timelimit like every 10 second one jump?

can anyone help me? :S

peace

Aykay · 04-10-2011 , 06:32 Re: SUPER FAST JUMP

This was actually damn fun to play around with.

PHP Code:


			
#include <amxmodx>

#include <fakemeta>

#include <engine>

#include <cstrike>



#define PLUGIN "FastJump"

#define VERSION "1.0"

#define AUTHOR "Aykay"



new jump_player[33][2];



public plugin_init()

{

    register_plugin(PLUGIN, VERSION, AUTHOR)

    register_forward(FM_CmdStart, "CmdStart");

    register_cvar("jump_cooldown", "3")  // set this to 0 for unlimited.

    register_cvar("jump_tallowed", "1")

    register_cvar("jump_ctallowed", "1")

}



public CmdStart(id, uc_handle)

{

    if(!is_user_alive(id))

        return FMRES_IGNORED;

    

    if (( cs_get_user_team(id) == CS_TEAM_CT ) && get_cvar_num("jump_ctallowed") == 0)

        return FMRES_IGNORED;

        

    if (( cs_get_user_team(id) == CS_TEAM_T ) && get_cvar_num("jump_tallowed") == 0)

        return FMRES_IGNORED;

        

    new button = get_uc(uc_handle, UC_Buttons);

    new flags = get_entity_flags(id);

    

    if(button & IN_JUMP && button & IN_DUCK && flags & FL_ONGROUND && get_gametime() > jump_player[id][1] + get_cvar_num("jump_cooldown"))

    {

        jump_player[id][1] = floatround(get_gametime());

        new Float:velocity[3];

        VelocityByAim(id, 700, velocity);

        velocity[2] = random_float(265.0,285.0); //edit velocity here - can be set to a random float <--- or just a float.

        entity_set_vector(id, EV_VEC_velocity, velocity);

    }

    

    return FMRES_IGNORED;

}

eskemo · 04-10-2011 , 07:05 Re: SUPER FAST JUMP

<3 Aykay thanks for script ima use it aswell

Aykay · 04-10-2011 , 07:07 Re: SUPER FAST JUMP

<3

ConnorMcLeod · 04-10-2011 , 07:23 Re: SUPER FAST JUMP

Better to use this, will save you cpu :

PHP Code:


			
#include <amxmodx>

#include <engine>

#include <fakemeta>

#include <hamsandwich>



#define VERSION "0.0.1"



#define MAX_PLAYERS        32



#define FBitSet(%1,%2)        (%1 & %2)



new g_bSuperJump

#define MarkUserLongJump(%1)    g_bSuperJump |= 1<<(%1 & 31)

#define ClearUserLongJump(%1)    g_bSuperJump &= ~( 1<<(%1 & 31) )

#define HasUserLongJump(%1)        g_bSuperJump &  1<<(%1 & 31)



new g_pCvarMinVelocity, g_pCvarPunchAngle, g_pCvarLongjumpSpeed, g_pCvarZVelocity, g_pCvarAllowedTeams, g_pCvarCoolDown



new Float:g_flNextSuperJump[MAX_PLAYERS+1]



public plugin_init()

{

    register_plugin("Super Jump", VERSION, "ConnorMcLeod")



    g_pCvarLongjumpSpeed = register_cvar( "longjump_speed"       , "700" ) // horizontal speed

    g_pCvarPunchAngle    = register_cvar( "longjump_punchangle"  , "-5"  ) // angle effect

    g_pCvarZVelocity     = register_cvar( "longjump_zvelocity"   , "300" ) // vertical speed

    g_pCvarMinVelocity   = register_cvar( "longjump_minvelocity" , "50"  )

    g_pCvarAllowedTeams  = register_cvar( "longjump_teams"       , "2"   ) // 0:disabled 1:Ts 2:CTs 3:All

    g_pCvarCoolDown      = register_cvar( "longjump_cooldown"    , "5.0" )



    RegisterHam(Ham_Player_Jump, "player", "Player_Jump")

    RegisterHam(Ham_Player_Duck, "player", "Player_Duck")

}



public Player_Duck(id)

{

    if( HasUserLongJump(id) )

    {

        ClearUserLongJump(id)

        return HAM_SUPERCEDE

    }

    return HAM_IGNORED

}



public Player_Jump(id)

{

    if( !is_user_alive(id) )

    {

        return HAM_IGNORED

    }



    static iFlags ; iFlags = entity_get_int(id, EV_INT_flags)



    if( FBitSet(iFlags, FL_WATERJUMP) || entity_get_int(id, EV_INT_waterlevel) >= 2 )

    {

        return HAM_IGNORED

    }



    const XO_PLAYER = 5    

    const m_afButtonPressed = 246



    static afButtonPressed ; afButtonPressed = get_pdata_int(id, m_afButtonPressed, XO_PLAYER)



    if( !FBitSet(afButtonPressed, IN_JUMP) || !FBitSet(iFlags, FL_ONGROUND) )

    {

        return HAM_IGNORED

    }



    const m_iTeam = 114

    new Float:flTime = get_gametime()



    if(    (entity_get_int(id, EV_INT_bInDuck) || iFlags & FL_DUCKING)

    &&    get_pcvar_num(g_pCvarAllowedTeams) & get_pdata_int(id, m_iTeam, XO_PLAYER)

    &&    g_flNextSuperJump[id] < flTime

    &&    entity_get_int(id, EV_INT_button) & IN_DUCK

    &&    entity_get_int(id, EV_INT_flDuckTime)    )

    {

        g_flNextSuperJump[id] = flTime + get_pcvar_float(g_pCvarCoolDown)

        static Float:fVecTemp[3]

        entity_get_vector(id, EV_VEC_velocity, fVecTemp)

        if( vector_length(fVecTemp) > get_pcvar_float(g_pCvarMinVelocity) )

        {

            const m_Activity = 73

            const m_IdealActivity = 74



            const PLAYER_SUPERJUMP = 7

            const ACT_LEAP = 8



            entity_get_vector(id, EV_VEC_punchangle, fVecTemp)

            fVecTemp[0] = get_pcvar_float(g_pCvarPunchAngle)

            entity_set_vector(id, EV_VEC_punchangle, fVecTemp)



            get_global_vector(GL_v_forward, fVecTemp)

            static Float:flLongJumpSpeed ; flLongJumpSpeed = get_pcvar_float(g_pCvarLongjumpSpeed) * 1.6

            fVecTemp[0] *= flLongJumpSpeed

            fVecTemp[1] *= flLongJumpSpeed

            fVecTemp[2] = get_pcvar_float(g_pCvarZVelocity)



            entity_set_vector(id, EV_VEC_velocity, fVecTemp)



            set_pdata_int(id, m_Activity, ACT_LEAP, XO_PLAYER)

            set_pdata_int(id, m_IdealActivity, ACT_LEAP, XO_PLAYER)

            MarkUserLongJump(id)



            entity_set_int(id, EV_INT_oldbuttons, entity_get_int(id, EV_INT_oldbuttons) | IN_JUMP)



            entity_set_int(id, EV_INT_gaitsequence, PLAYER_SUPERJUMP)

            entity_set_float(id, EV_FL_frame, 0.0)



            set_pdata_int(id, m_afButtonPressed, afButtonPressed & ~IN_JUMP, XO_PLAYER)

            return HAM_SUPERCEDE

        }

    }

    return HAM_IGNORED

}