[404UserNotFound]

So I was converting the Pyro's Hadouken plugin to newdecls, and here's what I've got thus far:

Spoiler

PHP Code:

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>
#include <tf2>
#include <tf2_stocks>

#pragma semicolon 1
#pragma newdecls required

public void OnEntityCreated(int iEntity, const char[] strClassName)
{
    if (!StrEqual(strClassName, "instanced_scripted_scene", false))
    {
        return;
    }
    SDKHook(iEntity, SDKHook_Spawn, OnSceneSpawned);
}

public Action OnSceneSpawned(int iEntity)
{
    int iClient = GetEntPropEnt(iEntity, Prop_Data, "m_hOwner");
    char strSceneFile[128];
    GetEntPropString(iEntity, Prop_Data, "m_iszSceneFile", strSceneFile, sizeof(strSceneFile));
    if (StrEqual(strSceneFile, "scenes/player/pyro/low/taunt02.vcd"))
    {
        if ((GetEntityFlags(iClient) & FL_ONGROUND) )  
        {
            if (!IsValidClient(iClient))
            {
                return Plugin_Continue;
            }
            if (!IsPlayerAlive(iClient))
            {
                return Plugin_Continue;
            }
            if (TF2_GetPlayerClass(iClient) != TFClass_Pyro)
            {
                return Plugin_Continue;
            }
            if (TF2_IsPlayerInCondition(iClient, TFCond_Taunting))
            {
                return Plugin_Continue;
            }
            CreateTimer(2.0, FireBall, iClient);
            CreateTimer(0.1, AddCondition, iClient);
        }
    }
    return Plugin_Continue;
}

public Action AddCondition(Handle hTimer, any aClient)
{
    int iIndexTaunt = GetEntProp(aClient, Prop_Send, "m_iTauntItemDefIndex");
    switch(iIndexTaunt)
    {
        case 167, 438, 463, 1106, 1107, 1109, 1110, 1111, 1112, 1113, 1114, 1115, 1116, 1117, 1118, 1119, 1120, 1121:
        {
            return Plugin_Handled;            
        }
    }
    TF2_AddCondition(aClient, TFCond_Kritzkrieged, 1.3);
    TF2_AddCondition(aClient, TFCond_Buffed, 1.3);
    
    return Plugin_Handled;
}

public Action FireBall(Handle hTimer, any aClient)
{
    if (!IsValidClient(aClient))
    {
        return Plugin_Handled;
    }
    if (!IsPlayerAlive(aClient))
    {
        return Plugin_Handled;
    }
    if (TF2_GetPlayerClass(aClient) != TFClass_Pyro)
    {
        return Plugin_Handled;
    }
    if (!TF2_IsPlayerInCondition(aClient, TFCond_Taunting))
    {
        return Plugin_Handled;
    }
    float fPosition[3];
    float fAngles[3];
    fAngles[2] += 25.0;
    int iTeam = GetClientTeam(aClient);
    GetClientEyePosition(aClient, fPosition);
    GetClientEyeAngles(aClient, fAngles);
    int iWeapon = GetEntPropEnt(aClient, Prop_Send, "m_hActiveWeapon");
    int iIndex = GetEntProp(iWeapon, Prop_Send, "m_iItemDefinitionIndex");
    if(iWeapon && IsValidEdict(iWeapon))
    {
        switch(iIndex)
        {
            case 12, 1141, 199, 39, 351, 415, 595, 1081, 1153:
            {
                int iIndextaunt = GetEntProp(aClient, Prop_Send, "m_iTauntItemDefIndex");
                switch(iIndextaunt)
                {
                    case 167, 438, 463, 1106, 1107, 1109, 1110, 1111, 1112, 1113, 1114, 1115, 1116, 1117, 1118, 1119, 1120, 1121:
                    {
                        return Plugin_Handled;            
                    }
                }
                RocketsGameFired(aClient, fPosition, fAngles, 650.0, 800.0, iTeam, true);
                TF2_AddCondition(aClient, TFCond_Ubercharged, 0.3);
                return Plugin_Changed;
            }
        }
    }        
    return Plugin_Handled;
}

