[bibu]

I am having some troubles with Ham's AddPlayerItem. In the following code, I test it on dust as T and using only the first chat print, this gets called 3 times.

- knife
- glock
- c4

But after trying to filter some weapons out with cs_get_weapon_id, it all acts differently. The default function gets like printed more than 10 times.

See this output:

PHP Code:

knife, USP or C4 added.
some other weapon blocked.
knife, USP or C4 added.
some other weapon blocked.
some other weapon blocked.
some other weapon blocked.
some other weapon blocked.
some other weapon blocked.
some other weapon blocked.
some other weapon blocked. 


The first 3 prints are right I assume, since the glock also gets blocked, but what on earth are those other weapons which get blocked?

Test yourself on de_dust as T:

PHP Code:

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

public plugin_init()
    RegisterHam(Ham_AddPlayerItem, "player", "AddPlayerItem") 

public AddPlayerItem(id, iWeapon)
{
    // Using only the print below, it all works fine. And gets called three times on t spawn, knife + glock + c4
    //client_print(id, print_chat, "weapon added.")
        
    switch(cs_get_weapon_id(iWeapon))
    {
        // Allow getting knife, c4, and usp into the inventory.
        case CSW_KNIFE, CSW_USP, CSW_C4:
        {
            client_print(id, print_chat, "knife, USP or C4 added.")
            return HAM_IGNORED
        }
        // All other weapons can't be added.
        default:
        {
            client_print(id, print_chat, "some other weapon blocked.")
            SetHamReturnInteger(false) //dont know if this is needed?
            return HAM_SUPERCEDE
        } 
    }
    return HAM_IGNORED
} 


[ConnorMcLeod]

Why don't you debug it like this ?

PHP Code:

public AddPlayerItem(id, iWeapon)
{
    // Using only the print below, it all works fine. And gets called three times on t spawn, knife + glock + c4
    //client_print(id, print_chat, "weapon added.")

    new iId = cs_get_weapon_id(iWeapon);
    switch( iId )
    {
        // Allow getting knife, c4, and usp into the inventory.
        case CSW_KNIFE, CSW_USP, CSW_C4: // you don't check for glock18 ?
        {
            client_print(id, print_chat, "knife, USP or C4 added.")
            return HAM_IGNORED
        }
        // All other weapons can't be added.
        default:
        {
            new class[32];
            pev(iWeapon, pev_classname, class, charsmax(class));
            client_print(id, print_chat, "some other weapon blocked. iId=%d classname=%s", iId, class)
            SetHamReturnInteger(false) //dont know if this is needed?
            return HAM_SUPERCEDE
        }
    }
    return HAM_IGNORED
} 


[bibu]

knife, USP or C4 added. some other weapon blocked. iId=17 classname=weapon_glock18 knife, USP or C4 added. some other weapon blocked. iId=17 classname=weapon_glock18 some other weapon blocked. iId=17 classname=weapon_glock18 some other weapon blocked. iId=17 classname=weapon_glock18 some other weapon blocked. iId=17 classname=weapon_glock18 some other weapon blocked. iId=17 classname=weapon_glock18 some other weapon blocked. iId=17 classname=weapon_glock18 some other weapon blocked. iId=17 classname=weapon_glock18 // and much more...

Somehow then, I get glock like more than 20 times, how is that possible?

[ConnorMcLeod]

No idea, nobody knows what you are running on your server.
It doesn't seem to be default game behavior.

[bibu]

Originally Posted by ConnorMcLeod No idea, nobody knows what you are running on your server. It doesn't seem to be default game behavior.

Default plugins no other 3rd party plugins lol. Did you test on yourself?

[ConnorMcLeod]

Oh, i had forgotten that, you need to remove weapon, else it gonna be touch few times before it is removed.

PHP Code:

            set_pev(iWeapon, pev_flags, FL_KILLME);
            SetHamReturnInteger(false);
            return HAM_SUPERCEDE; 


You can check iWeapon value, it should be the same on all calls.

[bibu]

Originally Posted by ConnorMcLeod Oh, i had forgotten that, you need to remove weapon, else it gonna be touch few times before it is removed.

Wow, this helped, thank you. Could you answer me why such function require setting return to false and Ham_Touch to block weapon pickup not. On that hook superceding is just fine.

[Arkshine]

When you hook a function, superceding means you don't run the original function code but function is still hooked and you need to return a value. By default, Ham sets to 0. Therefore in this case, SetHamReturnInteger is not necessary, though adding it won't hurt (readability, consistency reasons).

A touch function is called several times by frame.
When you pickup a weapon, you are going to hit most likely such function :

PHP Code:

void CBasePlayerItem::DefaultTouch( CBaseEntity *pOther )
{
        // if it's not a player, ignore
        if ( !pOther->IsPlayer() )
                return;

        CBasePlayer *pPlayer = (CBasePlayer *)pOther;

        // can I have this?
        if ( !g_pGameRules->CanHavePlayerItem( pPlayer, this ) )
        {
                if ( gEvilImpulse101 )
                {
                        UTIL_Remove( this );
                }
                return;
        }

        if (pOther->AddPlayerItem( this ))
        {
                AttachToPlayer( pPlayer );
                EMIT_SOUND(ENT(pPlayer->pev), CHAN_ITEM, "items/gunpickup2.wav", 1, ATTN_NORM);
        }

        SUB_UseTargets( pOther, USE_TOGGLE, 0 ); // UNDONE: when should this happen?
} 


It means that if you want to supercede AddPlayerItem and you don't return 0, the code inside the check will be called. It's not what you want.
Also, since a touch function called several times in a row, and the weapon entity still existing, your callback is going to be called few times.
That's why you need, in this case, to tell the game this entity needs to be removed.