[lemmon_cs]

I want a plugin that shows players faceit level on TAB Score automatically without any commands , it looks like this https://imgur.com/a/ilIVCDj and it's possible to do with this https://developers.faceit.com/

[CowGod]

********* on discord

[OcC]

Originally Posted by lemmon_cs I want a plugin that shows players faceit level on TAB Score automatically without any commands , it looks like this https://imgur.com/a/ilIVCDj and it's possible to do with this https://developers.faceit.com/

you can try this

PHP Code:

#pragma semicolon 1
#pragma newdecls required
#pragma dynamic 16384

#include <sdktools>
#include <sdkhooks>
#include <json>
#include <SteamWorks>

public Plugin myinfo =
{
    name = "Faceit Level",
    description = "Show players faceit rank",
    author = "Phoenix (˙·٠●Феникс●٠·˙)",
    version = "1.0.2",
    url = "zizt.ru hlmod.ru"
};

//Ваш ключ API
#define API_KEY     "ВАШ API КЛЮЧ"

enum struct Player
{
    int iUserID;
    int iSkillLevel;
    bool bLoad;
}

Player g_Players[MAXPLAYERS+1];
int m_nPersonaDataPublicLevel;


public void OnPluginStart()
{
    m_nPersonaDataPublicLevel = FindSendPropInfo("CCSPlayerResource", "m_nPersonaDataPublicLevel");
    
    for (int i = 1; i <= MaxClients; ++i)
    {
        if (IsClientAuthorized(i) && !IsFakeClient(i))
        {
            OnClientAuthorized(i, NULL_STRING);
        }
    }
}

public void OnMapStart()
{
    char sBuf[PLATFORM_MAX_PATH];
    
    for(int i = 0; i < 10; i++)
    {
        FormatEx(sBuf, sizeof sBuf, "materials/panorama/images/icons/xp/level%i.png", 5001 + i);
        
        AddFileToDownloadsTable(sBuf);
    }
    
    SDKHook(GetPlayerResourceEntity(), SDKHook_ThinkPost, Hook_OnThinkPost);
}

//Чтобы уменьшить количество запросов к API
public void OnClientConnected(int iClient)
{
    int iUserID = GetClientUserId(iClient);
    
    if(g_Players[iClient].iUserID != iUserID)
    {
        g_Players[iClient].iUserID = iUserID;
        g_Players[iClient].iSkillLevel = 0;
        g_Players[iClient].bLoad = false;
    }
}

public void OnClientAuthorized(int iClient, const char[] sAuth)
{
    if(g_Players[iClient].bLoad || IsFakeClient(iClient))
    {
        return;
    }
    
    char sBuf[20];
    
    GetClientAuthId(iClient, AuthId_SteamID64, sBuf, sizeof sBuf);
    
    Handle hRequest = SteamWorks_CreateHTTPRequest(k_EHTTPMethodGET, "https://open.faceit.com/data/v4/players");
    SteamWorks_SetHTTPRequestNetworkActivityTimeout(hRequest, 10);
    
    SteamWorks_SetHTTPRequestHeaderValue(hRequest, "Authorization", "Bearer " ... API_KEY);
    
    SteamWorks_SetHTTPRequestGetOrPostParameter(hRequest, "game", "csgo");
    SteamWorks_SetHTTPRequestGetOrPostParameter(hRequest, "game_player_id", sBuf);
    
    SteamWorks_SetHTTPRequestContextValue(hRequest, GetClientUserId(iClient));
    
    SteamWorks_SetHTTPCallbacks(hRequest, HTTPPlayerDetailsComplete);
    
    SteamWorks_SendHTTPRequest(hRequest);
}

void HTTPPlayerDetailsComplete(Handle hRequest, bool bFailure, bool bRequestSuccessful, EHTTPStatusCode eStatusCode, any iUserID)
{
    //Пока что игнорируем ошибки при загрузке
    if(eStatusCode == k_EHTTPStatusCode200OK || eStatusCode == k_EHTTPStatusCode404NotFound)
    {
        int iClient = GetClientOfUserId(iUserID);
        
        if(iClient)
        {
            //Если игрок играл на faceit
            if(eStatusCode == k_EHTTPStatusCode200OK)
            {
                SteamWorks_GetHTTPResponseBodyCallback(hRequest, HTTPPlayerDetailsCompleteData, iUserID);
            }
            else
            {
                g_Players[iClient].bLoad = true;
            }
        }
    }
    
    delete hRequest;
}

void HTTPPlayerDetailsCompleteData(const char[] sData, any iUserID)
{
    int iClient = GetClientOfUserId(iUserID);
    
    if(iClient)
    {
        JSON_Object root = json_decode(sData);
        JSON_Object games = root.GetObject("games");
        JSON_Object csgo = games.GetObject("csgo");
        
        if(csgo)
        {
            g_Players[iClient].iSkillLevel = csgo.GetInt("skill_level", 0);
        }
        
        root.Cleanup();
        delete root;
        
        g_Players[iClient].bLoad = true;
    }
}

