[Endoint]

Hi,

I'm after a plugin that removes bomb damage entirely.
I'd basically like the bomb to never effect players on my server, but obviously still have grenade damage, etc.

I have read over this plugin, but it seems that this firstly; only removes bomb damage after the round ends, and secondly, seems to only have the ability to set this for specific admin flags, rather than for the entire server and anyone who enters it.

Does anyone know of any plugin that will do what i'm after?

Thanks.

[Drixevel]

#include <sourcemod>
#include <sdkhooks>

#define PLUGIN_VERSION "2.1"

public Plugin myinfo = 
{
	name = "No Bomb Damage",
	author = "Keith Warren (Shaders Allen)",
	description = "Stops all damage from bombs occuring to players.",
	version = PLUGIN_VERSION,
	url = "http://github.com/shadersallen"
}

public void OnPluginStart()
{
	for (int i = 1; i <= MaxClients; i++)
	{
		if (IsClientInGame(i))
			OnClientPutInServer(i);
	}
}

public void OnClientPutInServer(int client)
{	
	SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage);
}

public Action OnTakeDamage(int victim, int& attacker, int& inflictor, float& damage, int& damagetype)
{
	if (!IsValidEntity(inflictor))
		return Plugin_Continue;
	
	char class[32];
	GetEntityClassname(inflictor, class, sizeof(class));
	
	if (!StrEqual(class, "planted_c4", false))
		return Plugin_Continue;
	
	damage = 0.0;
	return Plugin_Changed;
}

[Bacardi]

There are on some maps env_explosion added in bombsite, to create more effect when c4 explode.
So those can hurt players also when they are too near.

[Endoint]

Originally Posted by Drixevel #include <sourcemod> #include <sdkhooks> #define PLUGIN_VERSION "2.1" public Plugin myinfo = { name = "No Bomb Damage", author = "Keith Warren (Shaders Allen)", description = "Stops all damage from bombs occuring to players.", version = PLUGIN_VERSION, url = "http://github.com/shadersallen" } public void OnPluginStart() { for (int i = 1; i <= MaxClients; i++) { if (IsClientInGame(i)) OnClientPutInServer(i); } } public void OnClientPutInServer(int client) { SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage); } public Action OnTakeDamage(int victim, int& attacker, int& inflictor, float& damage, int& damagetype) { if (!IsValidEntity(inflictor)) return Plugin_Continue; char class[32]; GetEntityClassname(inflictor, class, sizeof(class)); if (!StrEqual(class, "planted_c4", false)) return Plugin_Continue; damage = 0.0; return Plugin_Changed; }

Wow thank you kind sir

Originally Posted by Bacardi There are on some maps env_explosion added in bombsite, to create more effect when c4 explode. So those can hurt players also when they are too near.

Which maps are you talking about? Is there a way around this?

[Bacardi]

Originally Posted by Endoint Which maps are you talking about? Is there a way around this?

well I don't know, which maps have those.
Cs:s has at least in map de_dust2. It's rare object after all.

I just mention it so you would not be suprised if player die at event c4 explosion.

[godzcsgo]

Is this for CS:GO or CS:S?

[CliptonHeist]

Originally Posted by godzcsgo Is this for CS:GO or CS:S?

Both

[Drumanid]

#include <sourcemod>

public Plugin myinfo =
{
	name = "No bomb damage",
	author = "Drumanid",
	version = "1.0.0",
	url = "Discord: Drumanid#9108"
};

public void OnPluginStart()
{
	HookEvent("bomb_exploded", view_as<EventHook>(BombExploded), EventHookMode_Pre);
}

#define OFF 0
#define ON 2
void BombExploded()
{
	Damage(OFF);
	RequestFrame(view_as<RequestFrameCallback>(BombExplodedFrame));
}

void BombExplodedFrame()
{
	Damage(ON);
}

void Damage(int iType)
{
	for(int iClient = 1; iClient <= MaxClients; ++iClient)
		if(IsClientInGame(iClient) && IsPlayerAlive(iClient))
			SetEntProp(iClient, Prop_Data, "m_takedamage", iType);
}

[eyal282]

Originally Posted by Drumanid #include <sourcemod> public Plugin myinfo = { name = "No bomb damage", author = "Drumanid", version = "1.0.0", url = "Discord: Drumanid#9108" }; public void OnPluginStart() { HookEvent("bomb_exploded", view_as<EventHook>(BombExploded), EventHookMode_Pre); } #define OFF 0 #define ON 2 void BombExploded() { Damage(OFF); RequestFrame(view_as<RequestFrameCallback>(BombExplodedFrame)); } void BombExplodedFrame() { Damage(ON); } void Damage(int iType) { for(int iClient = 1; iClient <= MaxClients; ++iClient) if(IsClientInGame(iClient) && IsPlayerAlive(iClient)) SetEntProp(iClient, Prop_Data, "m_takedamage", iType); }

Never use such a pathetic method especially when:

1. There are working alternatives.
2. This will enforce disabling godmode on all players.

[Drumanid]

Originally Posted by eyal282 Never use such a pathetic method especially when: 1. There are working alternatives. 2. This will enforce disabling godmode on all players.

I do not think that this method is 'pathetic'.

1. What is higher? - No
Better than checking for damage every time.
2. What prevents to make a check?

There is a better option, suggest
Not agree - criticize, criticize - offer, offer - do, do - answer.

Another view implementation:

#include <sourcemod>
#include <sdkhooks>

public Plugin myinfo =
{
	name = "No bomb damage",
	author = "Drumanid",
	version = "1.0.0",
	url = "Discord: Drumanid#9108"
};

public void OnPluginStart()
{
	HookEvent("bomb_exploded", view_as<EventHook>(Event_BombExploded), EventHookMode_Pre);
}

#define EVENT(%0) \
for(int iClient = 1; iClient <= MaxClients; ++iClient)\
if(IsClientInGame(iClient) && IsPlayerAlive(iClient))\
%0(iClient, SDKHook_OnTakeDamageAlive, OnTakeDamageAlive)

void Event_BombExploded()
{
	EVENT(SDKHook);
	RequestFrame(view_as<RequestFrameCallback>(BombExplodedFrame));
}

void BombExplodedFrame()
{
	EVENT(SDKUnhook);
}

Action OnTakeDamageAlive(int iVictim, int &iAttacker, int &iInflictor, float &fDamage, int &iDamageType)
{
	return iDamageType == 64 ? Plugin_Handled:Plugin_Continue;
}