public Action RocketsGameFired(int iClient, float fPosition[3], float fAngles[3], float fSpeed, float fDamage, int iTeam, bool bCritical)
{
    char strClassName[32] = "CTFProjectile_Rocket";
    int iRocket = CreateEntityByName("tf_projectile_energy_ball");
    if(!IsValidEntity(iRocket))
    {
        return -0;
    }
    
    float fVelocity[3];
    float fBuffer[3];
    
    GetAngleVectors(fAngles, fBuffer, NULL_VECTOR, NULL_VECTOR);
    
    fVelocity[0] = fBuffer[0]*fSpeed;
    fVelocity[1] = fBuffer[1]*fSpeed;
    fVelocity[2] = fBuffer[2]*fSpeed;
    
    TeleportEntity(iRocket, fPosition, fAngles, fVelocity);
    
    SetEntData(iRocket, FindSendPropInfo("CTFProjectile_Rocket", "m_iTeamNum"), GetClientTeam(iClient), true);
    SetEntData(iRocket, FindSendPropOffs(strClassName, "m_bCritical"), bCritical, true);
    SetEntPropEnt(iRocket, Prop_Send, "m_hOwnerEntity", iClient);
    SetEntDataFloat(iRocket, FindSendPropOffs(strClassName, "m_iDeflected") + 4, fDamage, true);
    
    SetVariantInt(iTeam);
    AcceptEntityInput(iRocket, "TeamNum", -1, -1, 0);

    SetVariantInt(iTeam);
    AcceptEntityInput(iRocket, "SetTeam", -1, -1, 0); 
    
    DispatchSpawn(iRocket);
    return iRocket;
} 


Specifically, the lines that are triggering the two tag mismatch errors are the two "returns" within the RocketsGameFired function;

Spoiler

PHP Code:

public Action RocketsGameFired(int iClient, float fPosition[3], float fAngles[3], float fSpeed, float fDamage, int iTeam, bool bCritical)
{
    char strClassName[32] = "CTFProjectile_Rocket";
    int iRocket = CreateEntityByName("tf_projectile_energy_ball");
    if(!IsValidEntity(iRocket))
    {
        return -0; // MISMATCH
    }
    
    float fVelocity[3];
    float fBuffer[3];
    
    GetAngleVectors(fAngles, fBuffer, NULL_VECTOR, NULL_VECTOR);
    
    fVelocity[0] = fBuffer[0]*fSpeed;
    fVelocity[1] = fBuffer[1]*fSpeed;
    fVelocity[2] = fBuffer[2]*fSpeed;
    
    TeleportEntity(iRocket, fPosition, fAngles, fVelocity);
    
    SetEntData(iRocket, FindSendPropInfo("CTFProjectile_Rocket", "m_iTeamNum"), GetClientTeam(iClient), true);
    SetEntData(iRocket, FindSendPropOffs(strClassName, "m_bCritical"), bCritical, true);
    SetEntPropEnt(iRocket, Prop_Send, "m_hOwnerEntity", iClient);
    SetEntDataFloat(iRocket, FindSendPropOffs(strClassName, "m_iDeflected") + 4, fDamage, true);
    
    SetVariantInt(iTeam);
    AcceptEntityInput(iRocket, "TeamNum", -1, -1, 0);

    SetVariantInt(iTeam);
    AcceptEntityInput(iRocket, "SetTeam", -1, -1, 0); 
    
    DispatchSpawn(iRocket);
    return iRocket; // MISMATCH
} 


What do.

(thank god the compiler tells you if you screwed up and used "void" where you should've used "Action" for example, that's a big help for me)

[Phil25]

RocketsGameFired should be int, not Action. And why are you returning -0?

[WildCard65]

here's a little something to help you out:

PHP Code:

DoSomething() {} 


is the same as:

PHP Code:

int DoSomething() {} 


just with the compiler possibly complaining about no value being returned.

Also:

PHP Code:

Action:DoSomething() { return Plugin_Continue; } 


is the same as:

PHP Code:

Action DoSomething() { return Plugin_Continue; } 


[Miu]

there's no negative zero in modern int representations, just return -1

[ddhoward]

