[icetea]

anyone know how to change the speed of a thrown grenade?

[Exolent[jNr]]

I've tried, and I haven't found any solution for changing the actual grenade's velocity.
However, I was able to recreate a grenade in the same path, and make it go where I wanted.
I had to make the real grenade SOLID_NOT, and invisible.
Then, when the grenade was about to explode, I set it's origin where the fake one is at, then deleted the fake entity.

[Prajch]

Originally Posted by Exolent[jNr] I've tried, and I haven't found any solution for changing the actual grenade's velocity. However, I was able to recreate a grenade in the same path, and make it go where I wanted. I had to make the real grenade SOLID_NOT, and invisible. Then, when the grenade was about to explode, I set it's origin where the fake one is at, then deleted the fake entity.

pev_velocity was no good?

[Exolent[jNr]]

No, it wasn't.

[zwfgdlc]

it is work fine for me.try this.

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <csx>

#define PLUGIN_NAME "change grenade speed"
#define PLUGIN_VERSION  "1.0"
#define PLUGIN_AUTHOR   "zwfgdlc"

public plugin_init()
{
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR);
}

public grenade_throw(id,greindex,wid)
{
    new Float:vel[3]
    velocity_by_aim(id,1800,vel);
    set_pev(greindex,pev_velocity,vel);
}

[hlstriker]

Tested and works...

PHP Code:

#include <amxmodx>
#include <fakemeta>

#define PLUGIN    "Nade Velocity"
#define VERSION    "1.0"
#define AUTHOR    "hlstriker"


public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    register_forward(FM_SetModel, "fwd_SetModel");
}

public fwd_SetModel(iEnt, const szModel[])
{
    // Check to see if a he grenade model was set...
    if(equal(szModel, "models/w_hegrenade.mdl"))
    {
        // The model is also set as soon as you buy a grenade, but has no owner yet.
        // So check to see if the nade as an owner and continue...
        if(pev(iEnt, pev_owner) > 0)
        {
            static Float:flVelocity[3];
            pev(iEnt, pev_velocity, flVelocity);
            flVelocity[0] *= 2.5;
            flVelocity[1] *= 2.5;
            flVelocity[2] *= 2.5;
            set_pev(iEnt, pev_velocity, flVelocity);
        }
    }
} 


[Sn!ff3r]

flVelocity[0] *= 2.5;

Yes, and 2.5 is maximal really workong value ;)

btw. real funny efect

[Orangutanz]

Originally Posted by Exolent[jNr] I've tried, and I haven't found any solution for changing the actual grenade's velocity. However, I was able to recreate a grenade in the same path, and make it go where I wanted. I had to make the real grenade SOLID_NOT, and invisible. Then, when the grenade was about to explode, I set it's origin where the fake one is at, then deleted the fake entity.

Code for this has been present in ChickenMod for ages (years), where we just drop the grenade.