[OciXCrom]

Originally Posted by Napoleon_be It would be more convenient to have this option included by default, but no idea on how to manage this since many servers use different simon plugins.

Most mods usually have a "is_user_simon" native so you could use that by default and offer an easy way to change it. You can check to see if such a native is currently loaded in the server and use it.

[tonkata245]

Originally Posted by Napoleon_be I could do that. Adding colors is easy though, just read my topic on how to do it. Thanks for your input on the "unglowing" part. Right now, it is indeed still showing players to "unglow" which are already "unglowed", will fix that. So what i'll be doing is, i'll make a simon version for you and post it here. I'll also update my plugin and make it only show player names to unglow that are set glowing. You may expect this to be done by wednesday.

did you do it

[Napoleon_be]

Not yet, sorry for my false promises. I'm still going to hospitals every week. I've been suffering from cluster headaches the last couple months and the medicines bring all kind of side effects with them. I don't wanna go further into it tho, as i'm pretty fatigued.

The reason i've been promising these things is because i have days i feel pretty good and i feel like doing things, but the day after, things can turn real quick.

Hope someone else can help you out, cheers.

[tonkata245]

Originally Posted by Napoleon_be Not yet, sorry for my false promises. I'm still going to hospitals every week. I've been suffering from cluster headaches the last couple months and the medicines bring all kind of side effects with them. I don't wanna go further into it tho, as i'm pretty fatigued. The reason i've been promising these things is because i have days i feel pretty good and i feel like doing things, but the day after, things can turn real quick. Hope someone else can help you out, cheers.

Well no problem. I will put up with another plugin

[Napoleon_be]

Originally Posted by OciXCrom Most mods usually have a "is_user_simon" native so you could use that by default and offer an easy way to change it. You can check to see if such a native is currently loaded in the server and use it.

Could you give me an example on how this could be done? I've been looking at several tutorials and threads but i couldn't really relate on how to do this with the simon part. Thanks in advance.

https://forums.alliedmods.net/showthread.php?t=291455

https://forums.alliedmods.net/showthread.php?t=41251

EDIT: Okay honestly, never mind. I think i just found an easy fix for this. Like i said, medicines...

[OciXCrom]

Handling the native:

native is_user_simon(id)
new const SIMON_NATIVE[] = "is_user_simon"

new bool:g_bSimonNativeExists

public plugin_natives()
{
    set_native_filter("native_filter")
}

public native_filter(const szNative[], id, iTrap)
{
    if(!iTrap)
    {
        if(equal(szNative, SIMON_NATIVE))
        {
            g_bSimonNativeExists = true
            return PLUGIN_HANDLED
        }
    }

    return PLUGIN_CONTINUE
}

Using the native:

if(g_bSimonNativeExists && is_user_simon(id))
{
    // your code here...
}

You simply need to make sure that the native is not used unless it's loaded.

[Napoleon_be]

Originally Posted by OciXCrom You simply need to make sure that the native is not used unless it's loaded.

Isn't that what the native filter is used for or am i wrong?

Spoiler

PHP Code:

/* Sublime AMXX Editor v2.2 */

/*
    Credits to OciXCrom: took his way of configuring everything without hardcoding.
*/

#include <amxmodx>
#include <amxmisc>
#include <fun>
#include <cromchat>

#define PLUGIN  "Advanced Glow Menu [AGM]"
#define VERSION "2.1.2"
#define AUTHOR  "NapoleoN#"

#if AMXX_VERSION_NUM < 183
    const MAX_PLAYERS = 32;
    const MAX_NAME_LENGTH = 32;
    const MAX_FMT_LENGTH = 256;
#endif

enum _:g_eSettings
{
    PREFIX_STR[MAX_PLAYERS + 1],
    ACCESS_FLAGS_BIT,
    ACCESS_FLAGS_STR[MAX_PLAYERS + 1],
    AIM_FLAGS_BIT,
    AIM_FLAGS_STR[MAX_PLAYERS + 1],
    bool:CHAT_MSG_ENABLED,
    bool:RESET_GLOW_ROUNDSTART,
    bool:SIMON_ONLY
};