void Hook_OnThinkPost(int iEnt)
{
    for (int i = 1; i <= MaxClients; i++)
    {
        if(g_Players[i].iSkillLevel)
        {
            SetEntData(iEnt, m_nPersonaDataPublicLevel + i * 4, g_Players[i].iSkillLevel + 5000);
        }
    }
} 


[raj kaul]

Originally Posted by OcC you can try this // C:\Users\PC\Desktop\compiler\scripting\includ e\SteamWorks.inc(215) : error 147: new-style declarations are required // C:\Users\PC\Desktop\compiler\scripting\includ e\SteamWorks.inc(216) : error 147: new-style declarations are required // C:\Users\PC\Desktop\compiler\scripting\includ e\SteamWorks.inc(217) : error 147: new-style declarations are required // C:\Users\PC\Desktop\compiler\scripting\includ e\SteamWorks.inc(21 : error 147: new-style declarations are required // C:\Users\PC\Desktop\compiler\scripting\includ e\SteamWorks.inc(219) : error 147: new-style declarations are required // C:\Users\PC\Desktop\compiler\scripting\includ e\SteamWorks.inc(219) : error 147: new-style declarations are required // C:\Users\PC\Desktop\compiler\scripting\includ e\SteamWorks.inc(220) : error 147: new-style declarations are required // C:\Users\PC\Desktop\compiler\scripting\includ e\SteamWorks.inc(220) : error 147: new-style declarations are required // C:\Users\PC\Desktop\compiler\scripting\includ e\SteamWorks.inc(221) : error 147: new-style declarations are required // C:\Users\PC\Desktop\compiler\scripting\includ e\SteamWorks.inc(221) : error 147: new-style declarations are required // C:\Users\PC\Desktop\compiler\scripting\includ e\SteamWorks.inc(222) : error 147: new-style declarations are required // C:\Users\PC\Desktop\compiler\scripting\includ e\SteamWorks.inc(223) : error 147: new-style declarations are required // C:\Users\PC\Desktop\compiler\scripting\includ e\SteamWorks.inc(223) : error 147: new-style declarations are required // C:\Users\PC\Desktop\compiler\scripting\includ e\SteamWorks.inc(223) : error 147: new-style declarations are required // C:\Users\PC\Desktop\compiler\scripting\includ e\SteamWorks.inc(223) : fatal error 190: too many error messages on one line]

i dont know about coding and getting this errors . can you help me ?

[8guawong]

Originally Posted by raj kaul i dont know about coding and getting this errors . can you help me ?

PHP Code:

#pragma semicolon 1

#include <SteamWorks>
#pragma newdecls required
#pragma dynamic 16384

#include <sdktools>
#include <sdkhooks>
#include <json>

public Plugin myinfo =
{
    name = "Faceit Level",
    description = "Show players faceit rank",
    author = "Phoenix (˙·٠●Феникс●٠·˙)",
    version = "1.0.2",
    url = "zizt.ru hlmod.ru"
};

//Ваш ключ API
#define API_KEY     "ВАШ API КЛЮЧ"

enum struct Player
{
    int iUserID;
    int iSkillLevel;
    bool bLoad;
}

Player g_Players[MAXPLAYERS+1];
int m_nPersonaDataPublicLevel;


public void OnPluginStart()
{
    m_nPersonaDataPublicLevel = FindSendPropInfo("CCSPlayerResource", "m_nPersonaDataPublicLevel");
    
    for (int i = 1; i <= MaxClients; ++i)
    {
        if (IsClientAuthorized(i) && !IsFakeClient(i))
        {
            OnClientAuthorized(i, NULL_STRING);
        }
    }
}

public void OnMapStart()
{
    char sBuf[PLATFORM_MAX_PATH];
    
    for(int i = 0; i < 10; i++)
    {
        FormatEx(sBuf, sizeof sBuf, "materials/panorama/images/icons/xp/level%i.png", 5001 + i);
        
        AddFileToDownloadsTable(sBuf);
    }
    
    SDKHook(GetPlayerResourceEntity(), SDKHook_ThinkPost, Hook_OnThinkPost);
}

//Чтобы уменьшить количество запросов к API
public void OnClientConnected(int iClient)
{
    int iUserID = GetClientUserId(iClient);
    
    if(g_Players[iClient].iUserID != iUserID)
    {
        g_Players[iClient].iUserID = iUserID;
        g_Players[iClient].iSkillLevel = 0;
        g_Players[iClient].bLoad = false;
    }
}

