[Iciaria]

I'm having some problems writing a plugin.
The code snippet looks like this

PHP Code:

public void OnPluginStart()
{
#if DEBUG
        HookEvent("weapon_fire", Event_Weapon_Fire, EventHookMode_PostNoCopy);            
#endif
}

void CheckStatus()
{
        for(int i =1; i<=MaxClients; i++)
        {
//              if(!IS_VALID_SURVIVOR(i))
//              if(!IsValidEntity(i) )
//                      return;
//              PrintToChatAll("1");
//              if(!IsClientConnected(i) )
//                      return;
//              PrintToChatAll("2");
//              if(!IsValiClient(i) )
//                      return;
                if(!IsClientInGame(i) )
                        return;
                if(GetClientTeam(i) == 2)
                {       
                        char name[64];
                        GetClientName(i, name, sizeof(name) );
                        int health = GetEntProp(i, Prop_Send, "m_iHealth");
                        float buffer = GetTempHealth(i);
//GetEntPropFloat(i, Prop_Send, "m_healthBuffer");
                        int count = GetEntProp(i, Prop_Send, "m_currentReviveCount");
                        PrintToChatAll("%s#HP:%d， TEMP:%f， REV:%d,", name, health, buffer, count);
                        PrintToServer("%s#HP:%d， TEMP:%f， REV:%d,", name, health, buffer, count);
                }
        }

} 


I run many tests on my multiple servers.
"IsClientInGame()" sometimes thinks the client is not in the game.

The following situations have occurred in the test:

1.Only the first player to join is considered "in game".
2.Following the first point, when a second player joins the server, the fake client will be considered "Not in game", and . The second player is also sometimes considered "Not in game".
3.All players, fake clients or not, are correctly considered "in game"
4.Only real players are considered "in game"

I also tested in pure server and the result is still the same
Initially, it throws

 03/24/2023 - 19:59:23: [SM] Call stack trace:
L 03/24/2023 - 19:59:23: [SM]   [0] Event.GetInt
L 03/24/2023 - 19:59:23: [SM]   [1] Line 90, test.sp::Event_Weapon_Fire

After I removed "EventHookMode_PostNoCopy", the error in the log above disappeared. However, the problem is still happening..

I also tried changing the cvars "sv_lan" and "sv_cheats", but, the miracle didn't happen.

Can anyone tell me what exactly is going on?
I'm very confused.......

[Marttt]

Wrong section, and the snippet provided doesn't give any clue about your exception (the error is the line above "Call stack trace" that you didn't copy+paste)

anyway, your "for" loop is wrong, if you use "return" inside, it will exit the "CheckStatus" function,
use "continue" instead to go to the next index, otherwise it will stop looping in the first "not in game" client

[Iciaria]

Originally Posted by Marttt Wrong section, and the snippet provided doesn't give any clue about your exception (the error is the line above "Call stack trace" that you didn't copy+paste) anyway, your "for" loop is wrong, if you use "return" inside, it will exit the "CheckStatus" function, use "continue" instead to go to the next index, otherwise it will stop looping in the first "not in game" client

Thanks a lot, everything is clear now.my stupid mistakexD

PS.I only see this error in the log, so I didn't paste the other lines because they are the same.

[Marttt]

They may be the same, but the specific error message is above

E.g:

PHP Code:

L 03/12/2023 - 21:07:22: [SM] Exception reported: Entity 1 (1) is invalid
L 03/12/2023 - 21:07:22: [SM] Blaming: someplugin.smx
L 03/12/2023 - 21:07:22: [SM] Call stack trace:
L 03/12/2023 - 21:07:22: [SM]   [0] SetEntPropEnt
L 03/12/2023 - 21:07:22: [SM]   [1] Line 210, someplugin.sp::OnGameFrame 


"Exception reported: Entity 1 (1) is invalid" part also matters to someone help you.

In your case if you are using "EventHookMode_PostNoCopy" you can't use Event.GetInt functions,
cause EventHookMode_PostNoCopy is just a notification,
without any values from event, just triggers after it was sent.

So you will keep having errors in log, just change to EventHookMode_Post (or leave it blank cause is the default value)

PHP Code:

enum EventHookMode
{
    EventHookMode_Pre,                  //< Hook callback fired before event is fired */
    EventHookMode_Post,                 //< Hook callback fired after event is fired */
    EventHookMode_PostNoCopy            //< Hook callback fired after event is fired, but event data won't be copied */
}; 


[Grey83]

PHP Code:

                if(!IsClientInGame(i) )
                        return; 


==>

PHP Code:

                if(!IsClientInGame(i) )
                        continue; 


https://wiki.alliedmods.net/Introduc...7#Loop_Control

[Iciaria]

that should be right

PHP Code:

public void OnPluginStart()
{
#if DEBUG
        HookEvent("weapon_fire", Event_Weapon_Fire);            
#endif
}
void Event_Weapon_Fire(Event event, const char[] name, bool dontBroadcast)
{
        int client = GetClientOfUserId(event.GetInt("userid"));
        if(!IsFakeClient(client))
        {
                CheckStatus();
        }
}
void CheckStatus()
{
        for(int i =1; i<=MaxClients; i++)
        {
                if(!IsClientInGame(i) )
                        continue;
                if(GetClientTeam(i) == 2)
                {       
                        char name[64];
                        GetClientName(i, name, sizeof(name) );
                        int health = GetEntProp(i, Prop_Send, "m_iHealth");
                        float buffer = GetTempHealth(i);
                        int count = GetEntProp(i, Prop_Send, "m_currentReviveCount");
                        PrintToChatAll("%s#HP:%d， TEMP:%f， REV:%d,", name, health, buffer, count);
                        PrintToServer("%s#HP:%d， TEMP:%f， REV:%d,", name, health, buffer, count);
                }
        }

} 


L 03/24/2023 - 19:59:23: [SM] Blaming: test.smx
L 03/24/2023 - 19:59:23: [SM] Call stack trace:
L 03/24/2023 - 19:59:23: [SM]   [0] Event.GetInt
L 03/24/2023 - 19:59:23: [SM]   [1] Line 90, test.sp::Event_Weapon_Fire

Sorry I seem to have forgotten to paste a lot of important stuff
, the problem is only because of "return;"
Anyway thanks.

[Grey83]

PHP Code:

#pragma semicolon 1
#pragma newdecls required

public void OnPluginStart()
{
#if DEBUG
    HookEvent("weapon_fire", Event_Weapon_Fire);
#endif
}

public void Event_Weapon_Fire(Event event, const char[] name, bool dontBroadcast)
{
    int client = GetClientOfUserId(event.GetInt("userid"));
    if(client && !IsFakeClient(client)) CheckStatus();
}

stock void CheckStatus()
{
    float buffer;
    for(int i = 1, health, count; i <= MaxClients; i++) if(IsClientInGame(i) && GetClientTeam(i) == 2)
    {
        health = GetEntProp(i, Prop_Send, "m_iHealth");
        buffer = GetTempHealth(i);
        count = GetEntProp(i, Prop_Send, "m_currentReviveCount");

        PrintToChatAll("%N#HP:%d， TEMP:%f， REV:%d,", i, health, buffer, count);
        PrintToServer("%N#HP:%d， TEMP:%f， REV:%d,", i, health, buffer, count);
    }
}