[anon12]

Hi can someone make me a plugin that blocks the radio at round start (Like "Go go go!")

I already tried this but it makes my server crash

PHP Code:

#include <amxmodx> 

#define VERSION "0.2.2" 
#define PLUGIN "RoundStart Radio Blocker" 

new Float:g_flRoundStartGameTime 
new gmsgSendAudio, g_iMsgSendAudio 
new Trie:g_tStartRoundSounds 

public plugin_init() 
{ 
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod") 
    register_logevent("LogEvent_Round_Start", 2, "1=Round_Start") 

    gmsgSendAudio = get_user_msgid("SendAudio") 

    new szStartRoundSounds[][] = { 
        "%!MRAD_LOCKNLOAD", 
        "%!MRAD_MOVEOUT", 
        "%!MRAD_LETSGO", 
        "%!MRAD_GO", 
        "%!MRAD_ELIM", 
        "%!MRAD_GETOUT", 
        "%!MRAD_VIP" 
    } 

    g_tStartRoundSounds = TrieCreate() 
    for(new i; i<sizeof(szStartRoundSounds); i++) 
    { 
        TrieSetCell(g_tStartRoundSounds, szStartRoundSounds[i], 1) 
    } 
} 

public LogEvent_Round_Start() 
{ 
    g_flRoundStartGameTime = get_gametime() 
    if( !g_iMsgSendAudio ) 
    { 
        g_iMsgSendAudio = register_message(gmsgSendAudio, "Message_SendAudio") 
    } 
} 

public Message_SendAudio()  
{ 
    if(get_gametime() != g_flRoundStartGameTime) 
    { 
        unregister_message(gmsgSendAudio, g_iMsgSendAudio) 
        g_iMsgSendAudio = 0 
        return PLUGIN_CONTINUE 
    } 

    new szArg2[18] 
    get_msg_arg_string(2, szArg2, charsmax(szArg2)) 
    if( TrieKeyExists(g_tStartRoundSounds, szArg2) ) 
    { 
        if( get_msg_block(SVC_TEMPENTITY) == BLOCK_NOT ) 
        { 
            set_msg_block(SVC_TEMPENTITY, BLOCK_ONCE) 
        } 
        return PLUGIN_HANDLED 
    } 

    return PLUGIN_CONTINUE 
} 


[AvaStIn]

untested , i dont have a licence to make scripts hhhh

PHP Code:

#include <amxmodx>  

#define VERSION "0.2.2"  
#define PLUGIN "RoundStart Radio Blocker"  

new Float:g_flRoundStartGameTime  
new gmsgSendAudio, g_iMsgSendAudio  
new Trie:g_tStartRoundSounds  
new gtoggle;

public plugin_init()  
{  
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")  
    register_logevent("LogEvent_Round_Start", 2, "1=Round_Start")  
    gtoggle = register_cvar( "amx_toggle", "1" );

    gmsgSendAudio = get_user_msgid("SendAudio")  

    new szStartRoundSounds[][] = {  
        "%!MRAD_LOCKNLOAD",  
        "%!MRAD_MOVEOUT",  
        "%!MRAD_LETSGO",  
        "%!MRAD_GO",  
        "%!MRAD_ELIM",  
        "%!MRAD_GETOUT",  
        "%!MRAD_VIP"  
    }  

    g_tStartRoundSounds = TrieCreate()  
    for(new i; i<sizeof(szStartRoundSounds); i++)  
    {  
        TrieSetCell(g_tStartRoundSounds, szStartRoundSounds[i], 1)  
    }  
}  

public LogEvent_Round_Start()  
{  
    if( get_pcvar_num( gtoggle ) != 0 )
    {
            g_flRoundStartGameTime = get_gametime()  
           if( !g_iMsgSendAudio )  
          {  
              g_iMsgSendAudio = register_message(gmsgSendAudio, "Message_SendAudio")  
           }  
    }
}  

