[Steveh]

Hello,

I need help with one of my plugins, in one part of it, It needs to check everyone is in water.

PHP Code:

    for(new i = 1; i <= MaxClients; i++){
        if(IsClientInGame(i) && IsPlayerAlive(i) && !IsFakeClient(i)){
if((GetEntityFlags(i) & FL_INWATER || GetEntityFlags(i) & FL_SWIM))
{
PrintToChat(i, "You are in water"); 
}
}
} 


I don't see why this doesn't work, as the water the players run into is deep.

Thanks,

Steveh

[Leonardo]

helped me in TF2

if(GetEntityFlags(iClient) & FL_FLY) // lolwtf flying in water

[blodia]

the search feature is your friend
http://forums.alliedmods.net/showthread.php?t=129795

[Leonardo]

blodia
can't see anything helphul there o.o

[psychonic]

Originally Posted by Steveh Hello, I need help with one of my plugins, in one part of it, It needs to check everyone is in water. PHP Code:     for(new i = 1; i <= MaxClients; i++){         if(IsClientInGame(i) && IsPlayerAlive(i) && !IsFakeClient(i)){ if((GetEntityFlags(i) & FL_INWATER || GetEntityFlags(i) & FL_SWIM)) { PrintToChat(i, "You are in water");  } } }  I don't see why this doesn't work, as the water the players run into is deep. Thanks, Steveh

Originally Posted by Leonardo helped me in TF2 if(GetEntityFlags(iClient) & FL_FLY) // lolwtf flying in water

Most entity flags shifted on the engine that css and tf2 are on. There's an open bug that I hope to have resolved in the near future.

Originally Posted by Leonardo blodia can't see anything helphul there o.o

The water level prop and level defines would also check if in water, and if so, how far into the water (depth-wise). Indeed useful.

[Leonardo]

oh dear
okay then

[Greyscale]

From one of my plugins. It's the napalm feature of ZR, it puts out napalm fire if you go in water. There's a cvar that controls how far into the water you need to be before it's doused.

/**
 * @section m_nWaterLevel defines.
 */
#define NAPALM_WLEVEL_DRY 0
#define NAPALM_WLEVEL_FEET 1
#define NAPALM_WLEVEL_HALF 2
#define NAPALM_WLEVEL_FULL 3
/**
 * @endsection
 */

Action:NapalmOnTakeDamage(client, damagetype)
{
    // Client was damaged by fire.
    if (damagetype & DMG_CSS_BURN)
    {
        // Only take action if it isn't disabled, or the option is valid.
        new douse = GetConVarInt(g_hCvarsList[CVAR_NAPALM_DOUSE]);
        
        if (douse > NAPALM_WLEVEL_DRY && douse <= NAPALM_WLEVEL_FULL)
        {
            // If the client water-level is equal or higher than the given, then we want to extinguish the flame.
            new waterlevel = GetEntProp(client, Prop_Data, "m_nWaterLevel");
            if (waterlevel >= douse)
            {
                // Put the fire out.
                
                //ExtinguishEntity(client);  <-- Don't use this.  Takes off the FL_ONFIRE flag, but flame doesn't get extinguished.
                
                // This works.
                new fire = GetEntPropEnt(client, Prop_Data, "m_hEffectEntity");
                if (IsValidEntity(fire))
                {
                    // Make sure the entity is a flame, so we can extinguish it.
                    decl String:classname[64];
                    GetEdictClassname(fire, classname, sizeof(classname));
                    if (StrEqual(classname, "entityflame", false))
                    {
                        SetEntPropFloat(fire, Prop_Data, "m_flLifetime", 0.0);
                    }
                    // Log what entity was in that property, for future reference.
                    else
                    {
                        LogEvent(false, LogTypeOld_Normal, LOG_GAME_EVENTS, LogModule_Napalm, "Napalm Douse", "Found unexpected entity in prop \"m_flLifetime\": \"%s\"", classname);
                    }
                }
            }
        }
    }
    
    // Let the damage module continue as usual.
    return Plugin_Continue;
}

[Steveh]

Thanks for the help, the issue has been fixed.


Steveh