native is_user_simon(id);
new const g_szSimonNative[] = "is_user_simon";
new bool:g_bSimonNativeExists;

new g_szSettings[g_eSettings];

new Array:g_aColorInfo;
new g_iColorSize;

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);

    register_dictionary("AGMML.txt");

    register_logevent("roundStart", 2, "1=Round_Start");

    g_aColorInfo = ArrayCreate(50);

    readConfigFile(); // Changing any settings requires the map to be changed or the server to be restarted.
    readColors(); // Changing any settings requires the map to be changed or the server to be restarted.
}

public plugin_end()
{
    ArrayDestroy(g_aColorInfo);
}

public plugin_natives()
{
    set_native_filter("nativeFilter");
}

public nativeFilter(const szNative[], id, iTrap)
{
    if(!iTrap)
    {
        if((equal(szNative, g_szSimonNative)))
        {
            g_bSimonNativeExists = true
            return PLUGIN_HANDLED;
        }
    }
    return PLUGIN_CONTINUE;
}

public setGlowTarget(id)
{

    if(!has_agm_access(id))
    {
            ColorChat(id, GREEN, "%L", id, "MSG_NO_ACCESS", g_szSettings[PREFIX_STR]);
            return PLUGIN_HANDLED;
    }

    if(g_szSettings[SIMON_ONLY] && (g_bSimonNativeExists && is_user_simon(id)))
    {
        new iTarget, iBody;
        get_user_aiming(id, iTarget, iBody);

        log_amx("Access granted.");
        
        if(iTarget)
        {
            log_amx("Valid target found.");

            switch(get_user_team(iTarget))
            {
                case 1: set_user_rendering(iTarget, kRenderFxGlowShell, 255, 0, 0, kRenderNormal, 25); // Terrorists
                case 2: set_user_rendering(iTarget, kRenderFxGlowShell, 0, 0, 255, kRenderNormal, 25); // CT
            }
        }
    }

    return PLUGIN_HANDLED;
}

public removeGlowTarget(id)
{

    if(!has_aim_access(id))
    {
            ColorChat(id, GREEN, "%L", id, "MSG_NO_ACCESS", g_szSettings[PREFIX_STR]);
            return PLUGIN_HANDLED;
    }

    if(g_szSettings[SIMON_ONLY] && (g_bSimonNativeExists && is_user_simon(id)))
    {
        new iTarget, iBody;
        get_user_aiming(id, iTarget, iBody);

        if(iTarget)
        {
            set_user_rendering(iTarget);
        }
    }

    return PLUGIN_HANDLED;
}

public openGlowMenu(id)
{
    if(!has_agm_access(id))
    {
            ColorChat(id, GREEN, "%L", id, "MSG_NO_ACCESS", g_szSettings[PREFIX_STR]);
            return PLUGIN_HANDLED;
    }

    if(g_szSettings[SIMON_ONLY] && ( g_bSimonNativeExists && is_user_simon(id) ))
    {
        displayColorMenu(id);
    }

    return PLUGIN_HANDLED;
}

displayColorMenu(id)
{
    new szTemp[64];
    formatex(szTemp, charsmax(szTemp), "%s Set glow color", g_szSettings[PREFIX_STR]);
    new iColorMenu = menu_create(szTemp, "colorMenuHandler");

    new szColor[32], szCode[32], szColorData[MAX_FMT_LENGTH];
    for(new i; i < g_iColorSize; i++) {
        ArrayGetString(g_aColorInfo, i, szColorData, charsmax(szColorData));

        split(szColorData, szColor, charsmax(szColor), szCode, charsmax(szCode), " ");
        remove_quotes(szColor);

        formatex(szColorData, charsmax(szColorData), "%s %s", szCode, szColor);
        menu_additem(iColorMenu, szColor, szColorData);
    }
    menu_display(id, iColorMenu);
}

