[ConnorMcLeod]

Hi, i have found a feature in the game that made me think on a new semiclip method.
Can some people would be kind enough to test that method with that team semiclip plugin ?
There are nor cvars, semiclip is for both teams but obviously only between teamates.
There is one chat command : /invis that allow players to not see their teamates at all.

The only problem with this method is that you don't hear anymore your teamates (runing, fire, buying etc...), but it can still be a good method for kz or surf servers or whatever.

Spoiler

PHP Code:

#define SHOW_NAMES_WHEN_AIM
// #define ENABLE_SHOTS_DAMAGE

#include <amxmodx>
#include <engine>
#include <fakemeta>
#include <hamsandwich>

#define VERSION "0.1.0"
#define PLUGIN "Team SemiClip"

#define MAX_PLAYERS 32

#define get_player_team(%0)    get_pdata_int(%0,114)

#define GROUP_OP_NAND    1

#if defined SHOW_NAMES_WHEN_AIM
    new HamHook:PreThink, HamHook:PreThinkP
#endif

#if defined ENABLE_SHOTS_DAMAGE
    new HamHook:PostThink, HamHook:PostThinkP
#endif

new g_iCurrentPlayer
new g_bSeePlayers[MAX_PLAYERS+1], bool:g_bIsPlayerNearCurrentPlayer[MAX_PLAYERS+1]

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")

    register_clcmd("say /invis", "ClCmd_Invis", PLUGIN_CONTINUE)
    register_clcmd("say_team /invis", "ClCmd_Invis", PLUGIN_HANDLED)

    RegisterHam(Ham_Spawn, "player", "CBasePlayer_Spawn_Post", true)
    RegisterHam(Ham_Killed, "player", "CBasePlayer_Killed_Post", true)

    register_forward(FM_AddToFullPack, "client_AddToFullPack", 0)
    register_forward(FM_AddToFullPack, "client_AddToFullPack_P", 1)

    register_forward(FM_CmdStart, "client_CmdStart_P", 1)

    #if defined SHOW_NAMES_WHEN_AIM
        DisableHamForward( PreThink = RegisterHam(Ham_Player_PreThink, "player", "CBasePlayer_PreThink", 0) )
        DisableHamForward( PreThinkP = RegisterHam(Ham_Player_PreThink, "player", "CBasePlayer_PreThink_P", 1) )
    #endif

    #if defined ENABLE_SHOTS_DAMAGE
        DisableHamForward( PostThink = RegisterHam(Ham_Player_PostThink, "player", "CBasePlayer_PostThink", 0) )
        DisableHamForward( PostThinkP = RegisterHam(Ham_Player_PostThink, "player", "CBasePlayer_PostThink_P", 1) )
    #endif
}

public client_putinserver(id) 
{
    g_bSeePlayers[id] = true
}

public ClCmd_Invis(id, RETURN_TYPE)
{
    g_bSeePlayers[id] = !g_bSeePlayers[id]
    client_print(id, print_chat, " ** Teamates Visibility is now %s.", g_bSeePlayers[id] ? "On" : "Off")
    return RETURN_TYPE
}

public CBasePlayer_Spawn_Post( id )
{
    if( is_user_alive(id) )
    {
        set_pev(id, pev_groupinfo, get_player_team(id))
    }
}

public CBasePlayer_Killed_Post( id )
{
    set_pev(id, pev_groupinfo, 0)
}

public client_CmdStart_P( id )
{
    static shouldsee, enabled
    if( ( shouldsee = is_user_alive(id) ) )
    {
        engfunc(EngFunc_SetGroupMask, 1, GROUP_OP_NAND)
        set_pev(id, pev_groupinfo, get_player_team(id))
        shouldsee *= g_bSeePlayers[id]
    }
    if( enabled != shouldsee )
    {
        if( !enabled )
        {
            enabled = true
            #if defined SHOW_NAMES_WHEN_AIM
                EnableHamForward( PreThink )
                EnableHamForward( PreThinkP )
            #endif
            #if defined ENABLE_SHOTS_DAMAGE
                EnableHamForward( PostThink )
                EnableHamForward( PostThinkP )
            #endif
        }
        else
        {
            enabled = false
            #if defined SHOW_NAMES_WHEN_AIM
                DisableHamForward( PreThink )
                DisableHamForward( PreThinkP )
            #endif
            #if defined ENABLE_SHOTS_DAMAGE
                DisableHamForward( PostThink )
                DisableHamForward( PostThinkP )
            #endif
        }
    }
}

public client_AddToFullPack(es, e, ent, id, hostflags, player, pSet)
{
    if( player && g_iCurrentPlayer != id && is_user_alive(id) )
    {
        g_iCurrentPlayer = id

        static invis
        if( g_bSeePlayers[id] )
        {
            invis = false
            set_pev(id, pev_groupinfo, 0)
            static team
            static players[32], num, plr
            team = get_player_team(id)
            num = find_sphere_class(id, "player", 512.0, players, sizeof(players))
            arrayset(g_bIsPlayerNearCurrentPlayer, false, sizeof(g_bIsPlayerNearCurrentPlayer))
            for(--num; num>=0; num--)
            {
                plr = players[num]
                g_bIsPlayerNearCurrentPlayer[ plr ] = team == get_player_team(plr)
            }
        }
        else
        {
            if( !invis )
            {
                arrayset(g_bIsPlayerNearCurrentPlayer, false, sizeof(g_bIsPlayerNearCurrentPlayer))
                invis = true
            }
            set_pev(id, pev_groupinfo, 3 - get_player_team(id))
        }
    }
}

