[noto3]

A bug that allows survivors to gain more than the maximum hp (100)

If you revive an incapacitated survivor, they have a temporary hp of 20 (this can be changed with sm_cvar survivor_revive_health). Now reviving yourself while you're incapacitated with the command "give health" adds that temporary health (sm_cvar survivor_revive_health) to your new maximum hp -> 100(max) + 20(temp) give health = 120 new hp. This bug also affects plugins such as the points system. Any help would be appreciated.

[moschinovac]

Revive by use "native void L4D_ReviveSurvivor(int client)" of L4Dhooks instead "give health". Work fine for me

[noto3]

Any alternative solution to this?

[HarryPotter]

PHP Code:

void CheatCommand(int client)
{
    int give_flags = GetCommandFlags("give");
    SetCommandFlags("give", give_flags & ~FCVAR_CHEAT);
    if (GetEntProp(client, Prop_Send, "m_isHangingFromLedge"))//懸掛
    {
        FakeClientCommand(client, "give health");
    }
    else if (IsIncapacitated(client))//倒地
    {
        if(GetInfectedAttacker(client) < 0)
        {
            FakeClientCommand(client, "give health");
            SetEntPropFloat(client, Prop_Send, "m_healthBufferTime", GetGameTime());
            SetEntPropFloat(client, Prop_Send, "m_healthBuffer", 0.0);
        }
    }
    else if(GetClientHealth(client)<100) //血量低於100
    {
        FakeClientCommand(client, "give health");
        SetEntPropFloat(client, Prop_Send, "m_healthBufferTime", GetGameTime());
        SetEntPropFloat(client, Prop_Send, "m_healthBuffer", 0.0);
    }
    
    SetCommandFlags("give", give_flags);
}

bool IsIncapacitated(int client)
{
    return view_as<bool>(GetEntProp(client, Prop_Send, "m_isIncapacitated"));
}

int GetInfectedAttacker(int client)
{
    int attacker;

        /* Charger */
        attacker = GetEntPropEnt(client, Prop_Send, "m_pummelAttacker");
        if (attacker > 0)
        {
            return attacker;
        }

        attacker = GetEntPropEnt(client, Prop_Send, "m_carryAttacker");
        if (attacker > 0)
        {
            return attacker;
        }
        /* Jockey */
        attacker = GetEntPropEnt(client, Prop_Send, "m_jockeyAttacker");
        if (attacker > 0)
        {
            return attacker;
        }

    /* Hunter */
    attacker = GetEntPropEnt(client, Prop_Send, "m_pounceAttacker");
    if (attacker > 0)
    {
        return attacker;
    }

    /* Smoker */
    attacker = GetEntPropEnt(client, Prop_Send, "m_tongueOwner");
    if (attacker > 0)
    {
        return attacker;
    }

    return -1;
}