public void OnClientAuthorized(int iClient, const char[] sAuth)
{
    if(g_Players[iClient].bLoad || IsFakeClient(iClient))
    {
        return;
    }
    
    char sBuf[20];
    
    GetClientAuthId(iClient, AuthId_SteamID64, sBuf, sizeof sBuf);
    
    Handle hRequest = SteamWorks_CreateHTTPRequest(k_EHTTPMethodGET, "https://open.faceit.com/data/v4/players");
    SteamWorks_SetHTTPRequestNetworkActivityTimeout(hRequest, 10);
    
    SteamWorks_SetHTTPRequestHeaderValue(hRequest, "Authorization", "Bearer " ... API_KEY);
    
    SteamWorks_SetHTTPRequestGetOrPostParameter(hRequest, "game", "csgo");
    SteamWorks_SetHTTPRequestGetOrPostParameter(hRequest, "game_player_id", sBuf);
    
    SteamWorks_SetHTTPRequestContextValue(hRequest, GetClientUserId(iClient));
    
    SteamWorks_SetHTTPCallbacks(hRequest, HTTPPlayerDetailsComplete);
    
    SteamWorks_SendHTTPRequest(hRequest);
}

void HTTPPlayerDetailsComplete(Handle hRequest, bool bFailure, bool bRequestSuccessful, EHTTPStatusCode eStatusCode, any iUserID)
{
    //Пока что игнорируем ошибки при загрузке
    if(eStatusCode == k_EHTTPStatusCode200OK || eStatusCode == k_EHTTPStatusCode404NotFound)
    {
        int iClient = GetClientOfUserId(iUserID);
        
        if(iClient)
        {
            //Если игрок играл на faceit
            if(eStatusCode == k_EHTTPStatusCode200OK)
            {
                SteamWorks_GetHTTPResponseBodyCallback(hRequest, HTTPPlayerDetailsCompleteData, iUserID);
            }
            else
            {
                g_Players[iClient].bLoad = true;
            }
        }
    }
    
    delete hRequest;
}

void HTTPPlayerDetailsCompleteData(const char[] sData, any iUserID)
{
    int iClient = GetClientOfUserId(iUserID);
    
    if(iClient)
    {
        JSON_Object root = json_decode(sData);
        JSON_Object games = root.GetObject("games");
        JSON_Object csgo = games.GetObject("csgo");
        
        if(csgo)
        {
            g_Players[iClient].iSkillLevel = csgo.GetInt("skill_level", 0);
        }
        
        root.Cleanup();
        delete root;
        
        g_Players[iClient].bLoad = true;
    }
}

void Hook_OnThinkPost(int iEnt)
{
    for (int i = 1; i <= MaxClients; i++)
    {
        if(g_Players[i].iSkillLevel)
        {
            SetEntData(iEnt, m_nPersonaDataPublicLevel + i * 4, g_Players[i].iSkillLevel + 5000);
        }
    }
} 


should work

[raj kaul]

Originally Posted by 8guawong should work

PHP Code:

// C:\Users\PC\Desktop\compiler\scripting\faceitapi.sp(23) : error 001: expected token: "{", but found "struct"
// C:\Users\PC\Desktop\compiler\scripting\faceitapi.sp(25) : error 001: expected token: "public", but found "int"
// C:\Users\PC\Desktop\compiler\scripting\faceitapi.sp(26) : error 001: expected token: "}", but found "int"
// C:\Users\PC\Desktop\compiler\scripting\faceitapi.sp(28) : error 054: unmatched closing brace ("}")
// C:\Users\PC\Desktop\compiler\scripting\faceitapi.sp(66) : error 017: undefined symbol "g_Players"
// C:\Users\PC\Desktop\compiler\scripting\faceitapi.sp(66) : warning 215: expression has no effect
// C:\Users\PC\Desktop\compiler\scripting\faceitapi.sp(66) : error 001: expected token: ";", but found "]"
// C:\Users\PC\Desktop\compiler\scripting\faceitapi.sp(66) : error 029: invalid expression, assumed zero
// C:\Users\PC\Desktop\compiler\scripting\faceitapi.sp(66) : fatal error 190: too many error messages on one line 


[Franc1sco]

I added a cvar for people that dont know how to compile and I added the downlodable content.

EDIT: use this.

[LowPriority]

Originally Posted by Franc1sco I added a cvar for people that dont know how to compile and I added the downlodable content.

thank you for this but i still get this error

PHP Code:

L 05/12/2020 - 08:37:47: [SM] Exception reported: String formatted incorrectly - parameter 4 (total 3)
L 05/12/2020 - 08:37:47: [SM] Blaming: faceit_level.smx
L 05/12/2020 - 08:37:47: [SM] Call stack trace:
L 05/12/2020 - 08:37:47: [SM]   [0] Format
L 05/12/2020 - 08:37:47: [SM]   [1] Line 85, E:\Dropbox\UEA\1css server\faceit\faceit_level.sp::OnClientAuthorized 


my server.cfg settings

sm_faceitlevel_api "MY API" // change the value for your api key

[enjoi.]

I love your idea.

[Franc1sco]

Originally Posted by LowPriority my server.cfg settings sm_faceitlevel_api "MY API" // change the value for your api key

You need a api from https://developers.faceit.com/