[Hunter-Digital]

Hello again, I'ved got into a bump... again

I tried to hook +jump to a simple public that detects if the user is ducking and make him jump higher... but I can't make the command run if I remove the ON_GROUND check using client prethink and press jump in air I'll fly =) and that's not what I need...

Anyways, the main thing is: When a player is pressing the jump button, detect if he's holding the duck button and do an action.
Can anyone help me ?

[Exolent[jNr]]

PHP Code:

#include <amxmodx>
#include <fakemeta>

// make sure u leave the '.0' at the end of the number
// or you will get compile errors :)
#define HIGH_JUMP_SPEED 300.0

new bool:g_HighJump[32];

public plugin_init()
{
    register_plugin("High Jump", "1.0", "Hunter-Digital");
    register_forward(FM_PlayerPreThink, "fwd_PlayerPreThink");
    register_forward(FM_PlayerPostThink, "fwd_PlayerPostThink");
}

public fwd_PlayerPreThink(id)
{
    if(is_user_alive(id) && (pev(id, pev_flags) & FL_ONGROUND))
    {
        static button, oldbuttons;
        button = pev(id, pev_button);
        oldbuttons = pev(id, pev_oldbuttons);
        
        if((oldbuttons & IN_DUCK || button & IN_DUCK) && (button & IN_JUMP))
            g_HighJump[id-1] = true;
        else
            g_HighJump[id-1] = false;
    }
    return FMRES_IGNORED;
}

public fwd_PlayerPostThink(id)
{
    if(is_user_alive(id) && g_HighJump[id-1])
    {
        static Float:velocity[3];
        pev(id, pev_velocity, velocity);
        velocity[2] = HIGH_JUMP_SPEED;
        set_pev(id, pev_velocity, velocity);
        g_HighJump[id-1] = false;
    }
    return FMRES_IGNORED;
} 


you might have to play around with the number to get it the way u want it

[[ --<-@ ] Black Rose]

What?
This is like a jump just a bit more powerfull.

[Exolent[jNr]]

it checks if they are on the ground

and then they can only get the boost if they are on the ground and holding duck + jump

so they wont keep flying up into the air

[Hunter-Digital]

yes, it works excelent, thak you +k

bdw, I just needed a little script, I do not intend to make a plugin just from this this was a bump , but's solved now

PS: bdw, this type of plugin has been already made ? high-jump by duck+jump ? 'cause you can release it X-olent in your name 'cause it's your work

[Exolent[jNr]]

i probably wont because its just a small plugin but i might

[Hunter-Digital]

A small plugin that severily affects gameplay on a normal server

[Voi]

how to know if player just jumped ?:F

[Exolent[jNr]]

as in he landed or he just left the ground?

[StSatan]

Exolent[jNr] Server fps is very low with this plugin. It cause much lags. Please fix it.