The prototype in the documentation specifies Action. void also works.
https://sm.alliedmods.net/new-api/events/EventHook

[ddhoward]

It was contained within the includes, which is what the api pages were/are automagically generated from.

https://sm.alliedmods.net/api/index....e&id=38&file=&

PHP Code:

funcenum EventHook
{
    /**
     * Called when a game event is fired.
     *
     * @param event            Handle to event. This could be INVALID_HANDLE if every plugin hooking 
     *                        this event has set the hook mode EventHookMode_PostNoCopy.
     * @param name            String containing the name of the event.
     * @param dontBroadcast    True if event was not broadcast to clients, false otherwise.
     * @return                Ignored for post hooks. Plugin_Handled will block event if hooked as pre.
     */
    Action:public(Handle:event, const String:name[], bool:dontBroadcast),
    /**
     * Called when a game event is fired.
     *
     * @param event            Handle to event. This could be INVALID_HANDLE if every plugin hooking 
     *                        this event has set the hook mode EventHookMode_PostNoCopy.
     * @param name            String containing the name of the event.
     * @param dontBroadcast    True if event was not broadcast to clients, false otherwise.
     * @noreturn
     */
    public(Handle:event, const String:name[], bool:dontBroadcast),
}; 


aaand the new syntax equivalent:
https://sm.alliedmods.net/new-api/events/__raw

PHP Code:

typeset EventHook
{
    // Called when a game event is fired.
    //
    // @param event            Handle to event. This could be INVALID_HANDLE if every plugin hooking 
    //                        this event has set the hook mode EventHookMode_PostNoCopy.
    // @param name            String containing the name of the event.
    // @param dontBroadcast    True if event was not broadcast to clients, false otherwise.
    // @return                Ignored for post hooks. Plugin_Handled will block event if hooked as pre.
    ///
    function Action (Event event, const char[] name, bool dontBroadcast);
    //
    // Called when a game event is fired.
    //
    // @param event            Handle to event. This could be INVALID_HANDLE if every plugin hooking 
    //                        this event has set the hook mode EventHookMode_PostNoCopy.
    // @param name            String containing the name of the event.
    // @param dontBroadcast    True if event was not broadcast to clients, false otherwise.
    // @noreturn
    ///
    function void (Event event, const char[] name, bool dontBroadcast);
}; 


[Chaosxk]

Originally Posted by abrandnewday Got another question; PHP Code: public Action Event_PlayerSpawn(Handle hEvent, const char[] strName, bool bDontBroadcast) {     int iClient = GetClientOfUserId(hEvent.GetInt("userid"));  That above code gives me a method error; "error 105: cannot find method or property Handle.GetInt" If I switch "Handle hEvent" to "Event hEvent", it compiles properly. Why? If I'm converting from old syntax to new, do I need to switch events from "Handle hEvent" to "Event hEvent"? EDIT: Just now realizing that I'm using a horrible mishmash of old and new syntax. New syntax should be "Event hEvent".

Yes, these are the methods for the Event class: https://sm.alliedmods.net/new-api/events/Event

Take a look at the methods for the Handle class: https://sm.alliedmods.net/new-api/handles/Handle

As you can see, there isn't a Handle.GetInt in the Handle class but a Event.GetInt in the Event class.

Edit: Just realized you made an edit

[WildCard65]

Originally Posted by abrandnewday EDIT: Just now realizing that I'm using a horrible mishmash of old and new syntax. New syntax should be "Event hEvent".

Technically, it's not a mismatch of old and new syntax, this is:

PHP Code:

int g; // New
Handle:x; // Old (Because of the semicolon) 


the following is above but without the mismatch:

PHP Code:

int g;
Handle x 


[WildCard65]

Originally Posted by abrandnewday (I said mishmash, not mismatch ) And yeah, I see that it works if you keep "Handle", but then you can't do the new syntax "hEvent.GetEventInt" stuff, because it won't compile with "Handle"

view_as<Event>(hHandle).GetInt() is valid

[Phil25]

Sometimes it's better to keep using handles. I base that "sometimes" off that dynamic arrays work properly all the way when you have them as handles but will bug in some methods when you use ArrayList.