public colorMenuHandler(id, iMenu, iItem)
{
    if(is_user_alive(id))
    {
        new szCode[50], szR[4], szG[4], szB[4], szItem[38], iRed, iGreen, iBlue;
        new iAccess, iCallBack;
        menu_item_getinfo(iMenu, iItem, iAccess, szCode, charsmax(szCode), _, _, iCallBack);

        parse(szCode, szR, charsmax(szR), szG, charsmax(szG), szB, charsmax(szB), szItem, charsmax(szItem));

        iRed = str_to_num(szR);
        iGreen = str_to_num(szG);
        iBlue = str_to_num(szB);

        set_user_rendering(id, kRenderFxGlowShell, iRed, iGreen, iBlue, kRenderNormal, 25);

        if(g_szSettings[CHAT_MSG_ENABLED] && (iItem != MENU_EXIT))
        {
            new szName[32]; get_user_name(id, szName, charsmax(szName));
            ColorChat(id, GREEN, "%L", id, "MSG_SET_GLOW", g_szSettings[PREFIX_STR], szName, szItem);
        }
    }
    menu_destroy(iMenu);
}

public roundStart()
{
    if(g_szSettings[RESET_GLOW_ROUNDSTART])
    {
        new iPlayers[MAX_PLAYERS], iNum;
        get_players(iPlayers, iNum, "ch");

        for(new i; i < iNum; i++)
        {
            set_user_rendering(iPlayers[i]);
        }
    }
}

bool:has_agm_access(const id)
{
     return ((get_user_flags(id) & g_szSettings[ACCESS_FLAGS_BIT]) == g_szSettings[ACCESS_FLAGS_BIT]);
}

bool:has_aim_access(const id)
{
    return ((get_user_flags(id) & g_szSettings[AIM_FLAGS_BIT]) == g_szSettings[AIM_FLAGS_BIT]);
}