public Message_SendAudio()   
{  
    if(get_gametime() != g_flRoundStartGameTime)  
    {  
        unregister_message(gmsgSendAudio, g_iMsgSendAudio)  
        g_iMsgSendAudio = 0  
        return PLUGIN_CONTINUE  
    }  

    new szArg2[18]  
    get_msg_arg_string(2, szArg2, charsmax(szArg2))  
    if( TrieKeyExists(g_tStartRoundSounds, szArg2) )  
    {  
        if( get_msg_block(SVC_TEMPENTITY) == BLOCK_NOT )  
        {  
            set_msg_block(SVC_TEMPENTITY, BLOCK_ONCE)  
        }  
        return PLUGIN_HANDLED  
    }  

    return PLUGIN_CONTINUE  
} 


[anon12]

still crashes =/ it crash when i run it with this plugin https://forums.alliedmods.net/showthread.php?p=490083

[ConnorMcLeod]

I don't see why they would interfer.
Anyway, try to declare them in a different order in plugins.ini

[anon12]

tried it =( no luck. when i disable 1 of those plugin it works fine. crash happens everytime the round starts.

EDIT: not every round mostly like every 1-3 round

[ConnorMcLeod]

I have no clue, reading both codes, why it would crash server.

@pokemonmaster
SVC_TEMPENTITY is to remove the green '!' shown above player's head.


Try this :

PHP Code:

#include < amxmodx >

#pragma semicolon 1

#define PLUGIN "RoundStart Radio Blocker"
#define VERSION "0.3.0"

new gmsgSendAudio, gmsgRoundTime;

new g_iSendAudio_BlockStatus, g_iSVC_TEMPENTITY_BlockStatus;

new g_iMsgRoundTime;

public plugin_init()
{
    register_plugin( PLUGIN, VERSION, "ConnorMcLeod" );
    register_logevent("LogEvent_Round_Start", 2, "1=Round_Start");

    gmsgSendAudio = get_user_msgid("SendAudio");
    gmsgRoundTime = get_user_msgid("RoundTime");
}

public LogEvent_Round_Start()
{
    new players[32], num;
    get_players(players, num, "a");
    if( num )
    {
        if( !g_iMsgRoundTime )
        {
            g_iSendAudio_BlockStatus = get_msg_block(gmsgSendAudio);
            g_iSVC_TEMPENTITY_BlockStatus = get_msg_block(SVC_TEMPENTITY);
            set_msg_block(gmsgSendAudio, BLOCK_SET);
            set_msg_block(SVC_TEMPENTITY, BLOCK_SET);
            g_iMsgRoundTime = register_message(gmsgRoundTime, "Message_RoundTime");
        }
    }
}

public Message_RoundTime()
{
    set_msg_block(gmsgSendAudio, g_iSendAudio_BlockStatus);
    set_msg_block(SVC_TEMPENTITY, g_iSVC_TEMPENTITY_BlockStatus);
    unregister_message(gmsgRoundTime, g_iMsgRoundTime);
    g_iMsgRoundTime = 0;
} 


[pokemonmaster]

Originally Posted by ConnorMcLeod @pokemonmaster SVC_TEMPENTITY is to remove the green '!' shown above player's head.

I figured that before deleting my post. anyway, thank you.

[anon12]

UPDATE: Plugin works but after a few map changes it stops working until i restart the server.

[Debesėlis]

Originally Posted by anon12 UPDATE: Plugin works but after a few map changes it stops working until i restart the server.

same for me. Any fix?

[yokomo]

This sure work haha:

PHP Code:

#include <amxmodx>

new bool:bCanHear

public plugin_init()
{
    register_plugin("Kush Kush Hota Hay", "0.0.1", "wbyokomo")
    
    register_event("HLTV", "OnNewRound", "a", "1=0", "2=0")
    register_logevent("OnRoundStart",2, "1=Round_Start")
    
    register_message(get_user_msgid("SendAudio"), "OnSendAudio")
}

public OnNewRound()
{
    bCanHear = false
}

public OnRoundStart()
{
    remove_task(6153)
    set_task(1.0, "TaskEnableRadio", 6153)
}

public OnSendAudio()
{
    if(!bCanHear) return PLUGIN_HANDLED;
    
    return PLUGIN_CONTINUE;
}

public TaskEnableRadio()
{
    bCanHear = true
}