public client_AddToFullPack_P(es, e, ent, id, hostflags, player)
{
    if( !g_iCurrentPlayer || !is_user_alive(id) )
    {
        return
    }

    if( !player || g_iCurrentPlayer != id )
    {
        set_pev(g_iCurrentPlayer, pev_groupinfo, get_player_team(g_iCurrentPlayer))
        g_iCurrentPlayer = 0
        return
    }

    if( g_bSeePlayers[id] && g_bIsPlayerNearCurrentPlayer[ent] )
    {
        set_es(es, ES_Solid, SOLID_NOT)

        set_es(es, ES_RenderMode, kRenderTransColor) 
        set_es(es, ES_RenderAmt, floatround(entity_range(id, ent)*0.5))
    }
}

#if defined SHOW_NAMES_WHEN_AIM
    public CBasePlayer_PreThink(id)
    {
        set_pev(id, pev_groupinfo, 0)
    }

    public CBasePlayer_PreThink_P(id)
    {
        set_pev(id, pev_groupinfo, get_player_team(id))
    }
#endif

#if defined ENABLE_SHOTS_DAMAGE
    public CBasePlayer_PostThink(id)
    {
        set_pev(id, pev_groupinfo, 0)
    }

    public CBasePlayer_PostThink_P(id)
    {
        set_pev(id, pev_groupinfo, get_player_team(id))
    }
#endif 


[Lolz0r]

Maybe would do and for all player semiclip?

[ConnorMcLeod]

Here it is, i may post a reviewed version tomorrow.

Spoiler

PHP Code:

#define SHOW_NAMES_WHEN_AIM
// #define ENABLE_SHOTS_DAMAGE

// #define DONT_SEE_ANYONE // both previous defines are useless if you enable this

#include <amxmodx>
#include <fakemeta>

#if !defined DONT_SEE_ANYONE
    #include <engine> // entity_range
#endif

#define VERSION "0.1.0"
#define PLUGIN "SemiClip"

#if !defined DONT_SEE_ANYONE // NAND routine

    #define GROUP_OP_NAND    1

    public plugin_init()
    {
        register_plugin(PLUGIN, VERSION, "ConnorMcLeod")

        register_forward(FM_AddToFullPack, "client_AddToFullPack_P", 1)

        register_forward(FM_CmdStart, "client_CmdStart_P", 1) // instead of hooking FM_SetGroupMask and catching all AddToFullPack calls

        #if defined SHOW_NAMES_WHEN_AIM
            register_forward(FM_PlayerPreThink, "client_PlayerPreThink", 0)
            register_forward(FM_PlayerPreThink, "client_PlayerPreThink_P", 1)
        #endif

        #if defined ENABLE_SHOTS_DAMAGE
            register_forward(FM_PlayerPostThink, "client_PlayerPostThink", 0)
            register_forward(FM_PlayerPostThink, "client_PlayerPostThink_P", 1)
        #endif
    }

    public client_putinserver( id )
    {
        set_pev(id, pev_groupinfo, 1)
    }

    public client_CmdStart_P( id )
    {
        engfunc(EngFunc_SetGroupMask, 1, GROUP_OP_NAND)
    }

    #if defined SHOW_NAMES_WHEN_AIM
        public client_PlayerPreThink(id)
        {
            set_pev(id, pev_groupinfo, 0)
        }

        public client_PlayerPreThink_P(id)
        {
            set_pev(id, pev_groupinfo, 1)
        }
    #endif

    #if defined ENABLE_SHOTS_DAMAGE
        public client_PlayerPostThink(id)
        {
            set_pev(id, pev_groupinfo, 0)
        }

        public client_PlayerPostThink_P(id)
        {
            set_pev(id, pev_groupinfo, 1)
        }
    #endif

    public client_AddToFullPack_P(es, e, ent, id, hostflags, player, pSet)
    {
        if( player && id != ent && get_orig_retval() && is_user_alive(id) )
        {
            set_es(es, ES_Solid, SOLID_NOT)

            static Float:flDistance
            flDistance = entity_range(id, ent)
            if( flDistance < 512.0 )
            {
                set_es(es, ES_RenderMode, kRenderTransColor) 
                set_es(es, ES_RenderAmt, floatround(flDistance)/2) 
            }
        }
    }

#else // AND routine
    public plugin_init()
    {
        register_plugin(PLUGIN, VERSION, "ConnorMcLeod")
    }

    public client_putinserver( id )
    {
        set_pev(id, pev_groupinfo, 1<<(id&31))
    }
#endif 


[Lolz0r]

I will wait for the new version and will test both plugins.


I'll separate the I / invis function in a separate plugin?

[zhulo]

ConnorMcLeod, what is the difference between your method (set_pev(id, pev_groupinfo, 1)) and the previous (set_pev(id, pev_solid, SOLID_NOT))?

[ConnorMcLeod]

No, the player status need to be known by the semiclip plugin, but if you want in a separated plugin so you can make/keep your own menu, just create a dynamic native in your plugin or in this one it's not a big deal.

[brian201049]

I hope you can find out the problem that is the func_door and others movable entity will get stuck when two or more "semiclip ing" players and it touch that entity.

This problem can be solve by xPaw's DeathRun semiclip method but his method make the players cannot be knived.

[ConnorMcLeod]

Yes, proble should be fixed with that method.

[Lolz0r]

Originally Posted by ConnorMcLeod Yes, proble should be fixed with that method.

So this method is good for every mod?

[brian201049]

Originally Posted by ConnorMcLeod Yes, proble should be fixed with that method.

Really? You said your method can fix the func_door bug perfectly???
Tested or not? AWESOME!!

EDIT: ENABLE_SHOTS_DAMAGE must be uncommented

commented will make the emit sound didn't work