readConfigFile()
{
    new szConfigsDir[MAX_FMT_LENGTH], szFileName[MAX_FMT_LENGTH];
    get_configsdir(szConfigsDir, charsmax(szConfigsDir));
    formatex(szFileName, charsmax(szFileName), "%s/AGMConfig.ini", szConfigsDir);

    new iPointer = fopen(szFileName, "rt");

    if(iPointer)
    {
        new szData[96], szValue[64], szKey[32];

        while(!feof(iPointer))
        {
            fgets(iPointer, szData, charsmax(szData));
            trim(szData);

            switch(szData[0])
            {
                case EOS, '#', ';': continue;
                default:
                {
                    strtok(szData, szKey, charsmax(szKey), szValue, charsmax(szValue), '=');
                    trim(szKey);
                    trim(szValue);

                    if(equal(szKey, "CHAT_PREFIX"))
                    {
                        copy(g_szSettings[PREFIX_STR], charsmax(g_szSettings[PREFIX_STR]), szValue);
                    }

                    else if(equal(szKey, "ACCESS_FLAGS"))
                    {
                        copy(g_szSettings[ACCESS_FLAGS_STR], charsmax(g_szSettings[ACCESS_FLAGS_STR]), szValue);
                        g_szSettings[ACCESS_FLAGS_BIT] = read_flags(szValue);
                    }

                    else if(equal(szKey, "AIM_FLAGS"))
                    {
                        copy(g_szSettings[AIM_FLAGS_STR], charsmax(g_szSettings[AIM_FLAGS_STR]), szValue);
                        g_szSettings[AIM_FLAGS_BIT] = read_flags(szValue);
                    }

                    else if(equal(szKey, "CHAT_MSG_ENABLED"))
                    {
                        g_szSettings[CHAT_MSG_ENABLED] = bool:str_to_num(szValue);
                    }

                    else if(equal(szKey, "RESET_GLOW"))
                    {
                        g_szSettings[RESET_GLOW_ROUNDSTART] = bool:str_to_num(szValue);
                    }

                    else if(equal(szKey, "SIMON_ONLY"))
                    {
                        g_szSettings[SIMON_ONLY] = bool:str_to_num(szValue);
                    }

                    if(equal(szKey, "GLOWMENU_COMMANDS"))
                    {
                        while(szValue[0] != 0 && strtok(szValue, szKey, charsmax(szKey), szValue, charsmax(szValue), ','))
                        {
                            trim(szKey);
                            trim(szValue);

                            if(szKey[0] == '/' || szKey[0] == '!')
                            {
                                formatex(szData, charsmax(szData), "say %s", szKey);
                                register_clcmd(szData, "openGlowMenu");
                                formatex(szData, charsmax(szData), "say_team %s", szKey);
                                register_clcmd(szData, "openGlowMenu");
                            }
                            else 
                            {
                                register_clcmd(szData, "openGlowMenu");
                            }
                        }
                    }

                    if(equal(szKey, "TARGET_AIM_SET_GLOW"))
                    {
                        while(szValue[0] != 0 && strtok(szValue, szKey, charsmax(szKey), szValue, charsmax(szValue), ','))
                        {
                            trim(szKey);
                            trim(szValue);

                            formatex(szData, charsmax(szData), "%s", szKey);
                            register_clcmd(szData, "setGlowTarget");
                        }
                    }

                    if(equal(szKey, "TARGET_AIM_REMOVE_GLOW"))
                    {
                        while(szValue[0] != 0 && strtok(szValue, szKey, charsmax(szKey), szValue, charsmax(szValue), ','))
                        {
                            trim(szKey);
                            trim(szValue);

                            formatex(szData, charsmax(szData), "%s", szKey);
                            register_clcmd(szData, "removeGlowTarget");
                        }
                    }
                }
            }
        }
        fclose(iPointer);
    }
}

readColors()
{
    new szConfigsDir[MAX_FMT_LENGTH], szFileName[MAX_FMT_LENGTH];
    get_configsdir(szConfigsDir, charsmax(szConfigsDir));
    formatex(szFileName, charsmax(szFileName), "%s/AGMColors.ini", szConfigsDir);

    new iPointer = fopen(szFileName, "rt");
    new szLine[50];

    while(fgets(iPointer, szLine, charsmax(szLine))) 
    {
        trim(szLine);

        if(szLine[0] == EOS || szLine[0] == ';' || (szLine[0] == '/' && szLine[1] == '/') || szLine[0] == '#') 
        {
            continue;
        }

        ArrayPushString(g_aColorInfo, szLine);
        g_iColorSize = ArraySize(g_aColorInfo);
        log_amx(szLine);
    }
    fclose(iPointer);
} 


L 01/27/2022 - 21:27:42: Start of error session.
L 01/27/2022 - 21:27:42: Info (map "de_dust2") (file "addons/amxmodx/logs/error_20220127.log")
L 01/27/2022 - 21:27:42: [AMXX] Displaying debug trace (plugin "AGM.amxx", version "2.1.2")
L 01/27/2022 - 21:27:42: [AMXX] Run time error 14: native not found (native "is_user_simon")
L 01/27/2022 - 21:27:42: [AMXX]    [0] AGM.sma::openGlowMenu (line 142)

[OciXCrom]

is_user_simon(id) && g_bSimonNativeExists

The other way around. You first need to check if the native exists, then use it. Currently you're using it before checking and is causing an error when not loaded.

[Napoleon_be]

Originally Posted by OciXCrom is_user_simon(id) && g_bSimonNativeExists The other way around. You first need to check if the native exists, then use it. Currently you're using it before checking and is causing an error when not loaded.

Ah yes, i see why that would be the problem. However, i'm still receiving the same error.

Switched the checks around as you said

[OciXCrom]

I tested your code and I'm not getting that error.